From 2026e365a98e57c319f319e746d307fc94b97a12 Mon Sep 17 00:00:00 2001
From: Scott Murray <scott.murray@konsulko.com>
Date: Tue, 20 Dec 2022 14:24:30 -0500
Subject: Rework cluster demo configuration

Changes:
- Rename cluster-dashboard-demo-config to cluster-demo-config since
  the installed AGL.conf will also be used for receiver configuration
  now.
- Add a Flutter cluster version of AGL.conf that configures the
  receiver window geometry as required.  The alternative mechanism
  is used to generate separate packages with the different AGL.conf
  files.
- Update the package names installed by agl-demo-preload in the Qt
  and Flutter cluster demo images.

It may make sense to do further rework in the dashboard and receiver
apps post-CES to split things into separate configuration files, but
this seems the most straightforward way to do things for now.

Bug-AGL: SPEC-4640

Change-Id: If8a65228c75f28a53ef32a49be90f75a85d60a16
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
---
 .../cluster-demo-config/cluster-demo-config_1.0.bb | 31 ++++++++++++++++++++++
 .../cluster-demo-config/files/AGL.conf.default     |  2 ++
 .../cluster-demo-config/files/AGL.conf.flutter     |  2 ++
 3 files changed, 35 insertions(+)
 create mode 100644 recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb
 create mode 100644 recipes-config/cluster-demo-config/files/AGL.conf.default
 create mode 100644 recipes-config/cluster-demo-config/files/AGL.conf.flutter

(limited to 'recipes-config/cluster-demo-config')

diff --git a/recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb b/recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb
new file mode 100644
index 000000000..48b7965e4
--- /dev/null
+++ b/recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb
@@ -0,0 +1,31 @@
+SUMMARY = "AGL cluster demo configuration file"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI += " \
+    file://AGL.conf.default \
+    file://AGL.conf.flutter \
+"
+
+inherit allarch update-alternatives
+
+do_install() {
+    install -D -m 0644 ${WORKDIR}/AGL.conf.default ${D}${sysconfdir}/xdg/AGL.conf.default
+    install -m 0644 ${WORKDIR}/AGL.conf.flutter ${D}${sysconfdir}/xdg/ 
+}
+
+ALTERNATIVE_LINK_NAME[AGL.conf] = "${sysconfdir}/xdg/AGL.conf"
+
+PACKAGE_BEFORE_PN += "${PN}-flutter"
+
+FILES:${PN} += "${sysconfdir}/xdg/AGL.conf.default"
+RPROVIDES:${PN} = "AGL.conf"
+RCONFLICTS:${PN} = "${PN}-flutter"
+ALTERNATIVE:${PN} = "AGL.conf"
+ALTERNATIVE_TARGET_${PN} = "${sysconfdir}/xdg/AGL.conf.default"
+
+FILES:${PN}-flutter += "${sysconfdir}/xdg/AGL.conf.flutter"
+RPROVIDES:${PN}-flutter = "AGL.conf"
+RCONFLICTS:${PN}-flutter = "${PN}"
+ALTERNATIVE:${PN}-flutter = "AGL.conf"
+ALTERNATIVE_TARGET_${PN}-flutter = "${sysconfdir}/xdg/AGL.conf.flutter"
diff --git a/recipes-config/cluster-demo-config/files/AGL.conf.default b/recipes-config/cluster-demo-config/files/AGL.conf.default
new file mode 100644
index 000000000..dd8a912c5
--- /dev/null
+++ b/recipes-config/cluster-demo-config/files/AGL.conf.default
@@ -0,0 +1,2 @@
+[dashboard]
+animation=false
diff --git a/recipes-config/cluster-demo-config/files/AGL.conf.flutter b/recipes-config/cluster-demo-config/files/AGL.conf.flutter
new file mode 100644
index 000000000..dbd9f370b
--- /dev/null
+++ b/recipes-config/cluster-demo-config/files/AGL.conf.flutter
@@ -0,0 +1,2 @@
+[receiver]
+geometry=420x472+750,290
-- 
cgit 1.2.3-korg