From addb673cf642c1b06bfa912baf1aabbce5297400 Mon Sep 17 00:00:00 2001
From: Scott Murray <scott.murray@konsulko.com>
Date: Fri, 12 May 2023 15:13:15 -0400
Subject: Add vss and vss-agl recipes

Add recipes that use the VSS tools to generate the stock VSS 3.1.1
JSON as well as a version with the extra AGL signals and DBC
configuration for the KUKSA.val CAN feeder.  The latter has the
additional benefit of serving as a working example of using VSS
vspec overlays at build time.

Bug-AGL: SPEC-4761

Change-Id: I6358a8f0a8b64a857dc22cfbd91190ae05546cc0
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
---
 recipes-connectivity/vss/vss_3.1.1.bb | 43 +++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 recipes-connectivity/vss/vss_3.1.1.bb

(limited to 'recipes-connectivity/vss/vss_3.1.1.bb')

diff --git a/recipes-connectivity/vss/vss_3.1.1.bb b/recipes-connectivity/vss/vss_3.1.1.bb
new file mode 100644
index 00000000..05351662
--- /dev/null
+++ b/recipes-connectivity/vss/vss_3.1.1.bb
@@ -0,0 +1,43 @@
+SUMMARY = "Vehicle Signal Specification"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
+
+DEPENDS = "vss-tools-native"
+
+inherit allarch update-alternatives
+
+require vss.inc
+
+UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
+
+S = "${WORKDIR}/git"
+
+do_configure[noexec] = "1"
+
+EXTRA_OEMAKE = "TOOLSDIR=${STAGING_BINDIR_NATIVE}"
+
+do_compile() {
+    oe_runmake json
+}
+
+do_install() {
+    # Cannot use the "install" target in the project Makefile, as it is
+    # intended for setting the repo up for builds.
+    # For now, just the generated JSON is installed. It is possible that
+    # installing the vspec files somewhere as a development package may
+    # be useful, but for now things will be kept simple.
+    install -d ${D}${datadir}/vss
+    install -m 0644 ${S}/vss_rel_${PV}.json ${D}${datadir}/vss/
+}
+
+# NOTE:
+# A virtual RPROVIDES is not used for now, as packages such as KUKSA.val
+# provide their own copies of the VSS JSON, so we can install this one
+# and any alternatives in parallel and point e.g. KUKSA.val at the desired
+# file with a configuration change. This may be worth revisiting down the
+# road.
+
+ALTERNATIVE_LINK_NAME[vss.json] = "${datadir}/vss/vss.json"
+
+ALTERNATIVE:${PN} = "vss.json"
+ALTERNATIVE_TARGET_${PN} = "${datadir}/vss/vss_rel_${PV}.json"
-- 
cgit 1.2.3-korg