From 9d13096870330ac11d915893c113d9e25989153c Mon Sep 17 00:00:00 2001
From: Scott Murray <scott.murray@konsulko.com>
Date: Wed, 1 Mar 2017 11:05:33 -0500
Subject: Switch to split out demo apps

Add recipes for the split out controls, dashboard, phone, and radio app
repositories, remove the related packaging of same from the CES2017-demo
recipe, and add the split out apps to IMAGE_AGL_APPS in the agl-demo-platform
image definition.

Bug-AGL: SPEC-400, SPEC-401, SPEC-402, SPEC-403, SPEC-404

Change-Id: I790eee4edf97ab9c32ddfe5fe277cb7f05012ffc
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
---
 recipes-demo-hmi/radio/radio_git.bb | 48 +++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 recipes-demo-hmi/radio/radio_git.bb

(limited to 'recipes-demo-hmi/radio/radio_git.bb')

diff --git a/recipes-demo-hmi/radio/radio_git.bb b/recipes-demo-hmi/radio/radio_git.bb
new file mode 100644
index 000000000..d48ba6925
--- /dev/null
+++ b/recipes-demo-hmi/radio/radio_git.bb
@@ -0,0 +1,48 @@
+SUMMARY     = "Radio for CES2017 AGL Demonstration"
+DESCRIPTION = "AGL HMI Application for demonstrating Radio on AGL Distribution"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/radio"
+SECTION     = "apps"
+
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+SRC_URI_BRANCH = "master"
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/radio;protocol=http;branch=${SRC_URI_BRANCH} \
+           file://presets-ALS.conf \
+           file://presets-CES.conf \
+           file://presets-FOSDEM.conf \
+"
+SRCREV  = "${AUTOREV}"
+
+# Pinned branch/SRCREV for Charming Chinook
+SRC_URI_BRANCH_chinook = "chinook"
+SRCREV_chinook = "4dd6163184a243f80d6324c61d674383e88e9ba5"
+
+PV = "1.0+git${SRCPV}"
+S  = "${WORKDIR}/git"
+
+# build-time dependencies
+DEPENDS += "qtquickcontrols2 qtmultimedia"
+
+inherit qmake5 aglwgt
+
+# ALS, CES, FOSDEM available
+AGL_RADIO_PRESETS_LOCALE ?= "CES"
+
+do_install_append() {
+    install -d ${D}/home/root/app-data/radio
+    install -m 0644 ${WORKDIR}/presets-CES.conf ${D}/home/root/app-data/radio/
+    install -m 0644 ${WORKDIR}/presets-ALS.conf ${D}/home/root/app-data/radio/
+    install -m 0644 ${WORKDIR}/presets-FOSDEM.conf ${D}/home/root/app-data/radio/
+    install -m 0644 ${WORKDIR}/presets-${AGL_RADIO_PRESETS_LOCALE}.conf ${D}/home/root/app-data/radio/presets.conf
+}
+
+FILES_${PN} += " \
+	/home/root/app-data/radio/presets-*.conf \
+	/home/root/app-data/radio/presets.conf \
+"
+
+RDEPENDS_${PN} += " \
+    qtmultimedia-qmlplugins \
+    qtmultimedia-rtlfm-radio-plugin \
+"
-- 
cgit 1.2.3-korg