From bc27ab6af9319a4754eb54a3acb42f89d99aeeef Mon Sep 17 00:00:00 2001
From: Roger Zanoni <rzanoni@igalia.com>
Date: Tue, 23 Feb 2021 14:05:08 +0100
Subject: web-runtime: Update from chromium79 to chromium84

This patch contains all the squashed changes needed to bump
WAM and chromium, including the ported changes from cr79.

Bug-AGL: SPEC-3806

Signed-off-by: Roger Zanoni <rzanoni@igalia.com>
Change-Id: If2b18e2978e8b1050e4b167b9627c1a526867cfb
---
 recipes-wam/chromium/chromium84_git.bb | 83 ++++++++++++++++++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 recipes-wam/chromium/chromium84_git.bb

(limited to 'recipes-wam/chromium/chromium84_git.bb')

diff --git a/recipes-wam/chromium/chromium84_git.bb b/recipes-wam/chromium/chromium84_git.bb
new file mode 100644
index 00000000..90c7e618
--- /dev/null
+++ b/recipes-wam/chromium/chromium84_git.bb
@@ -0,0 +1,83 @@
+require chromium.inc
+
+SRC_URI = "\
+    git://github.com/igalia/${PN};branch=koi;protocol=https;rev=${SRCREV_chromium84};name=chromium84 \
+    git://github.com/webosose/chromium-v8;branch=@chromium84;destsuffix=git/src/v8;rev=${SRCREV_v8};name=v8 \
+    file://chromium-quiche-invalid-offsetof.patch \
+    file://chromium-skia-no_sanitize.patch \
+"
+
+# Needed by catapult
+DEPENDS += "python-six-native python-beautifulsoup4-native python-lxml-native python-html5lib-native python-webencodings-native"
+
+SRCREV_chromium84 = "20b9dd7995c70950e45d66c7c8cc2b2487c90eb6"
+SRCREV_v8 = "5c1d89dd2945a10cf7a6a3458050b3177a870b09"
+
+BROWSER_APPLICATION = "chromium84-browser"
+BROWSER_APPLICATION_DIR = "/opt/chromium84"
+MKSNAPSHOT_PATH = "v8_snapshot/"
+
+PACKAGECONFIG_remove="jumbo"
+
+GN_ARGS += "use_gtk=false"
+
+# Disable closure_compile
+# Else we need HOSTTOOLS += "java"
+GN_ARGS += "closure_compile=false"
+
+# When using meta-clang, one can switch to using the lld linker
+# by using the ld-is-lld distro feature otherwise use gold linker
+GN_ARGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', 'use_lld=true use_gold=false', bb.utils.contains('DISTRO_FEATURES', 'ld-is-gold', 'use_lld=false use_gold=true', 'use_lld=false use_gold=false', d), d)}"
+
+# Toolchains we will use for the build. We need to point to the toolchain file
+# we've created, set the right target architecture and make sure we are not
+# using Chromium's toolchain (bundled clang, bundled binutils etc).
+GN_ARGS += "\
+    host_toolchain=\"//build/toolchain/cros:host\" \
+    cros_host_is_clang=false \
+    use_custom_libcxx_for_host=false \
+    cros_host_ar=\"${BUILD_AR}\" \
+    cros_host_cc=\"${BUILD_CC} ${BUILD_CFLAGS}\" \
+    cros_host_cxx=\"${BUILD_CXX} ${BUILD_CXXFLAGS}\" \
+    cros_host_extra_ldflags=\"${BUILD_LDFLAGS}\" \
+    custom_toolchain=\"//build/toolchain/cros:target\" \
+    is_clang=false \
+    use_custom_libcxx=false \
+    target_cpu=\"${@gn_arch_name('${TUNE_ARCH}')}\" \
+    cros_target_ar=\"${AR}\" \
+    cros_target_cc=\"${CC}\" \
+    cros_target_cxx=\"${CXX}\" \
+    cros_target_extra_ldflags=\"${LDFLAGS}\" \
+    v8_snapshot_toolchain=\"//build/toolchain/cros:v8_snapshot\" \
+    cros_v8_snapshot_is_clang=false \
+    cros_v8_snapshot_ar=\"${BUILD_AR}\" \
+    cros_v8_snapshot_cc=\"${BUILD_CC}\" \
+    cros_v8_snapshot_cxx=\"${BUILD_CXX}\" \
+    linux_use_bundled_binutils=false \
+    gold_path=\"\" \
+    v8_enable_embedded_builtins=false \
+    use_v8_context_snapshot=false \
+"
+
+GN_ARGS_append = " \
+  use_system_minigbm=false \
+  use_wayland_gbm=false \
+"
+
+GN_ARGS_append = " \
+  is_webos=false \
+  is_agl=true \
+"
+
+# TODO: drop this after we migrate to ubuntu 16.04 or above
+GN_ARGS += "\
+    fatal_linker_warnings=false\
+"
+
+# TODO(rzanoni) copied from original recipe to fix qemux86 build.
+# check if it can be removed in the future.
+PACKAGECONFIG_remove_qemux86 = "gstreamer umediaserver neva-media gav neva-webrtc"
+#END TODO
+
+D = "${OUT_DIR}/${BUILD_TYPE}/image"
+
-- 
cgit 1.2.3-korg