Rename Instrument Cluster Container layer

meta-agl-lxc is no longer reflecting the actual content and use of the layer.
Rename it to  'meta-agl-ic-container' and the feature to 'agl-ic-container'.

Also rename the main image to 'agl-cluster-demo-lxc-host' to match the pattern used
by all other images  e.g. agl-<ivi,cluster,telematics>-demo-* .
But keep the names of the underlying images as-is.

Bug-AGL: SPEC-4464
Signed-off-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Change-Id: I898c786ca884331b302a3be8e150379fcf5bdc9b

3 files changed, 76 insertions, 0 deletions

diff --git a/meta-agl-ic-container/recipes-demo/mominavi/mominavi/mominavi b/meta-agl-ic-container/recipes-demo/mominavi/mominavi/mominavi
new file mode 100644
index 00000000..bd017dc9
--- /dev/null
+++ b/meta-agl-ic-container/recipes-demo/mominavi/mominavi/mominavi
@@ -0,0 +1,7 @@
+XDG_RUNTIME_DIR=/run/user/0
+QT_QPA_PLATFORM=wayland-egl
+QT_WAYLAND_DISABLE_WINDOWDECORATION=1
+QT_QPA_FONTDIR=/usr/share/fonts/truetype
+QT_IVI_SURFACE_ID=2010
+QT_WAYLAND_SHELL_INTEGRATION=ivi-shell
+WAYLAND_DISPLAY=wayland-1
diff --git a/meta-agl-ic-container/recipes-demo/mominavi/mominavi/mominavi.service b/meta-agl-ic-container/recipes-demo/mominavi/mominavi/mominavi.service
new file mode 100644
index 00000000..b49609e0
--- /dev/null
+++ b/meta-agl-ic-container/recipes-demo/mominavi/mominavi/mominavi.service
@@ -0,0 +1,12 @@
+[Unit]
+Description=mominavi
+After=multi-user.target weston.service network-online.target
+Requires=multi-user.target weston.service network-online.target
+
+[Service]
+Type=simple
+EnvironmentFile=/etc/default/mominavi
+ExecStart=/usr/bin/mominavi
+
+[Install]
+WantedBy=multi-user.target
diff --git a/meta-agl-ic-container/recipes-demo/mominavi/mominavi_git.bb b/meta-agl-ic-container/recipes-demo/mominavi/mominavi_git.bb
new file mode 100644
index 00000000..124252b5
--- /dev/null
+++ b/meta-agl-ic-container/recipes-demo/mominavi/mominavi_git.bb
@@ -0,0 +1,57 @@
+SUMMARY     = "Momiyama navigation example based on mapbox."
+DESCRIPTION = "The mominavi is a navigation example based on mapbox. It's based on aglqtnavigation. \
+               The mominavi is not require agl-appfw."
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d32239bcb673463ab874e80d47fae504"
+
+DEPENDS = " \
+    qtbase \
+    qtquickcontrols2 \
+    qtlocation \
+    qtgraphicaleffects \
+    qtsvg \
+    qtwebsockets \
+    "
+
+PV = "0.2.0"
+
+SRC_URI = "git://github.com/AGLExport/mominavi.git;protocol=https;branch=master \
+           file://mominavi.service \
+           file://mominavi \
+          "
+SRCREV = "553776e75da02b27224748756da55d38b6c7241f"
+
+S = "${WORKDIR}/git"
+
+inherit qmake5 systemd
+
+MOMIMAP_MAPBOX_ACCESS_TOKEN ??= "YOU_NEED_TO_SET_IT_IN_LOCAL_CONF"
+QT_INSTALL_PREFIX = "/usr"
+
+do_configure:prepend() {
+	if [ "${MOMIMAP_MAPBOX_ACCESS_TOKEN}" = "YOU_NEED_TO_SET_IT_IN_LOCAL_CONF" ]; then
+		bbwarn "WARNING: You should set MapBox development key to MOMIMAP_MAPBOX_ACCESS_TOKEN variable in local.conf."
+	fi
+}
+do_install:append() {
+    install -d ${D}/${systemd_unitdir}/system
+    install -m 0644 ${WORKDIR}/mominavi.service ${D}/${systemd_unitdir}/system
+
+    install -m 0755 -d ${D}${sysconfdir}/default/
+    install -m 0755 ${WORKDIR}/mominavi ${D}${sysconfdir}/default/
+
+    echo 'MOMIMAP_MAPBOX_ACCESS_TOKEN=${MOMIMAP_MAPBOX_ACCESS_TOKEN}' >> ${D}${sysconfdir}/default/mominavi
+}
+
+FILES:${PN} += " \
+    ${systemd_unitdir} \
+    ${sysconfdir}/*/* \
+    "
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE:${PN} = "mominavi.service"
+
+RDEPENDS:${PN} = " \
+    qtsvg \
+    qtwebsockets \
+    qtlocation \
+    "