From 13169c3265ba75d783eb3723504298a08e768110 Mon Sep 17 00:00:00 2001
From: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Date: Tue, 9 Aug 2022 11:33:17 +0200
Subject: Rename Instrument Cluster Container layer

meta-agl-lxc is no longer reflecting the actual content and use of the layer.
Rename it to  'meta-agl-ic-container' and the feature to 'agl-ic-container'.

Also rename the main image to 'agl-cluster-demo-lxc-host' to match the pattern used
by all other images  e.g. agl-<ivi,cluster,telematics>-demo-* .
But keep the names of the underlying images as-is.

Bug-AGL: SPEC-4464
Signed-off-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Change-Id: I898c786ca884331b302a3be8e150379fcf5bdc9b
---
 .../cluster-refgui/cluster-refgui_git.bb           | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 meta-agl-ic-container/recipes-demo/cluster-refgui/cluster-refgui_git.bb

(limited to 'meta-agl-ic-container/recipes-demo/cluster-refgui/cluster-refgui_git.bb')

diff --git a/meta-agl-ic-container/recipes-demo/cluster-refgui/cluster-refgui_git.bb b/meta-agl-ic-container/recipes-demo/cluster-refgui/cluster-refgui_git.bb
new file mode 100644
index 00000000..4327c8de
--- /dev/null
+++ b/meta-agl-ic-container/recipes-demo/cluster-refgui/cluster-refgui_git.bb
@@ -0,0 +1,49 @@
+DESCRIPTION = "AGL Cluster Reference GUI"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5335066555b14d832335aa4660d6c376"
+
+DEPENDS = " \
+    qttools-native \
+    qtmultimedia \
+"
+
+BRANCH = "master"
+SRC_URI = "git://git.automotivelinux.org/src/cluster-refgui;protocol=https;branch=${BRANCH} \
+           file://cluster.service \
+           file://cluster \
+"
+SRCREV = "a16c6201be94a57eb8151a91699084d99694877c"
+
+S = "${WORKDIR}/git"
+
+inherit cmake cmake_qt5 systemd
+
+# NOTE:
+# The app currently assumes the mp4 video file is in the same
+# directory, so changing this to ${bindir} to better match FHS
+# requires code changes.
+APP_DIR = "/opt/apps"
+EXTRA_OECMAKE = "-DAPPS_INST_DIR=${APP_DIR}"
+
+SYSTEMD_SERVICE:${PN} = "cluster.service"
+
+do_install:append() {
+    install -d ${D}${systemd_unitdir}/system
+    install -m 0644 ${WORKDIR}/cluster.service ${D}${systemd_unitdir}/system/
+    
+    install -m 0755 -d ${D}${sysconfdir}/default/
+    install -m 0755 ${WORKDIR}/cluster ${D}${sysconfdir}/default/
+}
+
+FILES:${PN} += "${APP_DIR}/"
+
+RDEPENDS:${PN} = " \
+    qtbase \
+    qtdeclarative \
+    qt3d \
+    qtgraphicaleffects \
+    qtmultimedia \
+    qtquickcontrols \
+    qtquickcontrols2 \
+    qtwayland \
+"
-- 
cgit 1.2.3-korg