From 68fa652a418a5dfcee12386fd58939bfd626144d Mon Sep 17 00:00:00 2001
From: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Date: Tue, 9 Aug 2022 11:33:17 +0200
Subject: Rename Instrument Cluster Container layer

meta-agl-lxc is no longer reflecting the actual content and use of the layer.
Rename it to  'meta-agl-ic-container' and the feature to 'agl-ic-container'.

Also rename the main image to 'agl-cluster-demo-lxc-host' to match the pattern used
by all other images  e.g. agl-<ivi,cluster,telematics>-demo-* .
But keep the names of the underlying images as-is.

Bug-AGL: SPEC-4464
Signed-off-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Change-Id: I898c786ca884331b302a3be8e150379fcf5bdc9b
---
 .../images/lxc-host-image-minimal.bb               | 62 ----------------------
 1 file changed, 62 deletions(-)
 delete mode 100644 meta-agl-lxc/recipes-platform/images/lxc-host-image-minimal.bb

(limited to 'meta-agl-lxc/recipes-platform/images/lxc-host-image-minimal.bb')

diff --git a/meta-agl-lxc/recipes-platform/images/lxc-host-image-minimal.bb b/meta-agl-lxc/recipes-platform/images/lxc-host-image-minimal.bb
deleted file mode 100644
index 38fc7b26..00000000
--- a/meta-agl-lxc/recipes-platform/images/lxc-host-image-minimal.bb
+++ /dev/null
@@ -1,62 +0,0 @@
-SUMMARY = "A minimal container host image"
-
-require recipes-platform/images/agl-image-boot.inc
-
-IMAGE_INSTALL += " \
-    kernel-image \
-    lxc \
-    ${LXC_CONTAINER_CONFIGS} \
-    drm-lease-manager \
-"
-
-CONTAINER_IMAGES ??= ""
-
-LXC_CONTAINER_CONFIGS ?= ""
-
-IMAGE_LINGUAS = " "
-
-NO_RECOMMENDATIONS = "1"
-
-# Handle modification of IMAGE_LINK_NAME done by ULCB builds with Kingfisher support
-MACHINE_SUFFIX = "${@bb.utils.contains('AGL_FEATURES', 'kingfisher', '-kf', '', d)}"
-
-python __anonymous() {
-    for c in (d.getVar('CONTAINER_IMAGES') or "").split():
-        (mc, image) = c.split(':')
-        dependency = 'mc::' + mc + ':' + image + ':do_image_complete'
-        d.appendVarFlag('do_rootfs', 'mcdepends', ' ' + dependency)
-
-        # Assume there is a X-lxc-config package for guest-image-X
-        config = image
-        if config.startswith('guest-image-'):
-            config = config[len('guest-image-'):]
-        d.appendVar('LXC_CONTAINER_CONFIGS', ' ' + 'lxc-config-' + config)
-}
-
-install_container_images() {
-    for c in ${CONTAINER_IMAGES}; do
-        config=${c%:*}
-        image=${c#*:}
-        name=${image#guest-image-}
-        rm -rf  ${IMAGE_ROOTFS}/var/lib/machines/${name}
-        install -m 0755 -d ${IMAGE_ROOTFS}/var/lib/machines/${name}
-        src="${TOPDIR}/tmp-${config}/deploy/images/${MACHINE}/${image}-${MACHINE}${MACHINE_SUFFIX}.tar.bz2"
-        bbnote "Installing ${src}"
-        tar -C ${IMAGE_ROOTFS}/var/lib/machines/${name} -xf ${src}
-    done
-}
-
-#
-# Force rebuild of rootfs on every build to work around mcdepends issue
-#
-# NOTE:
-# This is currently required as bitbake fails to trigger do_rootfs
-# sometimes even when the guest image has in fact rebuilt.  This is
-# being investigated with upstream.
-#
-do_rootfs[nostamp] = "1"
-
-ROOTFS_POSTPROCESS_COMMAND += "install_container_images; "
-
-IMAGE_ROOTFS_EXTRA_SPACE:append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"
-
-- 
cgit 1.2.3-korg