From 4507f748f323fac0cc82c6516a02424b927e2d01 Mon Sep 17 00:00:00 2001
From: Qiu Tingting <qiutt@fujitsu.com>
Date: Thu, 16 Nov 2023 05:33:31 +0000
Subject: tar: fix ptest with upgrade 1.34 -> 1.35

Rename tar_1.34.bbappend -> tar_1.35.bbappend
Add 0004-disable-sparse05.patch to fix ptest-runner pipeline crash,
becuase case sparse05 will write files larger than 2 ^ 33 bytes.

Bug-AGL: SPEC-4753

Signed-off-by: Qiu Tingting <qiutt@fujitsu.com>
Change-Id: Ia8b301fb104c4699d95804d8f4074f4a5b58737a
---
 .../recipes-external/tar/tar_1.35.bbappend         | 40 ++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 meta-agl-test/recipes-external/tar/tar_1.35.bbappend

(limited to 'meta-agl-test/recipes-external/tar/tar_1.35.bbappend')

diff --git a/meta-agl-test/recipes-external/tar/tar_1.35.bbappend b/meta-agl-test/recipes-external/tar/tar_1.35.bbappend
new file mode 100644
index 00000000..d00a61e0
--- /dev/null
+++ b/meta-agl-test/recipes-external/tar/tar_1.35.bbappend
@@ -0,0 +1,40 @@
+# Add ptest support
+
+# backport of yocto begin
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+# add for ptest support
+SRC_URI += " \
+    file://run-ptest \
+    file://0001-tests-fix-TESTSUITE_AT.patch \
+    file://0002-tests-check-for-recently-fixed-bug.patch \
+    file://0003-Exclude-VCS-directory-with-writing-from-an-archive.patch \
+    file://0004-disable-sparse05.patch \
+"
+
+inherit ptest
+
+do_compile_ptest() {
+    oe_runmake -C ${B}/gnu/ check
+    oe_runmake -C ${B}/lib/ check
+    oe_runmake -C ${B}/rmt/ check
+    oe_runmake -C ${B}/src/ check
+    rm -rf ${S}/tests/testsuite
+    oe_runmake -C ${B}/tests/ testsuite
+    oe_runmake -C ${B}/tests/ genfile checkseekhole ckmtime
+}
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests/
+    install --mode=755 ${B}/tests/atconfig ${D}${PTEST_PATH}/tests/
+    sed -i "/abs_/d" ${D}${PTEST_PATH}/tests/atconfig
+    echo "abs_builddir=${PTEST_PATH}/tests/" >> ${D}${PTEST_PATH}/tests/atconfig
+    install --mode=755 ${B}/tests/atlocal ${D}${PTEST_PATH}/tests/
+    sed -i "/PATH=/d" ${D}${PTEST_PATH}/tests/atlocal
+    install --mode=755 ${B}/tests/genfile ${D}${PTEST_PATH}/tests/
+    install --mode=755 ${B}/tests/checkseekhole ${D}${PTEST_PATH}/tests/
+    install --mode=755 ${B}/tests/ckmtime ${D}${PTEST_PATH}/tests/
+    install --mode=755 ${S}/tests/testsuite ${D}${PTEST_PATH}/tests/
+    sed -i "s#@PTEST_PATH@#${PTEST_PATH}#g" ${D}${PTEST_PATH}/run-ptest
+}
+# backport of yocto end
-- 
cgit 1.2.3-korg