From 09a8e540857fb291c1f05877c2f6be62ac893749 Mon Sep 17 00:00:00 2001
From: Jan-Simon Möller <jsmoeller@linuxfoundation.org>
Date: Mon, 18 Apr 2016 12:00:38 +0200
Subject: Add recipe for trinity
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

This is the new name for scrashme.
Recipe copied from meta-linaro.

Change-Id: Ieb21885750a7462aefa83cab85e8bcffd54d4233
Signed-off-by: Jan-Simon Möller <jsmoeller@linuxfoundation.org>
---
 .../recipes-test/trinity/trinity_git.bb            | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 meta-ivi-common/recipes-test/trinity/trinity_git.bb

diff --git a/meta-ivi-common/recipes-test/trinity/trinity_git.bb b/meta-ivi-common/recipes-test/trinity/trinity_git.bb
new file mode 100644
index 000000000..f0f09a855
--- /dev/null
+++ b/meta-ivi-common/recipes-test/trinity/trinity_git.bb
@@ -0,0 +1,42 @@
+SUMMARY = "a Linux System call fuzz teste."
+DESCRIPTION = "Trinity, a Linux System call fuzz tester."
+HOMEPAGE = "http://codemonkey.org.uk/projects/trinity/"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://${S}/COPYING;md5=96094d47cfbd2cc45eb46ce0fc423c04"
+
+COMPATIBLE_HOST = "(x86_64|arm|aarch64).*-linux"
+
+PV = "1.5"
+SRCREV = "edc2e693e298e0372010a361354c4a79a3cd93f3"
+SRC_URI = "git://github.com/kernelslacker/trinity.git;protocol=https;nobranch=1 \
+          "
+
+S = "${WORKDIR}/git"
+
+inherit useradd
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM_${PN} = "--system --create-home --shell /bin/sh ${PN} "
+
+do_configure () {
+    ./configure.sh
+}
+
+# workaround random build failures
+do_compile () {
+    ${MAKE}
+}
+
+do_install () {
+    oe_runmake install DESTDIR=${D}/usr
+    install -o ${PN} -d -m 0755 ${D}/${datadir}/${PN}
+    install -o ${PN} -m 0755 ${S}/scripts/test-all-syscalls-parallel.sh     ${D}/${datadir}/${PN}
+    install -o ${PN} -m 0755 ${S}/scripts/test-all-syscalls-sequentially.sh ${D}/${datadir}/${PN}
+    install -o ${PN} -m 0755 ${S}/scripts/test-multi.sh                     ${D}/${datadir}/${PN}
+    install -o ${PN} -m 0755 ${S}/scripts/test-vm.sh                        ${D}/${datadir}/${PN}
+}
+
+PACKAGES =+ "${PN}-example"
+
+FILES_${PN} = "${bindir}/trinity"
+FILES_${PN}-example = "${datadir}/${PN}"
-- 
cgit 1.2.3-korg