From 2460f6ac99d834f00dfa6e26546c41eac6cd38c9 Mon Sep 17 00:00:00 2001
From: Scott Murray <scott.murray@konsulko.com>
Date: Wed, 26 Jun 2024 15:22:14 -0400
Subject: Add meta-agl-kuksa-val

Add new meta-agl-kuksa-val layer, and populate it with the base
KUKSA.val databroker and VSS schema recipes from meta-agl, as well
as the recipes for the Python modules they depend on.

Additional changes:
- Installation of AGL-specific configuration has been removed from
  the kuksa-can-provider recipe.  It now packages the upstream
  example/test configuration in a new kuksa-can-provider-conf-example
  package that can be replaced via the RPROVIDES scheme.  Some minor
  tweaks for paths are made to the upstream .ini file to match
  FHS expectations.

Bug-AGL: SPEC-5136

Change-Id: I3128a223f4fcf16e496cb27e26afcaee0a28979a
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Reviewed-on: https://gerrit.automotivelinux.org/gerrit/c/AGL/meta-agl/+/30040
Tested-by: Jenkins Job builder account
ci-image-build: Jenkins Job builder account
ci-image-boot-test: Jenkins Job builder account
Reviewed-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
---
 .../recipes-support/vss/vss-tools_4.2.bb           | 29 +++++++++++++++
 meta-agl-kuksa-val/recipes-support/vss/vss.inc     |  5 +++
 meta-agl-kuksa-val/recipes-support/vss/vss_4.2.bb  | 43 ++++++++++++++++++++++
 3 files changed, 77 insertions(+)
 create mode 100644 meta-agl-kuksa-val/recipes-support/vss/vss-tools_4.2.bb
 create mode 100644 meta-agl-kuksa-val/recipes-support/vss/vss.inc
 create mode 100644 meta-agl-kuksa-val/recipes-support/vss/vss_4.2.bb

(limited to 'meta-agl-kuksa-val/recipes-support/vss')

diff --git a/meta-agl-kuksa-val/recipes-support/vss/vss-tools_4.2.bb b/meta-agl-kuksa-val/recipes-support/vss/vss-tools_4.2.bb
new file mode 100644
index 000000000..62f78f07e
--- /dev/null
+++ b/meta-agl-kuksa-val/recipes-support/vss/vss-tools_4.2.bb
@@ -0,0 +1,29 @@
+SUMMARY = "COVESA Vehicle Signal Specification tooling."
+HOMEPAGE = "https://github.com/COVESA/vss-tools"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
+
+SRC_URI = "git://github.com/COVESA/vss-tools.git;protocol=https;branch=release/4.2"
+SRCREV = "b350788d6dd16942e987fdb9e8b8b3b403fe23c6"
+
+S = "${WORKDIR}/git"
+
+inherit setuptools3
+
+RDEPENDS:${PN} += " \
+    python3-core \
+    python3-ctypes \
+    python3-email \
+    python3-importlib-metadata \
+    python3-json \
+    python3-logging \
+    python3-netclient \
+    python3-pkg-resources \
+    python3-anytree \
+    python3-deprecation \
+    python3-graphql-core \
+    python3-pyyaml \
+    python3-six \
+"
+
+BBCLASSEXTEND += "native nativesdk"
diff --git a/meta-agl-kuksa-val/recipes-support/vss/vss.inc b/meta-agl-kuksa-val/recipes-support/vss/vss.inc
new file mode 100644
index 000000000..aab950bee
--- /dev/null
+++ b/meta-agl-kuksa-val/recipes-support/vss/vss.inc
@@ -0,0 +1,5 @@
+SRC_URI = "git://github.com/COVESA/vehicle_signal_specification.git;branch=release/4.2;protocol=https"
+# v4.2
+SRCREV = "6024c4b29065b37c074649a1a65396b9d4de9b55"
+
+S = "${WORKDIR}/git"
diff --git a/meta-agl-kuksa-val/recipes-support/vss/vss_4.2.bb b/meta-agl-kuksa-val/recipes-support/vss/vss_4.2.bb
new file mode 100644
index 000000000..053516629
--- /dev/null
+++ b/meta-agl-kuksa-val/recipes-support/vss/vss_4.2.bb
@@ -0,0 +1,43 @@
+SUMMARY = "Vehicle Signal Specification"
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
+
+DEPENDS = "vss-tools-native"
+
+inherit allarch update-alternatives
+
+require vss.inc
+
+UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
+
+S = "${WORKDIR}/git"
+
+do_configure[noexec] = "1"
+
+EXTRA_OEMAKE = "TOOLSDIR=${STAGING_BINDIR_NATIVE}"
+
+do_compile() {
+    oe_runmake json
+}
+
+do_install() {
+    # Cannot use the "install" target in the project Makefile, as it is
+    # intended for setting the repo up for builds.
+    # For now, just the generated JSON is installed. It is possible that
+    # installing the vspec files somewhere as a development package may
+    # be useful, but for now things will be kept simple.
+    install -d ${D}${datadir}/vss
+    install -m 0644 ${S}/vss_rel_${PV}.json ${D}${datadir}/vss/
+}
+
+# NOTE:
+# A virtual RPROVIDES is not used for now, as packages such as KUKSA.val
+# provide their own copies of the VSS JSON, so we can install this one
+# and any alternatives in parallel and point e.g. KUKSA.val at the desired
+# file with a configuration change. This may be worth revisiting down the
+# road.
+
+ALTERNATIVE_LINK_NAME[vss.json] = "${datadir}/vss/vss.json"
+
+ALTERNATIVE:${PN} = "vss.json"
+ALTERNATIVE_TARGET_${PN} = "${datadir}/vss/vss_rel_${PV}.json"
-- 
cgit 1.2.3-korg