From c4952739d5d811153bacddd57fd1ecd09cbcad7d Mon Sep 17 00:00:00 2001
From: Scott Murray <scott.murray@konsulko.com>
Date: Wed, 22 Jan 2020 18:16:17 -0500
Subject: meta-agl-profile-core: handle freetype upgrade

Rename and update freetype bbappend in meta-agl-profile-core to work
with new 2.10.1 recipe in oe-core.

Bug-AGL: SPEC-2932

Change-Id: I71ae6dfde9d9ae36a3f70661fbb84afb575d6786
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
---
 .../recipes-test/freetype/freetype_2.%.bbappend    | 34 ++++++++++++++++++++++
 1 file changed, 34 insertions(+)
 create mode 100644 meta-agl-profile-core/recipes-test/freetype/freetype_2.%.bbappend

(limited to 'meta-agl-profile-core/recipes-test/freetype/freetype_2.%.bbappend')

diff --git a/meta-agl-profile-core/recipes-test/freetype/freetype_2.%.bbappend b/meta-agl-profile-core/recipes-test/freetype/freetype_2.%.bbappend
new file mode 100644
index 000000000..6aa1eabc2
--- /dev/null
+++ b/meta-agl-profile-core/recipes-test/freetype/freetype_2.%.bbappend
@@ -0,0 +1,34 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
+
+SRC_URI =+ "${SOURCEFORGE_MIRROR}/freetype/freetype-demos/${PV}/ft2demos-${PV}.tar.gz;name=ft2demos \
+           file://0001-Makefile-dont-build-gfx-demos.patch;patchdir=../ft2demos-${PV} \
+           file://0001-ft2demos-Makefile-Do-not-hardcode-libtool-path.patch;patchdir=../ft2demos-${PV} \
+          "
+SRC_URI[ft2demos.md5sum] = "c376adf4782bac9b9ac8e427884752d2"
+SRC_URI[ft2demos.sha256sum] = "5e9e94a2db9d1a945293a1644a502f6664a2173a454d4a55b19695e2e2f4a0bc"
+
+PACKAGES =+ "${PN}-demos"
+
+B = "${S}"
+
+do_compile_append () {
+    oe_runmake -C ${WORKDIR}/ft2demos-${PV} TOP_DIR=${WORKDIR}/${BPN}-${PV}/
+}
+
+do_install_append () {
+    install -d -m 0755 ${D}/${bindir}
+    for x in ftbench ftdump ftlint ftvalid ttdebug; do
+        install -m 0755 ${WORKDIR}/ft2demos-${PV}/bin/.libs/$x ${D}/${bindir}
+    done
+}
+
+FILES_${PN}-demos = "\
+    ${bindir}/ftbench \
+    ${bindir}/ftdump \
+    ${bindir}/ftlint \
+    ${bindir}/ftvalid \
+    ${bindir}/ttdebug \
+"
+
+# enable pixmap/libpng support to allow color emojis
+PACKAGECONFIG_append = " pixmap"
-- 
cgit 1.2.3-korg