From 61e6b5d03992bb72deb00f6ee518fc122fee59ef Mon Sep 17 00:00:00 2001
From: José Bollo <jose.bollo@iot.bzh>
Date: Wed, 12 Sep 2018 09:58:03 +0200
Subject: Cynagora: Replace cynara with cynagora
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Shift from the permission database cynara
to cynagora permission database with a compatibility
library.

The cache size required by dbus-cynara is updated
because that size is now a count of bytes, not a count
of entries.

Bug-AGL: SPEC-2844

Change-Id: I9a81de6e3b8bcb94adc0bb05c63183c2eda3f310
Signed-off-by: José Bollo <jose.bollo@iot.bzh>
---
 .../cynagora/cynagora-cynara-compat_2.0.bb         | 30 +++++++++++++++++
 .../recipes-security/cynagora/cynagora/run-ptest   |  4 +++
 .../recipes-security/cynagora/cynagora_2.0.bb      | 38 ++++++++++++++++++++++
 3 files changed, 72 insertions(+)
 create mode 100644 meta-security/recipes-security/cynagora/cynagora-cynara-compat_2.0.bb
 create mode 100755 meta-security/recipes-security/cynagora/cynagora/run-ptest
 create mode 100644 meta-security/recipes-security/cynagora/cynagora_2.0.bb

(limited to 'meta-security/recipes-security/cynagora')

diff --git a/meta-security/recipes-security/cynagora/cynagora-cynara-compat_2.0.bb b/meta-security/recipes-security/cynagora/cynagora-cynara-compat_2.0.bb
new file mode 100644
index 000000000..fa5cdbadc
--- /dev/null
+++ b/meta-security/recipes-security/cynagora/cynagora-cynara-compat_2.0.bb
@@ -0,0 +1,30 @@
+DESCRIPTION = "Cynara service with client libraries"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://Apache-2.0;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/cynagora;protocol=https;branch=${AGL_BRANCH}"
+SRCREV = "6c88efcb7b1361ba6389753e520e26fc556b7d79"
+PV = "2.0+git${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+inherit cmake
+
+PROVIDES = "cynara"
+RPROVIDES_${PN} = "cynara"
+DEPENDS = "libcap"
+RDEPENDS_${PN} = "cynagora"
+
+EXTRA_OECMAKE += " \
+	-DWITH_SYSTEMD=OFF \
+	-DWITH_CYNARA_COMPAT=ON \
+	-DDIRECT_CYNARA_COMPAT=ON \
+"
+
+do_install_append() {
+	# remove cynagora stuff
+	rm $(find ${D} -name '*cynagora*')
+	# remove stupid test
+	rm -r ${D}${bindir}
+}
+
diff --git a/meta-security/recipes-security/cynagora/cynagora/run-ptest b/meta-security/recipes-security/cynagora/cynagora/run-ptest
new file mode 100755
index 000000000..f95f0725b
--- /dev/null
+++ b/meta-security/recipes-security/cynagora/cynagora/run-ptest
@@ -0,0 +1,4 @@
+#!/bin/sh
+
+# test access to cynagora server
+cynagora-admin list > /dev/null
diff --git a/meta-security/recipes-security/cynagora/cynagora_2.0.bb b/meta-security/recipes-security/cynagora/cynagora_2.0.bb
new file mode 100644
index 000000000..77af839d8
--- /dev/null
+++ b/meta-security/recipes-security/cynagora/cynagora_2.0.bb
@@ -0,0 +1,38 @@
+DESCRIPTION = "Cynara service with client libraries"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://Apache-2.0;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/cynagora;protocol=https;branch=${AGL_BRANCH}"
+SRCREV = "6c88efcb7b1361ba6389753e520e26fc556b7d79"
+PV = "2.0+git${SRCPV}"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "systemd libcap"
+
+inherit cmake
+
+EXTRA_OECMAKE += " \
+	-DSYSTEMD_UNIT_DIR=${systemd_system_unitdir} \
+	-DWITH_SYSTEMD=ON \
+	-DWITH_CYNARA_COMPAT=OFF \
+"
+
+inherit useradd
+USERADD_PACKAGES = "${PN}"
+GROUPADD_PARAM_${PN} = "-r cynagora"
+USERADD_PARAM_${PN} = "\
+--system --home ${localstatedir}/lib/empty \
+--no-create-home --shell /bin/false \
+--gid cynagora cynagora \
+"
+
+FILES_${PN} += "${systemd_system_unitdir}"
+
+PACKAGES =+ "${PN}-tools"
+FILES_${PN}-tools += "${bindir}/cynagora-admin ${bindir}/cynagora-agent"
+RDEPENDS_${PN}_append_agl-devel = " ${PN}-tools"
+
+inherit ptest
+SRC_URI_append = " file://run-ptest"
+RDEPENDS_${PN}-ptest_append = " ${PN}-tools"
-- 
cgit 1.2.3-korg