summaryrefslogtreecommitdiffstats
path: root/meta-app-framework/recipes-core/nss-localuser/nss-localuser_0.1.bb
blob: 93d2a203402fad7d72bf18894a08ec5266c0b945 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
SUMMARY = "Name Service Switch module for resolving the local user hostname"

DESCRIPTION = "plugin for the GNU Name Service Switch (NSS) \
functionality of the GNU C Library (`glibc`) providing host name \
resolution for *"localuser"* family of virtual hostnames."

HOMEPAGE = "https://git.automotivelinux.org/src/nss-localuser/"

LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=79ad77111c398994735201536a4749ba"

SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/nss-localuser;protocol=https;branch=${AGL_BRANCH}"
SRCREV = "66803c6fdb609ed83a78b9194ecb23e9c1b773e7"
PV = "${AGL_BRANCH}+git${SRCPV}"

RDEPENDS:${PN} = "base-files"

S = "${WORKDIR}/git"

do_compile() {
	make
}

do_install() {
	make nssdir=${D}${libdir} install
}

pkg_postinst_ontarget:${PN} () {
	sed -e '/^hosts:/s/\<localuser\>\s*//' \
		-e 's/\(^hosts:\s\s*\)\(.*\)/\1localuser \2/' \
		-i $D${sysconfdir}/nsswitch.conf
}

pkg_prerm:${PN} () {
	sed -e '/^hosts:/s/\<localuser\>\s*//' \
		-i $D${sysconfdir}/nsswitch.conf
}

INSANE_SKIP:${PN} = "ldflags"