From e46d6a91dc9e8f0383aa604878ec2d8db04a85ce Mon Sep 17 00:00:00 2001
From: Thuy Tran <thuy.tran.xh@renesas.com>
Date: Tue, 30 Oct 2018 12:26:45 +0900
Subject: rcar-gen3: weston: Update to support weston 5.0

This commit uses the weston upstream version 5.0 with "GPU
only" h/w acceleration. It also modifies weston-init to adapt
upstream version.

Signed-off-by: Thuy Tran <thuy.tran.xh@renesas.com>
Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>
---
 .../recipes-graphics/wayland/weston_%.bbappend     | 37 ++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 meta-rcar-gen3/recipes-graphics/wayland/weston_%.bbappend

(limited to 'meta-rcar-gen3/recipes-graphics/wayland/weston_%.bbappend')

diff --git a/meta-rcar-gen3/recipes-graphics/wayland/weston_%.bbappend b/meta-rcar-gen3/recipes-graphics/wayland/weston_%.bbappend
new file mode 100644
index 0000000..18ed8ce
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/wayland/weston_%.bbappend
@@ -0,0 +1,37 @@
+require weston.inc
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+SRC_URI_append = " \
+    file://weston.ini \
+    file://weston.sh \
+"
+
+do_install_append() {
+    install -d ${D}/${sysconfdir}/xdg/weston
+    # install weston.ini as sample settings of gl-renderer
+    install -m 644 ${WORKDIR}/weston.ini ${D}/${sysconfdir}/xdg/weston/
+
+    # Checking for ivi-shell configuration
+    # If ivi-shell is enable, we will add its configs to weston.ini
+    if [ "X${USE_WAYLAND_IVI_SHELL}" = "X1" ]; then
+        sed -i '/repaint-window=34/c\repaint-window=34\nshell=ivi-shell.so' \
+            ${D}/${sysconfdir}/xdg/weston/weston.ini
+        sed -e '$a\\' \
+            -e '$a\[ivi-shell]' \
+            -e '$a\ivi-module=ivi-controller.so' \
+            -e '$a\ivi-input-module=ivi-input-controller.so' \
+            -e '$a\transition-duration=300' \
+            -e '$a\cursor-theme=default' \
+            -i ${D}/${sysconfdir}/xdg/weston/weston.ini
+    fi
+
+    # Set XDG_RUNTIME_DIR to /run/user/$UID (e.g. run/user/0)
+    install -d ${D}/${sysconfdir}/profile.d
+    install -m 0755 ${WORKDIR}/weston.sh ${D}/${sysconfdir}/profile.d/weston.sh
+}
+
+FILES_${PN}_append = " \
+    ${sysconfdir}/xdg/weston/weston.ini \
+    ${sysconfdir}/profile.d/weston.sh \
+"
-- 
cgit 1.2.3-korg