From 2bcde9579e411510547f3da2da9bd9fc0bc6ca6c Mon Sep 17 00:00:00 2001
From: Thao Nguyen <thao.nguyen.yb@renesas.com>
Date: Thu, 9 Nov 2017 13:32:33 +0700
Subject: rcar-gen3: weston: Update to support weston 2.0

This patch updates Renesas weston version from v1.11.0 to v2.0.0.
It also removes the fixes for some old issues which do not exist
in YP 2.4.

Signed-off-by: Thao Nguyen <thao.nguyen.yb@renesas.com>
Signed-off-by: Thuy Tran <thuy.tran.xh@rvc.renesas.com>
Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>
---
 .../recipes-graphics/wayland/weston_2.0.0.bbappend | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 meta-rcar-gen3/recipes-graphics/wayland/weston_2.0.0.bbappend

(limited to 'meta-rcar-gen3/recipes-graphics/wayland/weston_2.0.0.bbappend')

diff --git a/meta-rcar-gen3/recipes-graphics/wayland/weston_2.0.0.bbappend b/meta-rcar-gen3/recipes-graphics/wayland/weston_2.0.0.bbappend
new file mode 100644
index 0000000..ed76e5f
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/wayland/weston_2.0.0.bbappend
@@ -0,0 +1,57 @@
+require weston.inc
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+BRANCH = "rcar-gen3/2.0.0/gl-fallback"
+
+SRCREV = "ad2aea3f8aba60cb1affaf544bd236d6ba2bdb62"
+
+SRC_URI_remove = "https://wayland.freedesktop.org/releases/${BPN}-${PV}.tar.xz"
+
+SRC_URI_append = " \
+    git://github.com/renesas-rcar/weston.git;branch=${BRANCH} \
+    file://weston.png \
+    file://weston.desktop \
+    file://xwayland.weston-start \
+    file://weston.ini \
+    file://weston_v4l2.ini \
+"
+
+S = "${WORKDIR}/git"
+
+PACKAGECONFIG_append = " \
+    ${@base_conditional('USE_MULTIMEDIA', '1', ' v4l2', '', d)} \
+"
+PACKAGECONFIG[v4l2] = " --enable-v4l2, --disable-v4l2,,kernel-module-vsp2driver"
+
+do_install_append() {
+    install -d ${D}/${sysconfdir}/xdg/weston
+    if [ "X${USE_MULTIMEDIA}" = "X1" ]; then
+        # install weston.ini as sample settings of v4l2-renderer
+        if [ "${MACHINE}" = "m3ulcb" -o "${MACHINE}" = "h3ulcb" ] ; then
+            sed -i 's|media1|media0|g' ${WORKDIR}/weston_v4l2.ini
+        fi
+        install -m 644 ${WORKDIR}/weston_v4l2.ini ${D}/${sysconfdir}/xdg/weston/weston.ini
+    else
+        # install weston.ini as sample settings of gl-renderer
+        install -m 644 ${WORKDIR}/weston.ini ${D}/${sysconfdir}/xdg/weston/
+    fi
+
+    # Checking for ivi-shell configuration
+    # If ivi-shell is enable, we will add its configs to weston.ini
+    if [ "X${USE_WAYLAND_IVI_SHELL}" = "X1" ]; then
+        sed -i '/repaint-window=34/c\repaint-window=34\nshell=ivi-shell.so' \
+            ${D}/${sysconfdir}/xdg/weston/weston.ini
+        sed -e '$a\\' \
+            -e '$a\[ivi-shell]' \
+            -e '$a\ivi-module=ivi-controller.so' \
+            -e '$a\ivi-input-module=ivi-input-controller.so' \
+            -e '$a\transition-duration=300' \
+            -e '$a\cursor-theme=default' \
+            -i ${D}/${sysconfdir}/xdg/weston/weston.ini
+    fi
+}
+
+FILES_${PN}_append = " \
+    ${sysconfdir}/xdg/weston/weston.ini \
+"
-- 
cgit 1.2.3-korg