From 1c35920d85e424b3f65aa6df1dbde689dd6ec007 Mon Sep 17 00:00:00 2001
From: Nobuhiro Iwamatsu <nobuhiro.iwamatsu.yj@renesas.com>
Date: Wed, 25 Mar 2015 10:47:45 +0900
Subject: commit BSP v1.8.0

Signed-off-by: Nobuhiro Iwamatsu <nobuhiro.iwamatsu.yj@renesas.com>
---
 .../gstreamer1.0-plugins-base_1.2.3.bbappend       | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 meta-rcar-gen2/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.2.3.bbappend

(limited to 'meta-rcar-gen2/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.2.3.bbappend')

diff --git a/meta-rcar-gen2/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.2.3.bbappend b/meta-rcar-gen2/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.2.3.bbappend
new file mode 100644
index 0000000..eee4b59
--- /dev/null
+++ b/meta-rcar-gen2/recipes-multimedia/gstreamer/gstreamer1.0-plugins-base_1.2.3.bbappend
@@ -0,0 +1,49 @@
+require ../../include/gles-control.inc
+
+SRC_URI_rcar-gen2 = "git://github.com/renesas-devel/gst-plugins-base.git;protocol=git;branch=RCAR-GEN2/1.2.3"
+SRCREV_rcar-gen2 = "f5176e8e2e9b39ee96181c37cf61e2a90e56069b"
+LIC_FILES_CHKSUM_remove_rcar-gen2 = "\
+	file://common/coverage/coverage-report.pl;beginline=2;endline=17;md5=a4e1830fce078028c8f0974161272607"
+
+S = "${WORKDIR}/git"
+
+do_configure() {
+	./autogen.sh --noconfigure
+	oe_runconf
+}
+
+# For Common
+FILESEXTRAPATHS_prepend_rcar-gen2 := '${THISDIR}/${PN}:'
+VSPFILTER_CONFIGS = " \
+    file://gstvspfilter-alt.conf \
+    file://gstvspfilter-gose.conf \
+    file://gstvspfilter-koelsch.conf \
+    file://gstvspfilter-lager.conf \
+    file://gstvspfilter-porter.conf \
+    file://gstvspfilter-silk.conf \
+"
+
+# For wayland
+PACKAGECONFIG_remove_rcar-gen2 = "${@base_contains("DISTRO_FEATURES", "wayland", "orc", "", d)}"
+
+SRC_URI_append_rcar-gen2 = \
+    "${@'${VSPFILTER_CONFIGS}' \
+        if '${USE_WAYLAND}' == '1' else ''}"
+
+EXTRA_OECONF_append_rcar-gen2 = " \
+    ${@'--enable-vspfilter' \
+        if '${USE_WAYLAND}' == '1' else ''}"
+
+do_install_append_rcar-gen2() {
+    if [ '${USE_WAYLAND}' = '1' ] ; then
+        mkdir ${D}/etc/
+        install -m644 ${WORKDIR}/gstvspfilter-${MACHINE}.conf ${D}/etc/gstvspfilter.conf
+    fi
+}
+
+FILES_${PN}_append_rcar-gen2 = " \
+    ${@'${datadir}/gst-plugins-base/1.0/* ${sysconfdir}/*.conf' \
+        if '${USE_WAYLAND}' == '1' else ''}"
+
+# For x11
+# None
-- 
cgit 1.2.3-korg