1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
project('agl-shell-activator',
'c',
version: '0.0.1',
default_options: [
'warning_level=3',
'c_std=gnu99',
],
meson_version: '>= 0.50',
license: 'MIT/Expat',
)
pkgconfig = import('pkgconfig')
cc = meson.get_compiler('c')
add_project_arguments(
cc.get_supported_arguments([
'-Wno-unused-parameter',
'-Wno-pedantic',
'-Wextra',
'-Werror'
]),
language: 'c'
)
add_project_arguments([
'-DPACKAGE_STRING="agl-shell-activator @0@"'.format(meson.project_version()),
'-D_GNU_SOURCE',
'-D_ALL_SOURCE',
],
language: 'c'
)
optional_libc_funcs = [ 'memfd_create', 'strchrnul' ]
foreach func: optional_libc_funcs
if cc.has_function(func)
add_project_arguments('-DHAVE_@0@=1'.format(func.to_upper()), language: 'c')
endif
endforeach
env_modmap = ''
libwayland_dep = dependency('wayland-client')
agl_compositor_dep = dependency('agl-compositor-0.0.20-protocols')
dep_scanner = dependency('wayland-scanner', native: true)
prog_scanner = find_program(dep_scanner.get_pkgconfig_variable('wayland_scanner'))
dep_wp = dependency('wayland-protocols', version: '>= 1.18')
dir_wp_base = dep_wp.get_pkgconfig_variable('pkgdatadir')
dir_agl_compositor_base = agl_compositor_dep.get_pkgconfig_variable('pkgdatadir')
protocols = [
{ 'name': 'agl-shell-desktop', 'source': 'agl-compositor' },
]
foreach proto: protocols
proto_name = proto['name']
if proto['source'] == 'internal'
base_file = proto_name
xml_path = join_paths('protocol', '@0@.xml'.format(base_file))
elif proto['source'] == 'wp-stable'
base_file = proto_name
xml_path = join_paths(dir_wp_base, 'stable', proto_name, '@0@.xml'.format(base_file))
elif proto['source'] == 'agl-compositor'
base_file = proto_name
xml_path = join_paths(dir_agl_compositor_base, '@0@.xml'.format(base_file))
else
base_file = '@0@-unstable-@1@'.format(proto_name, proto['version'])
xml_path = join_paths(dir_wp_base, 'unstable', proto_name, '@0@.xml'.format(base_file))
endif
foreach output_type: [ 'client-header', 'server-header', 'private-code' ]
if output_type == 'client-header'
output_file = '@0@-client-protocol.h'.format(base_file)
elif output_type == 'server-header'
output_file = '@0@-server-protocol.h'.format(base_file)
else
output_file = '@0@-protocol.c'.format(base_file)
if dep_scanner.version().version_compare('< 1.14.91')
output_type = 'code'
endif
endif
var_name = output_file.underscorify()
target = custom_target(
'@0@ @1@'.format(base_file, output_type),
command: [ prog_scanner, output_type, '@INPUT@', '@OUTPUT@' ],
input: xml_path,
output: output_file,
)
set_variable(var_name, target)
endforeach
endforeach
prefix_path = get_option('prefix')
binplugin_dir = join_paths(prefix_path, get_option('bindir'))
common_inc = include_directories('include')
deps_agl_activator = [
libwayland_dep,
]
srcs_agl_activator = [
'src/main.c',
agl_shell_desktop_client_protocol_h,
agl_shell_desktop_protocol_c,
]
exe_wth_receiver = executable(
'agl-shell-activator',
srcs_agl_activator,
include_directories: common_inc,
dependencies: deps_agl_activator,
install_rpath: binplugin_dir,
install: true
)
cp = find_program('cp')
script_target = custom_target('install_script',
command: [ cp, '@INPUT@', '@OUTPUT@' ],
output : 'agl-activator',
input : 'script/agl-activator',
install : true,
install_dir: binplugin_dir,
)
|
