From af1a266670d040d2f4083ff309d732d648afba2a Mon Sep 17 00:00:00 2001
From: Angelos Mouzakitis <a.mouzakitis@virtualopensystems.com>
Date: Tue, 10 Oct 2023 14:33:42 +0000
Subject: Add submodule dependency files

Change-Id: Iaf8d18082d3991dec7c0ebbea540f092188eb4ec
---
 .../common/127 generated assembly/meson.build      | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 meson/test cases/common/127 generated assembly/meson.build

(limited to 'meson/test cases/common/127 generated assembly/meson.build')

diff --git a/meson/test cases/common/127 generated assembly/meson.build b/meson/test cases/common/127 generated assembly/meson.build
new file mode 100644
index 000000000..31a5f17d5
--- /dev/null
+++ b/meson/test cases/common/127 generated assembly/meson.build	
@@ -0,0 +1,66 @@
+project('generated assembly', 'c')
+
+cc = meson.get_compiler('c')
+
+if ['msvc', 'intel-cl'].contains(cc.get_id())
+  error('MESON_SKIP_TEST: assembly files cannot be compiled directly by the compiler')
+endif
+
+if meson.backend() == 'xcode'
+  error('MESON_SKIP_TEST: asm not supported with the Xcode backend. Patches welcome.')
+endif
+
+
+crt_workaround = []
+if cc.get_linker_id() == 'lld-link'
+  # It seems that when building without a .c file, lld-link.exe
+  # misses the fact that it needs to include the c runtime to
+  # make a working .dll. So here we add an empty .c file to easily
+  # pull in crt.
+  crt_workaround += 'empty.c'
+  if host_machine.cpu_family() == 'x86'
+    # x86 assembly needs manual annotation to be compatible with
+    # Safe Exception Handlers (?) This assembly doesn't have such
+    # annotation, so just disable the feature.
+    add_project_link_arguments('/SAFESEH:NO', language : 'c')
+  endif
+endif
+
+cpu = host_machine.cpu_family()
+supported_cpus = ['arm', 'x86', 'x86_64']
+
+if not supported_cpus.contains(cpu)
+  error('MESON_SKIP_TEST: unsupported cpu family: ' + cpu)
+endif
+
+if cc.get_id() == 'clang-cl' and cc.version().version_compare('< 12.0.0') and cpu == 'arm'
+  # https://reviews.llvm.org/D89622
+  error('MESON_SKIP_TEST: arm debug symbols not supported in clang-cl < 12.0.0')
+endif
+
+if cc.symbols_have_underscore_prefix()
+  add_project_arguments('-DMESON_TEST__UNDERSCORE_SYMBOL', language : 'c')
+endif
+
+copy = find_program('copyfile.py')
+output = 'square-@0@.S'.format(cpu)
+input = output + '.in'
+
+copygen = generator(copy,
+  arguments : ['@INPUT@', '@OUTPUT@'],
+  output : '@BASENAME@')
+
+l = library('square-gen', crt_workaround + [copygen.process(input)],
+  vs_module_defs: 'square.def')
+
+test('square-gen-test', executable('square-gen-test', 'main.c', link_with : l))
+
+copyct = custom_target('square',
+  input : input,
+  output : output,
+  command : [copy, '@INPUT@', '@OUTPUT@'])
+
+l = library('square-ct', crt_workaround + [copyct],
+  vs_module_defs: 'square.def')
+
+test('square-ct-test', executable('square-ct-test', 'main.c', link_with : l))
-- 
cgit 1.2.3-korg