From af1a266670d040d2f4083ff309d732d648afba2a Mon Sep 17 00:00:00 2001
From: Angelos Mouzakitis <a.mouzakitis@virtualopensystems.com>
Date: Tue, 10 Oct 2023 14:33:42 +0000
Subject: Add submodule dependency files

Change-Id: Iaf8d18082d3991dec7c0ebbea540f092188eb4ec
---
 .../Library/BaseLib/X64/DisablePaging64.nasm       | 78 ++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 roms/edk2/MdePkg/Library/BaseLib/X64/DisablePaging64.nasm

(limited to 'roms/edk2/MdePkg/Library/BaseLib/X64/DisablePaging64.nasm')

diff --git a/roms/edk2/MdePkg/Library/BaseLib/X64/DisablePaging64.nasm b/roms/edk2/MdePkg/Library/BaseLib/X64/DisablePaging64.nasm
new file mode 100644
index 000000000..c76ed1a76
--- /dev/null
+++ b/roms/edk2/MdePkg/Library/BaseLib/X64/DisablePaging64.nasm
@@ -0,0 +1,78 @@
+;------------------------------------------------------------------------------
+;
+; Copyright (c) 2006 - 2008, Intel Corporation. All rights reserved.<BR>
+; SPDX-License-Identifier: BSD-2-Clause-Patent
+;
+; Module Name:
+;
+;   DisablePaging64.Asm
+;
+; Abstract:
+;
+;   AsmDisablePaging64 function
+;
+; Notes:
+;
+;------------------------------------------------------------------------------
+
+    DEFAULT REL
+    SECTION .text
+
+;------------------------------------------------------------------------------
+; VOID
+; EFIAPI
+; InternalX86DisablePaging64 (
+;   IN      UINT16                    Cs,
+;   IN      UINT32                    EntryPoint,
+;   IN      UINT32                    Context1,  OPTIONAL
+;   IN      UINT32                    Context2,  OPTIONAL
+;   IN      UINT32                    NewStack
+;   );
+;------------------------------------------------------------------------------
+global ASM_PFX(InternalX86DisablePaging64)
+ASM_PFX(InternalX86DisablePaging64):
+    cli
+    lea     rsi, [.0]                     ; rsi <- The start address of transition code
+    mov     edi, [rsp + 0x28]            ; rdi <- New stack
+    lea     rax, [mTransitionEnd]         ; rax <- end of transition code
+    sub     rax, rsi                    ; rax <- The size of transition piece code
+    add     rax, 4                      ; Round RAX up to the next 4 byte boundary
+    and     al, 0xfc
+    sub     rdi, rax                    ; rdi <- Use stack to hold transition code
+    mov     r10d, edi                   ; r10 <- The start address of transicition code below 4G
+    push    rcx                         ; save rcx to stack
+    mov     rcx, rax                    ; rcx <- The size of transition piece code
+    rep     movsb                       ; copy transition code to top of new stack which must be below 4GB
+    pop     rcx                         ; restore rcx
+
+    mov     esi, r8d
+    mov     edi, r9d
+    mov     eax, r10d                   ; eax <- start of the transition code on the stack
+    sub     eax, 4                      ; eax <- One slot below transition code on the stack
+    push    rcx                         ; push Cs to stack
+    push    r10                         ; push address of tansition code on stack
+    DB      0x48                         ; prefix to composite "retq" with next "retf"
+    retf                                ; Use far return to load CS register from stack
+
+; Start of transition code
+.0:
+    mov     esp, eax                    ; set up new stack
+    mov     rax, cr0
+    btr     eax, 31                     ; Clear CR0.PG
+    mov     cr0, rax                    ; disable paging and caches
+
+    mov     ebx, edx                    ; save EntryPoint to rbx, for rdmsr will overwrite rdx
+    mov     ecx, 0xc0000080
+    rdmsr
+    and     ah, ~ 1                   ; clear LME
+    wrmsr
+    mov     rax, cr4
+    and     al, ~ (1 << 5)           ; clear PAE
+    mov     cr4, rax
+    push    rdi                         ; push Context2
+    push    rsi                         ; push Context1
+    call    rbx                         ; transfer control to EntryPoint
+    hlt                                 ; no one should get here
+
+mTransitionEnd:
+
-- 
cgit 1.2.3-korg