From 4204309872da5cb401cbb2729d9e2d4869a87f42 Mon Sep 17 00:00:00 2001
From: takeshi_hoshina <takeshi_hoshina@mail.toyota.co.jp>
Date: Thu, 22 Oct 2020 14:58:56 +0900
Subject: agl-basesystem 0.1

---
 .../linux/linux-imx-headers_4.14.x.bb              | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 bsp/meta-boundary/recipes-kernel/linux/linux-imx-headers_4.14.x.bb

(limited to 'bsp/meta-boundary/recipes-kernel/linux/linux-imx-headers_4.14.x.bb')

diff --git a/bsp/meta-boundary/recipes-kernel/linux/linux-imx-headers_4.14.x.bb b/bsp/meta-boundary/recipes-kernel/linux/linux-imx-headers_4.14.x.bb
new file mode 100644
index 00000000..2040c02f
--- /dev/null
+++ b/bsp/meta-boundary/recipes-kernel/linux/linux-imx-headers_4.14.x.bb
@@ -0,0 +1,58 @@
+# Copyright 2017-2018 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Installs i.MX-specific kernel headers"
+DESCRIPTION = "Installs i.MX-specific kernel headers to userspace. \
+New headers are installed in ${includedir}/imx."
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
+
+LOCALVERSION = "-imx"
+SRC_URI = "git://github.com/boundarydevices/linux-imx6.git;branch=${SRCBRANCH}"
+SRCBRANCH = "boundary-imx_4.14.x_2.0.0_ga"
+SRCREV = "${AUTOREV}"
+
+S = "${WORKDIR}/git"
+
+do_compile[noexec] = "1"
+
+IMX_UAPI_HEADERS = " \
+    dma-buf.h \
+    hantrodec.h \
+    hx280enc.h \
+    ion.h \
+    ipu.h \
+    isl29023.h \
+    mxc_asrc.h \
+    mxc_dcic.h \
+    mxc_mlb.h \
+    mxc_sim_interface.h \
+    mxc_v4l2.h \
+    mxcfb.h \
+    pxp_device.h \
+    pxp_dma.h \
+    version.h \
+    videodev2.h \
+"
+
+do_install() {
+    # We install all headers inside of B so we can copy only the
+    # whitelisted ones, and there is no risk of a new header to be
+    # installed by mistake.
+    oe_runmake headers_install INSTALL_HDR_PATH=${B}${exec_prefix}
+
+    # FIXME: The ion.h is still on staging so "promote" it for now
+    cp ${S}/drivers/staging/android/uapi/ion.h ${B}${includedir}/linux
+
+    # Install whitelisted headers only
+    for h in ${IMX_UAPI_HEADERS}; do
+        install -D -m 0644 ${B}${includedir}/linux/$h \
+	                   ${D}${includedir}/imx/linux/$h
+    done
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_HOST_imx = ".*"
+COMPATIBLE_HOST ?= "(none)"
-- 
cgit 1.2.3-korg