From 1c7d6584a7811b7785ae5c1e378f14b5ba0971cf Mon Sep 17 00:00:00 2001
From: takeshi_hoshina <takeshi_hoshina@mail.toyota.co.jp>
Date: Mon, 2 Nov 2020 11:07:33 +0900
Subject: basesystem-jj recipes

---
 .../recipes-bsp/bootfiles/bootfiles.bb             | 43 ++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 bsp/meta-raspberrypi/recipes-bsp/bootfiles/bootfiles.bb

(limited to 'bsp/meta-raspberrypi/recipes-bsp/bootfiles/bootfiles.bb')

diff --git a/bsp/meta-raspberrypi/recipes-bsp/bootfiles/bootfiles.bb b/bsp/meta-raspberrypi/recipes-bsp/bootfiles/bootfiles.bb
new file mode 100644
index 00000000..80e226d4
--- /dev/null
+++ b/bsp/meta-raspberrypi/recipes-bsp/bootfiles/bootfiles.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "Closed source binary files to help boot all raspberry pi devices."
+LICENSE = "Broadcom-RPi"
+
+LIC_FILES_CHKSUM = "file://LICENCE.broadcom;md5=c403841ff2837657b2ed8e5bb474ac8d"
+
+inherit deploy nopackages
+
+include recipes-bsp/common/raspberrypi-firmware.inc
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+DEPENDS = "rpi-config"
+
+COMPATIBLE_MACHINE = "^rpi$"
+
+S = "${RPIFW_S}/boot"
+
+PR = "r3"
+
+do_deploy() {
+    install -d ${DEPLOYDIR}/${PN}
+
+    for i in ${S}/*.elf ; do
+        cp $i ${DEPLOYDIR}/${PN}
+    done
+    for i in ${S}/*.dat ; do
+        cp $i ${DEPLOYDIR}/${PN}
+    done
+    for i in ${S}/*.bin ; do
+        cp $i ${DEPLOYDIR}/${PN}
+    done
+
+    # Add stamp in deploy directory
+    touch ${DEPLOYDIR}/${PN}/${PN}-${PV}.stamp
+}
+
+do_deploy[depends] += "rpi-config:do_deploy"
+
+addtask deploy before do_build after do_install
+do_deploy[dirs] += "${DEPLOYDIR}/${PN}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
-- 
cgit 1.2.3-korg