From 5b80bfd7bffd4c20d80b7c70a7130529e9a755dd Mon Sep 17 00:00:00 2001
From: ToshikazuOhiwa <toshikazu_ohiwa@mail.toyota.co.jp>
Date: Mon, 30 Mar 2020 09:24:26 +0900
Subject: agl-basesystem

---
 .../meta-oe/recipes-support/gpm/gpm_git.bb         | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 external/meta-openembedded/meta-oe/recipes-support/gpm/gpm_git.bb

(limited to 'external/meta-openembedded/meta-oe/recipes-support/gpm/gpm_git.bb')

diff --git a/external/meta-openembedded/meta-oe/recipes-support/gpm/gpm_git.bb b/external/meta-openembedded/meta-oe/recipes-support/gpm/gpm_git.bb
new file mode 100644
index 00000000..dcc9d68e
--- /dev/null
+++ b/external/meta-openembedded/meta-oe/recipes-support/gpm/gpm_git.bb
@@ -0,0 +1,47 @@
+DESCRIPTION = "GPM (General Purpose Mouse) is a mouse server \
+for the console and xterm, with sample clients included \
+(emacs, etc)."
+SECTION = "console/utils"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=18810669f13b87348459e611d31ab760"
+
+PV = "1.99.7+git${SRCREV}"
+PR = "r2"
+SRCREV = "1fd19417b8a4dd9945347e98dfa97e4cfd798d77"
+
+DEPENDS = "ncurses bison-native"
+
+SRC_URI = "git://github.com/telmich/gpm;protocol=git \
+           file://init \
+           file://no-docs.patch \
+           file://processcreds.patch \
+           file://gpm.service.in \
+           file://0001-Use-sigemptyset-API-instead-of-__sigemptyset.patch \
+           "
+
+S = "${WORKDIR}/git"
+
+inherit autotools-brokensep update-rc.d systemd
+
+INITSCRIPT_NAME = "gpm"
+INITSCRIPT_PARAMS = "defaults"
+
+do_configure_prepend() {
+    (cd ${S};./autogen.sh;cd -)
+}
+
+do_install_append () {
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+        install -d ${D}${systemd_system_unitdir}
+        sed 's:@bindir@:${bindir}:' < ${WORKDIR}/gpm.service.in >${D}${systemd_system_unitdir}/gpm.service
+    fi
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+        install -D -m 0755 ${WORKDIR}/init ${D}/${sysconfdir}/init.d/gpm
+    fi
+    install -D -m 0644 ${S}/src/headers/gpm.h ${D}${includedir}/gpm.h
+    ln -s libgpm.so.2 ${D}${libdir}/libgpm.so
+}
+
+SYSTEMD_SERVICE_${PN} = "gpm.service"
+
+FILES_${PN} += "${datadir}/emacs"
-- 
cgit 1.2.3-korg