From 1c7d6584a7811b7785ae5c1e378f14b5ba0971cf Mon Sep 17 00:00:00 2001
From: takeshi_hoshina <takeshi_hoshina@mail.toyota.co.jp>
Date: Mon, 2 Nov 2020 11:07:33 +0900
Subject: basesystem-jj recipes

---
 .../recipes-xfce/xfce4-panel/xfce4-panel_4.14.4.bb | 41 ++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 external/meta-openembedded/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.14.4.bb

(limited to 'external/meta-openembedded/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.14.4.bb')

diff --git a/external/meta-openembedded/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.14.4.bb b/external/meta-openembedded/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.14.4.bb
new file mode 100644
index 00000000..73cb82a1
--- /dev/null
+++ b/external/meta-openembedded/meta-xfce/recipes-xfce/xfce4-panel/xfce4-panel_4.14.4.bb
@@ -0,0 +1,41 @@
+SUMMARY = "Xfce4 Panel"
+SECTION = "x11"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=26a8bd75d8f8498bdbbe64a27791d4ee"
+DEPENDS = "garcon exo gtk+3 cairo virtual/libx11 libxml2 libwnck3 vala-native"
+
+inherit xfce gtk-doc gobject-introspection features_check remove-libtool mime-xdg
+
+REQUIRED_DISTRO_FEATURES = "x11"
+
+SRC_URI[md5sum] = "76efdbf7fb461f3058919c1309da67ca"
+SRC_URI[sha256sum] = "8e5ea79412ba84cfada897ff309cbe2cd4aca16b9bd4f93df060229528576fd5"
+SRC_URI += " \
+    file://0001-windowmenu-do-not-display-desktop-icon-when-no-windo.patch \
+    file://0002-use-lxdm-to-replace-dm-tool.patch \
+"
+
+python populate_packages_prepend() {
+    plugin_dir = d.expand('${libdir}/xfce4/panel/plugins/')
+    plugin_name = d.expand('${PN}-plugin-%s')
+    do_split_packages(d, plugin_dir, '^lib(.*).so$', plugin_name,
+                      '${PN} plugin for %s', extra_depends='', prepend=True,
+                      aux_files_pattern=['${datadir}/xfce4/panel/plugins/%s.desktop',
+                                         '${sysconfdir}/xdg/xfce/panel/%s-*',
+                                         '${datadir}/icons/hicolor/48x48/apps/*-%s.png',
+                                         '${bindir}/*%s*'])
+}
+
+PACKAGES_DYNAMIC += "^${PN}-plugin-.*"
+
+PACKAGES =+ "${PN}-gtk3"
+
+FILES_${PN} += "${libdir}/xfce4/panel/migrate \
+                ${libdir}/xfce4/panel/wrapper-1.0"
+
+FILES_${PN}-dev += "${libdir}/xfce4/panel/plugins/*.la"
+
+FILES_${PN}-gtk3 = " \
+    ${libdir}/libxfce4panel-2.0${SOLIBS} \
+    ${libdir}/xfce4/panel/wrapper-2.0 \
+"
-- 
cgit 1.2.3-korg