Rework cluster demo configuration

Changes:
- Rename cluster-dashboard-demo-config to cluster-demo-config since
  the installed AGL.conf will also be used for receiver configuration
  now.
- Add a Flutter cluster version of AGL.conf that configures the
  receiver window geometry as required.  The alternative mechanism
  is used to generate separate packages with the different AGL.conf
  files.
- Update the package names installed by agl-demo-preload in the Qt
  and Flutter cluster demo images.

It may make sense to do further rework in the dashboard and receiver
apps post-CES to split things into separate configuration files, but
this seems the most straightforward way to do things for now.

Bug-AGL: SPEC-4640

Change-Id: If8a65228c75f28a53ef32a49be90f75a85d60a16
Signed-off-by: Scott Murray <scott.murray@konsulko.com>

6 files changed, 35 insertions, 12 deletions

diff --git a/recipes-config/cluster-dashboard-demo-config/cluster-dashboard-demo-config_1.0.bb b/recipes-config/cluster-dashboard-demo-config/cluster-dashboard-demo-config_1.0.bb
deleted file mode 100644
index f1fce78f8..000000000
--- a/recipes-config/cluster-dashboard-demo-config/cluster-dashboard-demo-config_1.0.bb
+++ /dev/null
@@ -1,11 +0,0 @@
-SUMMARY = "AGL cluster demo dashboard configuration file"
-LICENSE = "MIT"
-LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-
-SRC_URI += "file://AGL.conf.cluster"
-
-inherit allarch
-
-do_install() {
-    install -D -m 0644 ${WORKDIR}/AGL.conf.cluster ${D}${sysconfdir}/xdg/AGL.conf
-}
diff --git a/recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb b/recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb
new file mode 100644
index 000000000..48b7965e4
--- /dev/null
+++ b/recipes-config/cluster-demo-config/cluster-demo-config_1.0.bb
@@ -0,0 +1,31 @@
+SUMMARY = "AGL cluster demo configuration file"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI += " \
+    file://AGL.conf.default \
+    file://AGL.conf.flutter \
+"
+
+inherit allarch update-alternatives
+
+do_install() {
+    install -D -m 0644 ${WORKDIR}/AGL.conf.default ${D}${sysconfdir}/xdg/AGL.conf.default
+    install -m 0644 ${WORKDIR}/AGL.conf.flutter ${D}${sysconfdir}/xdg/ 
+}
+
+ALTERNATIVE_LINK_NAME[AGL.conf] = "${sysconfdir}/xdg/AGL.conf"
+
+PACKAGE_BEFORE_PN += "${PN}-flutter"
+
+FILES:${PN} += "${sysconfdir}/xdg/AGL.conf.default"
+RPROVIDES:${PN} = "AGL.conf"
+RCONFLICTS:${PN} = "${PN}-flutter"
+ALTERNATIVE:${PN} = "AGL.conf"
+ALTERNATIVE_TARGET_${PN} = "${sysconfdir}/xdg/AGL.conf.default"
+
+FILES:${PN}-flutter += "${sysconfdir}/xdg/AGL.conf.flutter"
+RPROVIDES:${PN}-flutter = "AGL.conf"
+RCONFLICTS:${PN}-flutter = "${PN}"
+ALTERNATIVE:${PN}-flutter = "AGL.conf"
+ALTERNATIVE_TARGET_${PN}-flutter = "${sysconfdir}/xdg/AGL.conf.flutter"
diff --git a/recipes-config/cluster-dashboard-demo-config/files/AGL.conf.cluster b/recipes-config/cluster-demo-config/files/AGL.conf.default
index dd8a912c5..dd8a912c5 100644
--- a/recipes-config/cluster-dashboard-demo-config/files/AGL.conf.cluster
+++ b/recipes-config/cluster-demo-config/files/AGL.conf.default
diff --git a/recipes-config/cluster-demo-config/files/AGL.conf.flutter b/recipes-config/cluster-demo-config/files/AGL.conf.flutter
new file mode 100644
index 000000000..dbd9f370b
--- /dev/null
+++ b/recipes-config/cluster-demo-config/files/AGL.conf.flutter
@@ -0,0 +1,2 @@
+[receiver]
+geometry=420x472+750,290
diff --git a/recipes-platform/images/agl-cluster-demo-platform-flutter.bb b/recipes-platform/images/agl-cluster-demo-platform-flutter.bb
index cb088ee88..a0314f2f4 100644
--- a/recipes-platform/images/agl-cluster-demo-platform-flutter.bb
+++ b/recipes-platform/images/agl-cluster-demo-platform-flutter.bb
@@ -33,6 +33,7 @@ IMAGE_INSTALL:append = "\
 # Flutter
 IMAGE_INSTALL:append = "\
     flutter-cluster-dashboard \
+    ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "cluster-demo-config-flutter", "", d)} \
     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "flutter-cluster-dashboard-conf-demo", "flutter-cluster-dashboard-conf", d)} \
     flutter-auto-runtimerelease \
     "
diff --git a/recipes-platform/images/agl-cluster-demo-platform.bb b/recipes-platform/images/agl-cluster-demo-platform.bb
index d5c92742f..f11d883c3 100644
--- a/recipes-platform/images/agl-cluster-demo-platform.bb
+++ b/recipes-platform/images/agl-cluster-demo-platform.bb
@@ -13,6 +13,6 @@ REQUIRED_DISTRO_FEATURES = "wayland"
 # add packages for cluster demo platform (include demo apps) here
 IMAGE_INSTALL:append = " \
     packagegroup-agl-cluster-demo-platform \
-    ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "cluster-dashboard-demo-config", "", d)} \
+    ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "cluster-demo-config", "", d)} \
     ${@bb.utils.contains("AGL_FEATURES", "agl-demo-preload", "weston-ini-conf-landscape-inverted", "weston-ini-conf-landscape", d)} \
     "