agl-qemu-runner: Add recipes

Add recipes for agl-qemu-runner.sh QEMU wrapper script and template
systemd unit, and guest per-image configuration files and systemd
unit links for the various demo platform images.  The configurations
for the demo images can be mixed and matched somewhat, but only one
each of IVI and cluster should be used, as there are some static CPU
assignments in the configurations.  As well, this has only been
tested on the AGL reference hardware at present, some rework will
likely be required to support other platforms.

There is room to add a bbclass to simplify the guest configuration
recipes, but that has not been done for now as this approach may be
temporary; a switch to libvirtd with appropriate configurations is
likely.

Bug-AGL: SPEC-4618

Change-Id: Ieefbd4081cca506f915957cc313411a5ed1ece5c
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
(cherry picked from commit dce8116fb1a1b6f3c2976db126d9f923e2fe4c6f)

1 files changed, 29 insertions, 0 deletions

diff --git a/recipes-config/qemu-config/qemu-config-agl-ivi-demo-platform-flutter.bb b/recipes-config/qemu-config/qemu-config-agl-ivi-demo-platform-flutter.bb
new file mode 100644
index 000000000..5efb7a96c
--- /dev/null
+++ b/recipes-config/qemu-config/qemu-config-agl-ivi-demo-platform-flutter.bb
@@ -0,0 +1,29 @@
+SUMMARY     = "Setting files for agl-ivi-demo-plaform-flutter guest VM"
+LICENSE     = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+inherit systemd allarch
+
+SRC_URI = "file://${QEMU_IMAGE}.conf"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+QEMU_IMAGE = "agl-ivi-demo-platform-flutter"
+QEMU_UNIT = "agl-qemu-runner@${QEMU_IMAGE}.service"
+
+do_install() {
+    # Install template unit links
+    install -d ${D}${systemd_system_unitdir}
+    ln -sf agl-qemu-runner@.service ${D}${systemd_system_unitdir}/${QEMU_UNIT}
+    install -d ${D}${systemd_system_unitdir}/multi-user.target.wants
+    ln -sf ${systemd_system_unitdir}/${QEMU_UNIT} ${D}${systemd_system_unitdir}/multi-user.target.wants/${QEMU_UNIT}
+
+    # Install conf file
+    install -d ${D}${sysconfdir}/agl-qemu-runner
+    install -m 0644 ${WORKDIR}/${QEMU_IMAGE}.conf ${D}${sysconfdir}/agl-qemu-runner/
+}
+
+FILES:${PN} += "${systemd_system_unitdir}"
+
+RDEPENDS:${PN} += "agl-qemu-runner"