Rework guest network configuration for QEMU+KVM demo

Changes:
- Tweak agl-qemu-runner to make network options configurable.
- Add qemu-config-vmnet0 recipe that installs the required
  configuration files to set up a vmnet0 bridge device for QEMU to
  add the guests to, and to run dnsmasq against it to provide set
  IPs (in 172.16.10.0/8) to known MAC addresses that can be used to
  get the IVI and IC guests at stable IP addresses.
- As part of the above, disable connman DNS proxying to avoid
  conflicting with dnsmasq.  This does mean this package should
  only be used for simple host images where applications can live
  with less dynamic DNS configuration behavior.
- Update the various guest configuration files for agl-qemu-runner
  to set the new QEMU_NET_OPT variable as required.

Bug-AGL: SPEC-4618

Change-Id: I81d2ea9f0605a8bca7ac17d6e8f33c0b1a9f2c46
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
(cherry picked from commit 0219e6547b627f45936599fa54e02cad27dee4f4)

1 files changed, 41 insertions, 0 deletions

diff --git a/recipes-config/qemu-config/qemu-config-vmnet0.bb b/recipes-config/qemu-config/qemu-config-vmnet0.bb
new file mode 100644
index 00000000..bc634bf3
--- /dev/null
+++ b/recipes-config/qemu-config/qemu-config-vmnet0.bb
@@ -0,0 +1,41 @@
+SUMMARY     = "Setting files for QEMU networking for guest VMs"
+LICENSE     = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+inherit systemd allarch
+
+SRC_URI = "file://vmnet0.netdev \
+           file://vmnet0.network \
+	   file://bridge.conf \
+	   file://dnsmasq-qemu.conf \
+	   file://connman-nodnsproxy.conf \
+"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+QEMU_IMAGE = "agl-cluster-demo-platform"
+QEMU_UNIT = "agl-qemu-runner@${QEMU_IMAGE}.service"
+
+do_install() {
+    # Install systemd-networkd vmnet0 configuration
+    install -d ${D}${systemd_unitdir}/network
+    install -m 0644 ${WORKDIR}/vmnet0.netdev ${D}${systemd_unitdir}/network/
+    install -m 0644 ${WORKDIR}/vmnet0.network ${D}${systemd_unitdir}/network/
+
+    # Install QEMU bridge configuration
+    install -d ${D}${sysconfdir}/qemu
+    install -m 0644 ${WORKDIR}/bridge.conf ${D}${sysconfdir}/qemu/
+
+    # Configure dnsmasq to serve DHCP to the guests
+    install -d ${D}${sysconfdir}/dnsmasq.d
+    install -m 0644 ${WORKDIR}/dnsmasq-qemu.conf ${D}${sysconfdir}/dnsmasq.d/
+
+    # Disable ConnMan's local DNS proxy to not conflict with dnsmasq
+    install -d ${D}${systemd_system_unitdir}/connman.service.d/
+    install -m 0644 ${WORKDIR}/connman-nodnsproxy.conf ${D}${systemd_system_unitdir}/connman.service.d/    
+}
+
+FILES:${PN} += "${systemd_unitdir}/network ${systemd_system_unitdir}"
+
+RDEPENDS:${PN} += "agl-qemu-runner dnsmasq connman"