Add gateway demo

Changes:
- Add recipe for AGL VSS to MQTT proxy daemon
- Update agl-vcar.dbc CAN database definition to add signals useful
  for demoing the proxy (per V2C EG discussion).
- Add a patch to kuksa-dbc-feeder to allow sensor signal updates to
  generate CAN messages in output mode.
- Add VSS vspec variants to define the desired CAN input and output
  support for the various kuksa-dbc-feeder instances in the default
  and full gateway demos.
- Add configurations for kuksa-dbc-feeder for the running the default
  gateway demo with CAN output from a demo control panel instance on
  a single CAN interface, as well as a fuller setup with a second
  kuksa-dbc-feeder running against a second CAN interface on the
  gateway to handle the demo steering wheel and HVAC support.
- Add gateway demo specific configuration files for various KUKSA.val
  databroker clients to override the databroker location.
- Add agl-gateway-demo and agl-gateway-demo-preconfigured images for
  the default and full demos.
- Add *-preconfigured-gateway image flavors for the Flutter IVI, IC,
  and KVM demo images that support running with the databroker on
  the gateway.

NOTES:
- The *-preconfigured-gateway images assume the gateway has an IP
  address of 192.168.10.4.
- Required changes to the agl-demo-control-panel application and the
  addition of a agl-ivi-demo-control-panel-preconfigured-gateway
  image will come in a subsequent change.

Bug-AGL: SPEC-5107, SPEC-5138

Change-Id: I9797aa72737af7af3d791a5151198f80b6d90e0d
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Reviewed-on: https://gerrit.automotivelinux.org/gerrit/c/AGL/meta-agl-demo/+/29906
Tested-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Reviewed-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb b/recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb
new file mode 100644
index 000000000..b16116e65
--- /dev/null
+++ b/recipes-connectivity/agl-vss-proxy/agl-vss-proxy_git.bb
@@ -0,0 +1,47 @@
+SUMMARY     = "AGL VSS Proxy"
+DESCRIPTION = "AGL VSS Proxy"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-vss-proxy"
+
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = " \
+    glib-2.0 \
+    yaml-cpp \
+    protobuf-native \
+    grpc-native \
+    protobuf \
+    grpc \
+    kuksa-databroker \
+    mosquitto \
+"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/agl-vss-proxy;protocol=https;branch=${AGL_BRANCH} \
+           file://agl-vss-proxy.token \
+"
+SRCREV  = "e437300d0b5c20114ea1843dbf00815304af3f27"
+
+PV = "1.0+git${SRCPV}"
+S  = "${WORKDIR}/git"
+
+inherit meson pkgconfig systemd
+
+EXTRA_OEMESON += "-Dprotos=${STAGING_INCDIR}"
+
+SYSTEMD_SERVICE:${PN} = "agl-vss-proxy.service"
+
+do_install:append() {
+    # Currently using default global client and CA certificates
+    # for KUKSA.val SSL, installing app specific ones would go here.
+
+    # VIS authorization token file for KUKSA.val should ideally not
+    # be readable by other users, but currently that's not doable
+    # until a packaging/sandboxing/MAC scheme is (re)implemented or
+    # something like OAuth is plumbed in as an alternative.
+    install -d ${D}${sysconfdir}/agl-vss-proxy
+    install -m 0644 ${WORKDIR}/agl-vss-proxy.token ${D}${sysconfdir}/agl-vss-proxy/
+}
+
+FILES:${PN} += "${systemd_system_unitdir}"
+
+RDEPENDS:${PN} += "kuksa-databroker kuksa-databroker-agl"