Add demo specific KUKSA.val configuration

Add kuksa-val-agl and kuksa-val-agl-demo-cluster recipes that install
extra configuration for KUKSA.val for the AGL demo platform.

Changes:
- Add kuksa-val-agl recipe to install AGL specific signals overlay
  and uses a new environment variable hook in the kuksa-val systemd
  unit to pass the required --overlays option to pick it up.
- Add kuksa-val-agl-demo-cluster recipe to install cluster support
  specific kuksa-val environment file that makes kuksa-val-server
  listen on all addresses.  This is hopefully a stop gap approach
  for the cluster demo until support for listening on multiple
  addresses is added upstream.
- Add kuksa-val-agl to packagegroup-agl-ivi-services to enable the
  AGL specific signals in the demo images.
- Add kuksa-val-agl-demo-cluster to packagegroup-agl-demo-cluster-support
  to pick it up when the agl-demo-cluster-support feature is used
  to build an image for the full AGL demo setup.

Bug-AGL: SPEC-4405

Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Change-Id: I9f847a2520bc55be6d994a45bc8815b86ec1d1ae

1 files changed, 27 insertions, 0 deletions

diff --git a/recipes-connectivity/kuksa-val/kuksa-val-agl.bb b/recipes-connectivity/kuksa-val/kuksa-val-agl.bb
new file mode 100644
index 000000000..1614c5fbd
--- /dev/null
+++ b/recipes-connectivity/kuksa-val/kuksa-val-agl.bb
@@ -0,0 +1,27 @@
+SUMMARY = "AGL demo signal overlay for KUKSA.val, the KUKSA Vehicle Abstraction Layer"
+HOMEPAGE = "https://github.com/eclipse/kuksa.val"
+BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI = "file://00-agl_vss_overlay_2.2.json \
+           file://kuksa-val.env \
+"
+
+inherit allarch update-alternatives
+
+do_install() {
+    install -d ${D}${sysconfdir}/default
+    install -m 0644 ${WORKDIR}/kuksa-val.env ${D}${sysconfdir}/default/kuksa-val.agl
+    install -d ${D}${datadir}/kuksa-val/overlays
+    install -m 0644 ${WORKDIR}/00-agl_vss_overlay_2.2.json ${D}${datadir}/kuksa-val/overlays/
+}
+
+FILES:${PN} += "${datadir}/kuksa-val/overlays"
+
+ALTERNATIVE:${PN} = "kuksa-val-env"
+ALTERNATIVE_LINK_NAME[kuksa-val-env] = "${sysconfdir}/default/kuksa-val"
+ALTERNATIVE_TARGET[kuksa-val-env] = "${sysconfdir}/default/kuksa-val.agl"
+
+RDEPENDS:${PN} += "kuksa-val"