Move base VSS and KUKSA.val recipes to meta-agl-kuksa-val

Remove base VSS and KUKSA.val recipes, as they are moving to a new
meta-agl-kuksa-val layer in the meta-agl repository.  The recipes
for the Python modules they depend on have also been moved.

Additional changes:
- A new kuksa-can-provider-conf-agl recipe has been added to install
  our common AGL-specific kuksa-can-provider configuration.  The
  intent is that the kuksa-can-provider in meta-agl-kuksa-val not be
  dependent on our demo configuration choices.
- The other kuksa-can-provider configuration recipes have been
  tweaked to mark them as allarch.
- The python3-argparse-addons recipe and python3-cantools bbappend
  that used it have been removed, as it looks like it is no longer
  required.
- The dangling kuksa-val-agl-demo-cluster recipe has been removed,
  it was missed in the previous kuksa-val server removal.

Bug-AGL: SPEC-5136

Change-Id: I8c5aa556a796852c5ee3d8c26e045a089911f37e
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Reviewed-on: https://gerrit.automotivelinux.org/gerrit/c/AGL/meta-agl-demo/+/30038
Reviewed-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
ci-image-build: Jenkins Job builder account
ci-image-boot-test: Jenkins Job builder account
Tested-by: Jenkins Job builder account

1 files changed, 0 insertions, 43 deletions

diff --git a/recipes-connectivity/vss/vss_4.2.bb b/recipes-connectivity/vss/vss_4.2.bb
deleted file mode 100644
index 053516629..000000000
--- a/recipes-connectivity/vss/vss_4.2.bb
+++ /dev/null
@@ -1,43 +0,0 @@
-SUMMARY = "Vehicle Signal Specification"
-LICENSE = "MPL-2.0"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
-
-DEPENDS = "vss-tools-native"
-
-inherit allarch update-alternatives
-
-require vss.inc
-
-UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
-
-S = "${WORKDIR}/git"
-
-do_configure[noexec] = "1"
-
-EXTRA_OEMAKE = "TOOLSDIR=${STAGING_BINDIR_NATIVE}"
-
-do_compile() {
-    oe_runmake json
-}
-
-do_install() {
-    # Cannot use the "install" target in the project Makefile, as it is
-    # intended for setting the repo up for builds.
-    # For now, just the generated JSON is installed. It is possible that
-    # installing the vspec files somewhere as a development package may
-    # be useful, but for now things will be kept simple.
-    install -d ${D}${datadir}/vss
-    install -m 0644 ${S}/vss_rel_${PV}.json ${D}${datadir}/vss/
-}
-
-# NOTE:
-# A virtual RPROVIDES is not used for now, as packages such as KUKSA.val
-# provide their own copies of the VSS JSON, so we can install this one
-# and any alternatives in parallel and point e.g. KUKSA.val at the desired
-# file with a configuration change. This may be worth revisiting down the
-# road.
-
-ALTERNATIVE_LINK_NAME[vss.json] = "${datadir}/vss/vss.json"
-
-ALTERNATIVE:${PN} = "vss.json"
-ALTERNATIVE_TARGET_${PN} = "${datadir}/vss/vss_rel_${PV}.json"