SPEC-3723: restructure meta-agl-demo

All demo related components should be in here now.

We keep the packagegroups on purpose for now to stay backward-compatible.

v2: layer does pass yocto-check-layer, dependencies adapted
v3: remove the dynamic-layer setup, use all-in-one approach
v4: Fixed comments from Paul Barker. Tnx!
v5: Removed wayland/weston/agl-compositor additions, except for demo
    specific weston-init bbappend

Follow-up changes required later:
      - massaging packagegroups
      - scrub of recipes

Bug-AGL: SPEC-3723

Signed-off-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Change-Id: I47cefd8c23d46b2cdd063470e3f7d97d5ad952d8

18 files changed, 208 insertions, 12 deletions

diff --git a/recipes-graphics/hmi-debug/files/hmi-debug b/recipes-graphics/hmi-debug/files/hmi-debug
new file mode 100644
index 000000000..fee9573b7
--- /dev/null
+++ b/recipes-graphics/hmi-debug/files/hmi-debug
@@ -0,0 +1,8 @@
+#You can select log level of HMI framework
+#1 ERROR
+#2 WARNING
+#3 NOTICE
+#4 INFO
+#5 DEBUG
+#If you want to output debug log about hmi-framework, please uncomment the following.
+#USE_HMI_DEBUG=5
diff --git a/recipes-graphics/hmi-debug/hmi-debug_git.bb b/recipes-graphics/hmi-debug/hmi-debug_git.bb
new file mode 100644
index 000000000..27fb60d66
--- /dev/null
+++ b/recipes-graphics/hmi-debug/hmi-debug_git.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "Configurations for HMI framework"
+
+SECTION = "HMI"
+LICENSE = "Apache-2.0"
+
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+
+SRC_URI = " \
+    file://hmi-debug \
+"
+
+FILES_${PN} = " \
+    ${sysconfdir}/afm/unit.env.d \
+"
+
+do_install() {
+    install -d ${D}${sysconfdir}/afm/unit.env.d
+    install -m 644 ${WORKDIR}/hmi-debug ${D}${sysconfdir}/afm/unit.env.d
+}
diff --git a/recipes-graphics/kms-conf/kms-conf/kms.conf b/recipes-graphics/kms-conf/kms-conf/kms.conf
new file mode 100644
index 000000000..7fa9686e2
--- /dev/null
+++ b/recipes-graphics/kms-conf/kms-conf/kms.conf
@@ -0,0 +1,8 @@
+{
+    "device": "/dev/dri/card0",
+    "outputs": [
+      {
+        "name":"HDMI-A-1"
+      }
+    ]
+}
diff --git a/recipes-graphics/kms-conf/kms-conf/m3ulcb/kms.conf b/recipes-graphics/kms-conf/kms-conf/m3ulcb/kms.conf
new file mode 100644
index 000000000..16ea328f2
--- /dev/null
+++ b/recipes-graphics/kms-conf/kms-conf/m3ulcb/kms.conf
@@ -0,0 +1,12 @@
+{
+    "device": "/dev/dri/card0",
+    "outputs": [
+      {
+        "name":"HDMI-A-1"
+      },
+      {
+        "name":"LVDS1",
+        "mode":"off"
+      }
+    ]
+}
diff --git a/recipes-graphics/kms-conf/kms-conf_1.0.bb b/recipes-graphics/kms-conf/kms-conf_1.0.bb
new file mode 100644
index 000000000..b063f65ff
--- /dev/null
+++ b/recipes-graphics/kms-conf/kms-conf_1.0.bb
@@ -0,0 +1,12 @@
+SUMMARY = "kms configuration file for the qt eglfs platform"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+SRC_URI = " \
+    file://kms.conf \
+"
+
+do_install_append() {
+    install -d ${D}/etc
+    install -m 644 ${WORKDIR}/kms.conf ${D}/etc
+}
diff --git a/recipes-graphics/libhomescreen/libhomescreen_git.bb b/recipes-graphics/libhomescreen/libhomescreen_git.bb
new file mode 100644
index 000000000..da511c8a1
--- /dev/null
+++ b/recipes-graphics/libhomescreen/libhomescreen_git.bb
@@ -0,0 +1,19 @@
+SUMMARY     = "AGL Home Screen Library"
+DESCRIPTION = "libhomescreen"
+HOMEPAGE    = "http://docs.automotivelinux.org"
+LICENSE     = "Apache-2.0"
+SECTION     = "libs"
+
+BBCLASSEXTEND = " nativesdk"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+DEPENDS = "af-binder json-c"
+
+inherit cmake
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/libhomescreen.git;protocol=https;branch=${AGL_BRANCH}"
+SRCREV = "0d65d54ba63508c0ef545d02e94d5702f9c8ecb3"
+S = "${WORKDIR}/git"
+
+RDEPENDS_${PN} = "agl-service-homescreen"
diff --git a/recipes-graphics/qlibhomescreen/qlibhomescreen_git.bb b/recipes-graphics/qlibhomescreen/qlibhomescreen_git.bb
new file mode 100644
index 000000000..09a262eb7
--- /dev/null
+++ b/recipes-graphics/qlibhomescreen/qlibhomescreen_git.bb
@@ -0,0 +1,13 @@
+SUMMARY     = "A wrapper library of libhomescreen for Qt Application in AGL"
+SECTION     = "libs"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=2ee41112a44fe7014dce33e26468ba93"
+
+DEPENDS = "qtbase libhomescreen"
+RDEPENDS_${PN} = "libhomescreen"
+
+inherit qmake5
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/src/libqthomescreen.git;protocol=https;branch=${AGL_BRANCH}"
+SRCREV = "b218476402bceda7eb42d41064552a7261ff3205"
+S = "${WORKDIR}/git"
diff --git a/recipes-graphics/ttf-fonts/ttf-dejavu_%.bbappend b/recipes-graphics/ttf-fonts/ttf-dejavu_%.bbappend
index 159865860..86a5d90ca 100644
--- a/recipes-graphics/ttf-fonts/ttf-dejavu_%.bbappend
+++ b/recipes-graphics/ttf-fonts/ttf-dejavu_%.bbappend
@@ -1,12 +1 @@
-FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
-DEPENDS += "fontforge-native"
-
-# From the orginal work located at https://aur.archlinux.org/packages/ttf-dejavu-emojiless/
-
-SRC_URI_append = " file://cleaner.py"
-
-do_install_prepend() {
-    for TTF in ${S}/*.ttf; do
-        fontforge -script ${WORKDIR}/cleaner.py ${TTF}
-    done
-}
+require ${@bb.utils.contains('AGL_FEATURES', 'agldemo', 'ttf-dejavu_agldemo.inc', '', d)}
diff --git a/recipes-graphics/ttf-fonts/ttf-dejavu_agldemo.inc b/recipes-graphics/ttf-fonts/ttf-dejavu_agldemo.inc
new file mode 100644
index 000000000..bb47bdc73
--- /dev/null
+++ b/recipes-graphics/ttf-fonts/ttf-dejavu_agldemo.inc
@@ -0,0 +1,12 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
+DEPENDS_append = " fontforge-native"
+
+# From the orginal work located at https://aur.archlinux.org/packages/ttf-dejavu-emojiless/
+
+SRC_URI_append = " file://cleaner.py"
+
+do_install_prepend() {
+    for TTF in ${S}/*.ttf; do
+        fontforge -script ${WORKDIR}/cleaner.py ${TTF}
+    done
+}
diff --git a/recipes-graphics/wayland/weston-init.bbappend b/recipes-graphics/wayland/weston-init.bbappend
new file mode 100644
index 000000000..8af3184af
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init.bbappend
@@ -0,0 +1 @@
+require ${@bb.utils.contains('AGL_FEATURES', 'agldemo', 'weston-init_agldemo.inc', '', d)}
diff --git a/recipes-graphics/wayland/weston-init/tmpfiles.conf.in b/recipes-graphics/wayland/weston-init/tmpfiles.conf.in
new file mode 100644
index 000000000..c4b302faf
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/tmpfiles.conf.in
@@ -0,0 +1,6 @@
+# This file is distributed to create weston XDG_RUNTIME_DIR (/run/deamon/@WESTONUSER@)
+#
+# See tmpfiles.d(5) for details
+
+d /run/platform/ 0775 root root -
+d /run/platform/@WESTONUSER@ 0770 @WESTONUSER@ @WESTONGROUP@ -
diff --git a/recipes-graphics/wayland/weston-init/weston-dep.conf.in b/recipes-graphics/wayland/weston-init/weston-dep.conf.in
new file mode 100644
index 000000000..2b8102096
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/weston-dep.conf.in
@@ -0,0 +1,3 @@
+[Unit]
+Requires=@WESTON_DRM_DEVICE@
+After=@WESTON_DRM_DEVICE@
diff --git a/recipes-graphics/wayland/weston-init/weston.conf.in b/recipes-graphics/wayland/weston-init/weston.conf.in
new file mode 100644
index 000000000..9c3df052d
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/weston.conf.in
@@ -0,0 +1,12 @@
+[Service]
+Type=notify
+Environment="XDG_RUNTIME_DIR=@XDG_RUNTIME_DIR@"
+# Note that clearing PAMName (thus not having PAMName=login) disables
+# logind support for the session, which allows setting XDG_RUNTIME_DIR
+# to something other than /run/user/% (as is done above).
+# Without systemd-logind support, weston needs to be patched to allow
+# its direct launcher to work for non-root users in this scenario.
+PAMName=
+ExecStart=
+ExecStart=@WESTONSTART@
+SmackProcessLabel=System::Weston
diff --git a/recipes-graphics/wayland/weston-init/zz-dri-imx.rules.in b/recipes-graphics/wayland/weston-init/zz-dri-imx.rules.in
new file mode 100644
index 000000000..585db6be8
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/zz-dri-imx.rules.in
@@ -0,0 +1,2 @@
+SUBSYSTEM=="gpu_class", MODE="0660", GROUP="@WESTONGROUP@", SECLABEL{smack}="*"
+
diff --git a/recipes-graphics/wayland/weston-init/zz-dri.rules.in b/recipes-graphics/wayland/weston-init/zz-dri.rules.in
new file mode 100644
index 000000000..51c68c303
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/zz-dri.rules.in
@@ -0,0 +1 @@
+SUBSYSTEM=="drm", MODE="0660", GROUP="@WESTONGROUP@", SECLABEL{smack}="*", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston@@WESTONUSER@.service"
diff --git a/recipes-graphics/wayland/weston-init/zz-input.rules.in b/recipes-graphics/wayland/weston-init/zz-input.rules.in
new file mode 100644
index 000000000..fb3e677f4
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/zz-input.rules.in
@@ -0,0 +1 @@
+SUBSYSTEM=="input", MODE="0660", GROUP="input", SECLABEL{smack}="*", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston@@WESTONUSER@.service"
diff --git a/recipes-graphics/wayland/weston-init/zz-tty.rules.in b/recipes-graphics/wayland/weston-init/zz-tty.rules.in
new file mode 100644
index 000000000..e5ce4b553
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/zz-tty.rules.in
@@ -0,0 +1 @@
+SUBSYSTEM=="tty", KERNEL=="tty7", OWNER="@WESTONUSER@", SECLABEL{smack}="*", TAG+="systemd", ENV{SYSTEMD_WANTS}="weston@@WESTONUSER@.service"
diff --git a/recipes-graphics/wayland/weston-init_agldemo.inc b/recipes-graphics/wayland/weston-init_agldemo.inc
new file mode 100644
index 000000000..a5f0b09b5
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init_agldemo.inc
@@ -0,0 +1,77 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/weston-init:"
+
+inherit agl-graphical
+
+AGL_DEFAULT_WESTONSTART ??= "/usr/bin/agl-compositor --config ${sysconfdir}/xdg/weston/weston.ini"
+
+WESTONSTART ??= "${AGL_DEFAULT_WESTONSTART} ${WESTONARGS}"
+WESTONSTART_append = " ${@bb.utils.contains("IMAGE_FEATURES", "debug-tweaks", " --log=${DISPLAY_XDG_RUNTIME_DIR}/compositor.log", "",d)}"
+
+# Systemd name of DRM device to have weston/agl-compositor startup depend
+# upon, if required.  Currently only x86-64 seems to need a dependency to
+# avoid failures due to racing with i915 driver init on e.g. UpSquared.
+# It seems safer for now to only apply it there rather than doing a blanket
+# default everywhere that might then need to be over-ridden for vendor BSPs.
+WESTON_DRM_DEVICE ?= ""
+
+WIFILES = " \
+    file://weston.conf.in \
+    file://weston-dep.conf.in \
+    file://tmpfiles.conf.in \
+    file://zz-dri.rules.in \
+    file://zz-input.rules.in \
+    file://zz-tty.rules.in \
+"
+
+WIFILES_append_imx = " \
+    file://zz-dri-imx.rules.in \
+"
+
+SRC_URI_append = " ${WIFILES}"
+
+do_install_append() {
+    # Remove upstream weston udev rules just to be safe
+    rm -f ${D}${sysconfdir}/udev/rules.d/71-weston-drm.rules
+
+    # Process ".in" files
+    files=$(echo ${WIFILES} | sed s,file://,,g)
+    for f in ${files}; do
+        g=${f%.in}
+        if [ "${f}" != "${g}" ]; then
+            sed -e "s,@WESTONUSER@,${WESTONUSER},g" \
+                -e "s,@WESTONGROUP@,${WESTONGROUP},g" \
+                -e "s,@XDG_RUNTIME_DIR@,${DISPLAY_XDG_RUNTIME_DIR},g" \
+                -e "s,@WESTONSTART@,${WESTONSTART},g" \
+                -e "s,@WESTON_DRM_DEVICE@,${WESTON_DRM_DEVICE},g" \
+                    ${WORKDIR}/${f} > ${WORKDIR}/${g}
+        fi
+    done
+
+    # Install weston drop-in
+    install -d ${D}${systemd_system_unitdir}/weston@.service.d
+    install -m644 ${WORKDIR}/weston.conf ${D}/${systemd_system_unitdir}/weston@.service.d/weston-init.conf
+
+    # Install weston DRM device dependency drop-in if required
+    if [ -n "${WESTON_DRM_DEVICE}" ]; then
+        install -m 0644 ${WORKDIR}/weston-dep.conf ${D}/${systemd_system_unitdir}/weston@.service.d/
+    fi
+
+    # Install tmpfiles drop-in
+    install -d ${D}${libdir}/tmpfiles.d
+    install -m644 ${WORKDIR}/tmpfiles.conf ${D}${libdir}/tmpfiles.d/weston-init.conf
+
+    # Install udev rules
+    install -d ${D}${sysconfdir}/udev/rules.d
+    for f in ${files}; do
+        g=${f%.in}
+        h=${g%.rules}
+        if [ "${g}" != "${h}" ]; then
+            install -m644 ${WORKDIR}/${g} ${D}${sysconfdir}/udev/rules.d
+        fi
+    done
+}
+
+FILES_${PN} += " \
+    ${libdir}/tmpfiles.d/ \
+    ${systemd_system_unitdir}/weston@.service.d/ \
+"