SPEC-3723: restructure meta-agl-demo

All demo related components should be in here now.

We keep the packagegroups on purpose for now to stay backward-compatible.

v2: layer does pass yocto-check-layer, dependencies adapted
v3: remove the dynamic-layer setup, use all-in-one approach
v4: Fixed comments from Paul Barker. Tnx!
v5: Removed wayland/weston/agl-compositor additions, except for demo
    specific weston-init bbappend

Follow-up changes required later:
      - massaging packagegroups
      - scrub of recipes

Bug-AGL: SPEC-3723

Signed-off-by: Jan-Simon Moeller <jsmoeller@linuxfoundation.org>
Signed-off-by: Scott Murray <scott.murray@konsulko.com>
Change-Id: I47cefd8c23d46b2cdd063470e3f7d97d5ad952d8

1 files changed, 42 insertions, 0 deletions

diff --git a/recipes-multimedia/lightmediascanner/lightmediascanner_%.bbappend b/recipes-multimedia/lightmediascanner/lightmediascanner_%.bbappend
new file mode 100644
index 000000000..b47b2796c
--- /dev/null
+++ b/recipes-multimedia/lightmediascanner/lightmediascanner_%.bbappend
@@ -0,0 +1,42 @@
+# Disable everything but the roygalty-free formats
+PACKAGECONFIG = "ogg flac wave m3u pls jpeg png"
+
+FILESEXTRAPATHS_prepend := "${THISDIR}/files:"
+
+SRC_URI += "file://lightmediascanner.service \
+            file://plugin-ogg-fix-chucksize-issue.patch \
+            file://0002-switch-from-G_BUS_TYPE_SESSION-to-G_BUS_TYPE_SYSTEM.patch \
+            file://dbus-lightmediascanner.conf \
+           "
+
+CFLAGS_append = " -D_FILE_OFFSET_BITS=64"
+
+inherit systemd
+
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE_${PN} = "lightmediascanner.service"
+SYSTEMD_AUTO_ENABLE_${PN} = "enable"
+
+do_install_append() {
+       # Install LMS systemd service
+       if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+              install -d ${D}${systemd_system_unitdir}
+              install -m 644 -p -D ${WORKDIR}/lightmediascanner.service ${D}${systemd_system_unitdir}/lightmediascanner.service
+       fi
+
+       install -d ${D}/etc/dbus-1/system.d
+       install -m 0644 ${WORKDIR}/dbus-lightmediascanner.conf ${D}/etc/dbus-1/system.d/org.lightmediascanner.conf
+}
+
+FILES_${PN} += " \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '${systemd_system_unitdir}/lightmediascanner.service', '', d)} \
+    "
+
+EXTRA_OECONF = "--enable-static --with-dbus-services=${datadir}/dbus-1/system-services"
+PACKAGECONFIG[mp4] = "--enable-mp4,--disable-mp4,libmp4v2"
+
+# add support MP3 because of the format of music files for AGL CES/ALS2017 Demo
+PACKAGECONFIG_append = " id3 mp4"
+
+# add required character sets for id3 tag scanning
+RDEPENDS_${PN}_append = " glibc-gconv-utf-16 glibc-gconv-iso8859-1"