Update AM/FM radio QML plugin to version 0.2

This commit upgrades qml-radio-plugin to version 0.2, which :
- implements PulseAudio support (will work automatically if
  we enable it inside AGL) ;
- fixes QML properties and types as requested in [*] ;
- fixes sound stuttering issues.

It also puts the non-mandatory QML sample in a separate
"examples" package, thus avoiding building qtquickcontrols
if we do not need it.

[*] : http://lists.linuxfoundation.org/pipermail/
automotive-discussions/2015-December/001244.html

Change-Id: I2b173d8bb1c4055b2c7ac0c4691d802c2eb5f61f
Signed-off-by: Manuel Bachmann <mbc@iot.bzh>

1 files changed, 37 insertions, 0 deletions

diff --git a/recipes-qt/qml-radio-plugin/qml-radio-plugin_0.2.bb b/recipes-qt/qml-radio-plugin/qml-radio-plugin_0.2.bb
new file mode 100644
index 000000000..fad6ed3be
--- /dev/null
+++ b/recipes-qt/qml-radio-plugin/qml-radio-plugin_0.2.bb
@@ -0,0 +1,37 @@
+SUMMARY = "AM/FM Radio QML plugin (for RTL2832U hardware)"
+DESCRIPTION = "This provides a simple QML plugin able to detect and use \
+radio hardware, most notably RTL2832U chipsets (although it can easily \
+be extended). Among other things, it provides generic APIs to display \
+status, switch between AM/FM mode, choose frequency, mute sound..."
+HOMEPAGE = "https://github.com/iotbzh/qml_radio_plugin"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://qml_radio.cpp;endline=16;md5=10a65c128e3a6cff2a61bb38556ceb04"
+
+DEPENDS = "qtbase-native qtdeclarative rtl-sdr pulseaudio alsa-lib"
+RDEPENDS_${PN}-examples = "qtdeclarative-tools qtquickcontrols-qmlplugins"
+
+SRC_URI = "git://github.com/iotbzh/qml_radio_plugin"
+SRCREV = "36e6bbaaa6637abab344d38d8a0c4794fa42fb03"
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--with-moc-dir=${STAGING_BINDIR_NATIVE}/qt5"
+
+QML_LIBDIR = "${libdir}/qt5/qml"
+
+do_install_append() {
+     # Remove .la files for loadable module
+     rm -f ${D}/${QML_LIBDIR}/radio/*.la
+     # Install QML example
+     install -d ${D}/${datadir}/qt5/examples/radio
+     install -m 0644 ${S}/radio.qml ${D}/${datadir}/qt5/examples/radio
+}
+
+PACKAGES += "${PN}-examples"
+
+FILES_${PN} += "${QML_LIBDIR}/radio/*.so ${QML_LIBDIR}/radio/qmldir"
+FILES_${PN}-dbg += "${QML_LIBDIR}/radio/.debug"
+FILES_${PN}-examples += "${datadir}"