blob: 870d2e398dff97dbb9a6bf566bb0b40aa9fab0f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
SUMMARY = "AGL certificates for KUKSA.val, the KUKSA Vehicle Abstraction Layer"
HOMEPAGE = "https://github.com/eclipse/kuksa.val"
BUGTRACKER = "https://github.com/eclipse/kuksa.val/issues"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
SRC_URI = "file://CA.pem \
file://Client.key \
file://Client.pem \
file://Server.key \
file://Server.pem \
"
inherit allarch useradd
USERADD_PACKAGES = "${PN}-server"
USERADDEXTENSION = "useradd-staticids"
GROUPADD_PARAM:${PN}-server = "-g 900 kuksa ;"
do_install() {
# Install replacement CA certificate, server key + certificate,
# and client key + certificate.
# These are AGL specific versions generated using a tweaked
# genCerts.sh script to have different expiry dates than the
# upstream defaults, and use AGL as the organization.
install -d ${D}${sysconfdir}/kuksa-val/
install -m 0644 ${WORKDIR}/CA.pem ${D}${sysconfdir}/kuksa-val/
install -m 0640 -g 900 ${WORKDIR}/Server.key ${D}${sysconfdir}/kuksa-val/
install -m 0640 -g 900 ${WORKDIR}/Server.pem ${D}${sysconfdir}/kuksa-val/
install -m 0644 ${WORKDIR}/Client.key ${D}${sysconfdir}/kuksa-val/
install -m 0644 ${WORKDIR}/Client.pem ${D}${sysconfdir}/kuksa-val/
}
PACKAGE_BEFORE_PN += "${PN}-ca ${PN}-server ${PN}-client"
FILES:${PN}-ca = " \
${sysconfdir}/kuksa-val/CA.pem \
"
RPROVIDES:${PN}-ca += "kuksa-val-certificates-ca"
FILES:${PN}-server = " \
${sysconfdir}/kuksa-val/Server.key \
${sysconfdir}/kuksa-val/Server.pem \
"
RPROVIDES:${PN}-server += "kuksa-val-certificates-server"
RDEPENDS:${PN}-server += "${PN}-ca"
FILES:${PN}-client = " \
${sysconfdir}/kuksa-val/Client.key \
${sysconfdir}/kuksa-val/Client.pem \
"
RPROVIDES:${PN}-client += "kuksa-val-certificates-client"
RDEPENDS:${PN}-client += "${PN}-ca"
ALLOW_EMPTY:${PN} = "1"
RDEPENDS:${PN} += "${PN}-ca ${PN}-server ${PN}-client"
|
