blob: 721cdd7d23ca944b9e9a99acaaa5eb6cbdcfe978 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
SUMMARY = "Demo HVAC Service Daemon"
DESCRIPTION = "Demo HVAC Service Daemon"
HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/#/admin/projects/apps/agl-service-hvac"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
DEPENDS = " \
glib-2.0 \
boost \
openssl \
systemd \
protobuf-native \
grpc-native \
protobuf \
grpc \
kuksa-databroker \
"
SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-hvac;protocol=https;branch=${AGL_BRANCH} \
file://agl-service-hvac.conf.default \
file://agl-service-hvac.conf.gateway-demo \
file://agl-service-hvac.token \
"
SRCREV = "1f55937667e35fb79dabee0e180787e34a59169a"
PV = "2.0+git${SRCPV}"
S = "${WORKDIR}/git"
inherit meson pkgconfig systemd update-alternatives
EXTRA_OEMESON += "-Dprotos=${STAGING_INCDIR}"
SYSTEMD_SERVICE:${PN} = "agl-service-hvac.service"
do_install:append() {
# Currently using default global client and CA certificates
# for KUKSA.val SSL, installing app specific ones would go here.
# VIS authorization token file for KUKSA.val should ideally not
# be readable by other users, but currently that's not doable
# until a packaging/sandboxing/MAC scheme is (re)implemented or
# something like OAuth is plumbed in as an alternative.
install -d ${D}${sysconfdir}/xdg/AGL/agl-service-hvac
install -m 0644 ${WORKDIR}/agl-service-hvac.conf.default ${D}${sysconfdir}/xdg/AGL/
install -m 0644 ${WORKDIR}/agl-service-hvac.conf.gateway-demo ${D}${sysconfdir}/xdg/AGL/
install -m 0644 ${WORKDIR}/agl-service-hvac.token ${D}${sysconfdir}/xdg/AGL/agl-service-hvac/
}
FILES:${PN} += "${systemd_system_unitdir}"
RDEPENDS:${PN} += "${PN}-conf"
ALTERNATIVE_LINK_NAME[agl-service-hvac.conf] = "${sysconfdir}/xdg/AGL/agl-service-hvac.conf"
PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-gateway-demo"
FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.default"
RDEPENDS:${PN}-conf = "${PN}"
RPROVIDES:${PN}-conf = "agl-service-hvac.conf"
ALTERNATIVE:${PN}-conf = "agl-service-hvac.conf"
ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.default"
FILES:${PN}-conf-gateway-demo += "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.gateway-demo"
RDEPENDS:${PN}-conf-gateway-demo = "${PN}"
RPROVIDES:${PN}-conf-gateway-demo = "agl-service-hvac.conf"
ALTERNATIVE:${PN}-conf-gateway-demo = "agl-service-hvac.conf"
ALTERNATIVE_TARGET_${PN}-conf-gateway-demo = "${sysconfdir}/xdg/AGL/agl-service-hvac.conf.gateway-demo"
ALTERNATIVE_PRIORITY_${PN}-conf-gateway-demo = "20"
|
