blob: be555dab869259598adccf410ae8e057bfb771bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
DESCRIPTION = "AGL VSS helper daemon"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
SRC_URI = "file://agl-vss-helper.py \
file://agl-vss-helper.yaml \
file://agl-vss-helper.token \
file://agl-vss-helper.service \
"
S = "${WORKDIR}/sources"
UNPACKDIR = "${S}"
inherit systemd
SYSTEMD_SERVICE:${PN} = "${BPN}.service"
do_configure[noexec] = "1"
do_compile[noexec] = "1"
do_install() {
install -d ${D}${sbindir}
install -m 0755 ${UNPACKDIR}/${BPN}.py ${D}${sbindir}
install -d ${D}${sysconfdir}/xdg/AGL/${BPN}
install -m 0644 ${UNPACKDIR}/${BPN}.yaml ${D}${sysconfdir}/xdg/AGL/
install -m 0644 ${UNPACKDIR}/${BPN}.token ${D}${sysconfdir}/xdg/AGL/${BPN}/
install -D -m 0644 ${UNPACKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
}
RDEPENDS:${PN} = " \
python3 \
python3-asyncio \
python3-systemd \
kuksa-databroker \
kuksa-databroker-agl \
kuksa-client \
kuksa-certificates-agl-ca \
"
|
