blob: b3703c53d10f43675b2e86ed7594888a6c0c1f03 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
SUMMARY = "AGL Reference Navigation Cluster Streaming application"
DESCRIPTION = "Demo AGL turn by turn cluster navigation application based on QtLocation widget."
HOMEPAGE = "https://gerrit.automotivelinux.org/gerrit/admin/repos/apps/tbtnavi"
SECTION = "apps"
LICENSE = "Apache-2.0 & ISC & BSD-3-Clause & BSL-1.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984 \
file://LICENSE.mapbox-cheap-ruler-cpp;md5=761263ee6bdc98e8697d9fbc897021ba \
file://LICENSE.mapbox-geometry.hpp;md5=6e44f5d6aeec54f40fc84eebe3c6fc6c \
file://LICENSE.mapbox-variant;md5=79558839a9db3e807e4ae6f8cd100c1c \
file://include/mapbox/recursive_wrapper.hpp;beginline=4;endline=13;md5=cd3341aae76c0cf8345935abd20f0051 \
"
DEPENDS = " \
qtbase \
qtquickcontrols2 \
qtlocation \
libqtappfw \
qtwayland-native \
protobuf \
grpc \
grpc-native \
"
PV = "2.0+git${SRCPV}"
SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/tbtnavi;protocol=https;branch=${AGL_BRANCH} \
file://tbtnavi.service \
file://tbtnavi.conf \
file://tbtnavi.conf.kvm-demo \
file://tbtnavi.token \
file://kvm.conf \
"
SRCREV = "f00c1e19f5c4cbcd185c8043f3062612bf1537f7"
S = "${WORKDIR}/git"
inherit meson systemd pkgconfig update-alternatives
SYSTEMD_SERVICE:${PN} = "${BPN}.service"
do_install:append() {
install -D -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_system_unitdir}/${BPN}.service
install -D -m 0644 ${WORKDIR}/kvm.conf ${D}${systemd_system_unitdir}/${BPN}.service.d/kvm.conf
# Currently using default global client and CA certificates
# for KUKSA.val SSL, installing app specific ones would go here.
# VIS authorization token file for KUKSA.val should ideally not
# be readable by other users, but currently that's not doable
# until a packaging/sandboxing/MAC scheme is (re)implemented or
# something like OAuth is plumbed in as an alternative.
install -d ${D}${sysconfdir}/xdg/AGL/tbtnavi
install -m 0644 ${WORKDIR}/tbtnavi.conf ${D}${sysconfdir}/xdg/AGL/tbtnavi.conf.default
install -m 0644 ${WORKDIR}/tbtnavi.conf.kvm-demo ${D}${sysconfdir}/xdg/AGL/
install -m 0644 ${WORKDIR}/tbtnavi.token ${D}${sysconfdir}/xdg/AGL/tbtnavi/
}
ALTERNATIVE_LINK_NAME[tbtnavi.conf] = "${sysconfdir}/xdg/AGL/tbtnavi.conf"
RDEPENDS:${PN} += " \
qtwayland \
qtbase-qmlplugins \
qtgraphicaleffects-qmlplugins \
qtlocation \
ondemandnavi-config \
libqtappfw \
"
PACKAGE_BEFORE_PN += "${PN}-conf ${PN}-conf-kvm-demo"
FILES:${PN}-conf += "${sysconfdir}/xdg/AGL/tbtnavi.conf.default"
RDEPENDS:${PN}-conf = "${PN}"
RPROVIDES:${PN}-conf = "tbtnavi.conf"
RCONFLICTS:${PN}-conf = "${PN}-conf-kvm-demo"
ALTERNATIVE:${PN}-conf = "tbtnavi.conf"
ALTERNATIVE_TARGET_${PN}-conf = "${sysconfdir}/xdg/AGL/tbtnavi.conf.default"
FILES:${PN}-conf-kvm-demo += " \
${sysconfdir}/xdg/AGL/tbtnavi.conf.kvm-demo \
${systemd_system_unitdir}/tbtnavi.service.d/kvm.conf \
"
RDEPENDS:${PN}-conf-kvm-demo = "${PN}"
RPROVIDES:${PN}-conf-kvm-demo = "tbtnavi.conf"
RCONFLICTS:${PN}-conf-kvm-demo = "${PN}-conf"
ALTERNATIVE:${PN}-conf-kvm-demo = "tbtnavi.conf"
ALTERNATIVE_TARGET_${PN}-conf-kvm-demo = "${sysconfdir}/xdg/AGL/tbtnavi.conf.kvm-demo"
|
