Add recipes for new hmi fweel_4.99.1eel/4.99.14.99.1

    Add recipesc for agl-service-windowmanager-2017,
    agl-service-soundmanager-2017,
    agl-service-homescreen-2017 and homescreen-2017.

    [Patch Sets 2]
    Modify homescreen-2017_git.bb to use aglwgt make package.
    [Patch Sets 3]
    Modify agl-service-windowmanager-2017_git.bb to use aglwgt make package.
    Modify agl-service-soundmanager-2017_git.bb to use aglwgt make package.
    [Patch Sets 4]
    Modify agl-service-homescreen-2017_git.bb to use aglwgt make package.
    [Patch Sets 5] (jsmoeller)
    Modify layer and add packagegroup containing the required packages.
    Modify feature name to be agl-hmi-framework to be consistent in naming
    Mofify local.conf.inc to set DISTRO_FEATURES flag instead of setting IMAGE_INSTALL.

Change-Id: Iac998b5c9ed519649c8c367e97a5aa31c6140c26
Signed-off-by: zheng_wenlong <wenlong_zheng@nexty-ele.com>
Signed-off-by: Jan-Simon Möller <jsmoeller@linuxfoundation.org>

8 files changed, 135 insertions, 6 deletions

diff --git a/meta-hmi-framework/recipes-demo-hmi/agl-service-homescreen-2017/agl-service-homescreen-2017_git.bb b/meta-hmi-framework/recipes-demo-hmi/agl-service-homescreen-2017/agl-service-homescreen-2017_git.bb
new file mode 100644
index 00000000..a07bc1dc
--- /dev/null
+++ b/meta-hmi-framework/recipes-demo-hmi/agl-service-homescreen-2017/agl-service-homescreen-2017_git.bb
@@ -0,0 +1,25 @@
+SUMMARY     = "Homescreen binding and client library for application"
+DESCRIPTION = "Homescreen 2017 is the binding library"
+HOMEPAGE    = "https://git.automotivelinux.org/apps/agl-service-homescreen-2017"
+S = "${WORKDIR}/git"
+SECTION = "HMI"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+inherit cmake aglwgt
+DEPENDS = "dbus glib-2.0 af-binder json-c"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-homescreen-2017;protocol=https;branch=master"
+SRCREV = "e0163d2b8daae98ced81f4bc737998c00858e771"
+
+do_install_append() {
+    install -d ${D}/usr/lib/pkgconfig
+    install -m 0644 ${B}/homescreen.pc ${D}/usr/lib/pkgconfig
+
+    install -d ${D}/usr/include
+    install -m 0644 ${S}/include/libhomescreen.hpp ${D}/usr/include
+
+    install -d ${D}/usr/lib
+    install -m 0755 ${B}/libhomescreen/libhomescreen.so ${D}/usr/lib/libhomescreen.so.0.1
+    ln -sf libhomescreen.so.0.1 ${D}/usr/lib/libhomescreen.so
+}
diff --git a/meta-hmi-framework/recipes-demo-hmi/homescreen-2017/homescreen-2017_git.bb b/meta-hmi-framework/recipes-demo-hmi/homescreen-2017/homescreen-2017_git.bb
new file mode 100644
index 00000000..f13a9d16
--- /dev/null
+++ b/meta-hmi-framework/recipes-demo-hmi/homescreen-2017/homescreen-2017_git.bb
@@ -0,0 +1,15 @@
+SUMMARY     = "AGL Home Screen 2017 Application"
+DESCRIPTION = "AGL Home Screen 2017 Application"
+HOMEPAGE    = "https://gerrit.automotivelinux.org/gerrit/gitweb?p=staging/homescreen-2017.git"
+S           = "${WORKDIR}/git/"
+SECTION     = "apps"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://homescreen/LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+
+inherit qmake5 systemd pkgconfig aglwgt
+DEPENDS = " qtbase qtdeclarative qtquickcontrols2 pulseaudio agl-service-homescreen-2017 agl-service-windowmanager-2017"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/staging/homescreen-2017;protocol=https;branch=master"
+SRCREV = "381755e4686a08e766316aaf40e8fdfa202d48d4"
+
+PATH_prepend = "${STAGING_DIR_NATIVE}${OE_QMAKE_PATH_QT_BINS}:"
diff --git a/meta-hmi-framework/recipes-graphics/agl-service-windowmanager-2017/agl-service-windowmanager-2017_git.bb b/meta-hmi-framework/recipes-graphics/agl-service-windowmanager-2017/agl-service-windowmanager-2017_git.bb
new file mode 100644
index 00000000..d406d208
--- /dev/null
+++ b/meta-hmi-framework/recipes-graphics/agl-service-windowmanager-2017/agl-service-windowmanager-2017_git.bb
@@ -0,0 +1,32 @@
+SUMMARY     = "Window Manager binding and client library for application"
+DESCRIPTION = "Window Manager 2017 is the binding library  \
+	"
+HOMEPAGE    = ""
+S = "${WORKDIR}/git"
+SECTION = "graphics"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=2ee41112a44fe7014dce33e26468ba93"
+DEPENDS = "af-binder json-c wayland wayland-ivi-extension"
+RDEPENDS_${PN} = " \
+	"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-windowmanager-2017;protocol=https;branch=master"
+SRCREV = "797eac5c26337df9d444e0a5e396be93454249dd"
+
+inherit cmake aglwgt
+
+#If you would like to output log, uncomment out
+#EXTRA_OECMAKE = " -DENABLE_DEBUG_OUTPUT=ON "
+
+do_install_append() {
+    install -d ${D}${sysconfdir}/windowmanager
+    install -m 0644 ${S}/layers.json ${D}${sysconfdir}/windowmanager/
+    install -d ${D}${libdir}/pkgconfig
+    install -m 0644 ${B}/windowmanager.pc ${D}${libdir}/pkgconfig
+    install -d ${D}${includedir}
+    install -m 0644 ${S}/libwindowmanager/libwindowmanager.h ${D}${includedir}
+
+    install -m -0755 ${B}/libwindowmanager/libwindowmanager.so ${D}${libdir}/libwindowmanager.so.0.1
+    ln -sf libwindowmanager.so.0.1 ${D}${libdir}/libwindowmanager.so
+}
+FILES_${PN} += "${sysconfdir}/windowmanager/layers.json"
diff --git a/meta-hmi-framework/recipes-multimedia/agl-service-soundmanager-2017/agl-service-soundmanager-2017_git.bb b/meta-hmi-framework/recipes-multimedia/agl-service-soundmanager-2017/agl-service-soundmanager-2017_git.bb
new file mode 100644
index 00000000..0b6504fd
--- /dev/null
+++ b/meta-hmi-framework/recipes-multimedia/agl-service-soundmanager-2017/agl-service-soundmanager-2017_git.bb
@@ -0,0 +1,32 @@
+SUMMARY     = "Sound Manager binding and client library for application"
+ESCRIPTION = "Sound Manager is the binding library to communicate \
+	with Genivi Audio Manager. Genivi Audio Manager is the policy manager \
+	about sound. It controls volume and routing according to various situations.\
+	This recipe also provides client library to communicate with sound manager. \
+	"
+HOMEPAGE    = "https://wiki.automotivelinux.org/soundmanager"
+S = "${WORKDIR}/git"
+SECTION = "multimedia"
+LICENSE     = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae6497158920d9524cf208c09cc4c984"
+DEPENDS = "dbus glib-2.0 af-binder json-c"
+RDEPENDS_${PN} = "audiomanager audiomanager-plugins"
+
+SRC_URI = "git://gerrit.automotivelinux.org/gerrit/apps/agl-service-soundmanager-2017;protocol=https;branch=master"
+SRCREV = "4bf8930f4f56eae60cf4562b9a601c828f2bd501"
+
+inherit cmake aglwgt
+
+do_install_append() {
+	install -d ${D}${sysconfdir}/dbus-1/system.d
+	install -m 0644 ${S}/conf/soundmanager-dbus.conf ${D}${sysconfdir}/dbus-1/system.d/
+	install -d ${D}${libdir}/pkgconfig
+	install -m 0644 ${B}/soundmanager.pc ${D}${libdir}/pkgconfig
+	install -d ${D}${includedir}
+	install -m 0644 ${S}/include/libsoundmanager.hpp ${D}${includedir}
+
+	install -m -0755 ${B}/libsoundmanager/libsoundmanager.so ${D}${libdir}/libsoundmanager.so.0.1
+	ln -sf libsoundmanager.so.0.1 ${D}${libdir}/libsoundmanager.so
+}
+
+FILES_${PN} += "${sysconfdir}/dbus-1/system.d/soundmanager-dbus.conf"
diff --git a/meta-hmi-framework/recipes-platform/packagegroups/packagegroup-hmi-framework.bb b/meta-hmi-framework/recipes-platform/packagegroups/packagegroup-hmi-framework.bb
new file mode 100644
index 00000000..2dd8c655
--- /dev/null
+++ b/meta-hmi-framework/recipes-platform/packagegroups/packagegroup-hmi-framework.bb
@@ -0,0 +1,27 @@
+SUMMARY = "The software for the AGL hmi framework 2017"
+DESCRIPTION = "A set of packages belong to the hmi framework 2017"
+
+LICENSE = "MIT"
+
+inherit packagegroup
+
+PACKAGES = " \
+  packagegroup-hmi-framework \
+  packagegroup-hmi-framework-dev \
+"
+
+RDEPENDS_${PN} += " \
+  agl-service-windowmanager-2017 \
+  agl-service-soundmanager-2017 \
+  agl-service-homescreen-2017 \
+  homescreen-2017 \
+"
+
+#
+# THESE SHOULD NOT BE NEEDED and have to be converted to being shipped as platform libraries instead !
+#
+RDEPENDS_${PN}-dev += " \
+   agl-service-windowmanager-2017-dev \
+   agl-service-soundmanager-2017-dev \
+   agl-service-homescreen-2017-dev \
+"
diff --git a/templates/feature/hmi-framework/50_bblayers.conf.inc b/templates/feature/agl-hmi-framework/50_bblayers.conf.inc
index 8fbfa728..8fbfa728 100644
--- a/templates/feature/hmi-framework/50_bblayers.conf.inc
+++ b/templates/feature/agl-hmi-framework/50_bblayers.conf.inc
diff --git a/templates/feature/agl-hmi-framework/50_local.conf.inc b/templates/feature/agl-hmi-framework/50_local.conf.inc
new file mode 100644
index 00000000..2b72a8e2
--- /dev/null
+++ b/templates/feature/agl-hmi-framework/50_local.conf.inc
@@ -0,0 +1,4 @@
+# In order to enable the hmi-framework features ,
+# enables the following line:
+#
+DISTRO_FEATURES_append = " agl-hmi-framework "
diff --git a/templates/feature/hmi-framework/50_local.conf.inc b/templates/feature/hmi-framework/50_local.conf.inc
deleted file mode 100644
index 2ee6737f..00000000
--- a/templates/feature/hmi-framework/50_local.conf.inc
+++ /dev/null
@@ -1,6 +0,0 @@
-# In order to enable the agl virtualization features (agl-egvirt),
-# each supported board needs to add in one of its configuration
-# files (see for instance meta-agl/meta-agl-bsp/conf/include)
-# the following line:
-#
-IMAGE_INSTALL_append = ""