Revert "Remove weston with wayland-ivi-extention"

This reverts commit 24f2da7bfd7fa66e8a3b8ed7e5d8c09ef6956c68.

Bug-AGL: SPEC-5308
Change-Id: Ibf15daed630f08ad07bf6f91aaef016927eee0ac
Signed-off-by: Naoto Yamaguchi <naoto.yamaguchi@aisin.co.jp>

1 files changed, 46 insertions, 0 deletions

diff --git a/meta-agl-ic-container/recipes-graphics/wayland/weston-init-guest_0.1.bb b/meta-agl-ic-container/recipes-graphics/wayland/weston-init-guest_0.1.bb
new file mode 100644
index 00000000..c95f92e0
--- /dev/null
+++ b/meta-agl-ic-container/recipes-graphics/wayland/weston-init-guest_0.1.bb
@@ -0,0 +1,46 @@
+SUMMARY = "Startup script and systemd unit file for the Weston Wayland compositor in guest cotainer"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+SRC_URI = "file://weston.env \
+           file://weston.service \
+          "
+
+S = "${WORKDIR}"
+
+inherit features_check systemd
+
+do_install() {
+    install -Dm644 ${WORKDIR}/weston.env ${D}${sysconfdir}/default/weston
+
+    # Install Weston systemd service and accompanying udev rule
+    install -D -p -m0644 ${WORKDIR}/weston.service ${D}${systemd_system_unitdir}/weston.service
+    sed -i -e s:/etc:${sysconfdir}:g \
+        -e s:/usr/bin:${bindir}:g \
+        -e s:/var:${localstatedir}:g \
+        ${D}${systemd_unitdir}/system/weston.service
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+# rdepends on weston-init-guest which depends on wayland
+REQUIRED_DISTRO_FEATURES = "wayland"
+
+FILES:${PN} += " \
+    ${sysconfdir}/xdg/weston/weston.ini \
+    ${systemd_system_unitdir}/weston.service \
+    ${sysconfdir}/default/weston \
+    "
+CONFFILES:${PN} += " \
+    ${sysconfdir}/xdg/weston/weston.ini \
+    ${sysconfdir}/default/weston \
+    "
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE:${PN} = "weston.service"
+SYSTEMD_AUTO_ENABLE = "enable"
+
+RDEPENDS:${PN} = " \
+    weston \
+    weston-ini \
+    "
+RCONFLICTS:${PN} = "weston-init"