Integrate Whisper AI into AGL Voice Agent and Update Dependencies

V1:
  - Removed the following recipes from meta-offline-voiceagent:
    - python3-scipy
    - python3-scikit-learn
    - python3-openblas
    - python3-lapack
    - python3-numpy

  - Updated to use meta-python-ai layer for:
    - python3-scipy
    - python3-scikit-learn
    - python3-openblas
    - python3-lapack
    - python3-numpy
    - python3-pytorch

  - Added all the required recipes for Whisper AI:
    - Included recipes for Whisper AI base and tiny model

  - Updated recipes for:
    - python3-uvloop
    - python3-python-crfsuite

V2:
  - Remove vulkan from DISTRO_FEATURES as it has become coditional
    at upstream
  - Fix flutter_voiceassistant service
  - Update recipe of llvmlite to include the wheel for aarch64 also.

V3:
  - Fix llvmlite recipe and some patches
  - Removes rasa and its dependencies
  - Fix agl-service-voiceagent.service

Bug-AGL: SPEC-5200
Change-Id: I429e7d4b98fbbe1a4f8c1341ac8918d7d177b382
Signed-off-by: Anuj Solanki <anuj603362@gmail.com>

1 files changed, 64 insertions, 0 deletions

diff --git a/meta-offline-voice-agent/recipes-devtools/recipes-intel/intel-compute-runtime_24.13.29138.7.bb b/meta-offline-voice-agent/recipes-devtools/recipes-intel/intel-compute-runtime_24.13.29138.7.bb
new file mode 100644
index 00000000..5214d5cf
--- /dev/null
+++ b/meta-offline-voice-agent/recipes-devtools/recipes-intel/intel-compute-runtime_24.13.29138.7.bb
@@ -0,0 +1,64 @@
+SUMMARY = "The Intel(R) Graphics Compute Runtime for OpenCL(TM)"
+DESCRIPTION = "The Intel(R) Graphics Compute Runtime for OpenCL(TM) \
+is an open source project to converge Intel's development efforts \
+on OpenCL(TM) compute stacks supporting the GEN graphics hardware \
+architecture."
+
+LICENSE = "MIT & Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=eca6ec6997e18db166db7109cdbe611c \
+                    file://third_party/opencl_headers/LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = "git://github.com/intel/compute-runtime.git;protocol=https;branch=releases/24.13 \
+           file://disable-werror.patch \
+           file://allow-to-find-cpp-generation-tool.patch \
+           file://external-ocloc.patch \
+           "
+
+SRCREV = "7131387cdbb02d480a225c70daef913a6c024a6e"
+
+S = "${WORKDIR}/git"
+
+DEPENDS += " intel-graphics-compiler gmmlib libva qemu-native"
+
+RDEPENDS:${PN} += " intel-graphics-compiler gmmlib"
+
+inherit cmake pkgconfig qemu
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST:libc-musl = "null"
+
+EXTRA_OECMAKE = " \
+                 -DIGC_DIR=${STAGING_INCDIR}/igc \
+                 -DBUILD_TYPE=Release \
+                 -DSKIP_UNIT_TESTS=1 \
+                 -DCCACHE_ALLOWED=FALSE \
+                 -DNEO_DISABLE_LD_LLD=ON \
+                 -DNEO_DISABLE_LD_GOLD=ON \
+                 "
+
+EXTRA_OECMAKE:append:class-target = " \
+                                     -Docloc_cmd_prefix=ocloc \
+                                     -DCMAKE_CROSSCOMPILING_EMULATOR=${WORKDIR}/qemuwrapper \
+                                     "
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[levelzero] = "-DBUILD_WITH_L0=ON, -DBUILD_WITH_L0=OFF, level-zero"
+
+do_configure:prepend:class-target () {
+    # Write out a qemu wrapper that will be used by cmake.
+    qemu_binary="${@qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST'), [d.expand('${B}/bin'),d.expand('${STAGING_DIR_HOST}${libdir}'),d.expand('${STAGING_DIR_HOST}${base_libdir}')])}"
+    cat > ${WORKDIR}/qemuwrapper << EOF
+#!/bin/sh
+$qemu_binary "\$@"
+EOF
+    chmod +x ${WORKDIR}/qemuwrapper
+}
+
+FILES:${PN} += " \
+                 ${libdir}/intel-opencl/libigdrcl.so \
+                 ${libdir}/libocloc.so \
+                 "
+
+FILES:${PN}-dev = "${includedir}"
+
+UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"