Unified HMI: initial commit

This is the initial commit for RVGPU of Unified HMI.

`Unified HMI` is a common platform that promotes UX innovation
in integrated cockpits and enables flexible information display
from various applications across multiple displays.

`RVGPU` is a client-server based rendering engine
that creates 3D commands on a client device, sends them to a server
for GPU rendering, and displays the results.

- create new layer, meta-uhmi
- create sub-layer, meta-rvgpu
- add 1 feature to enable basesystem, agl-rvgpu

Bug-AGL: SPEC-4744
Change-Id: I9b6f3966e3d5a859787f81c41b584fa686fd1f87
Signed-off-by: Fumiya Kohzu <kohzu.fumiya@jp.panasonic.com>

1 files changed, 41 insertions, 0 deletions

diff --git a/meta-uhmi/meta-rvgpu/recipes-kernel/virtio-loopback-driver/virtio-loopback-driver_git.bb b/meta-uhmi/meta-rvgpu/recipes-kernel/virtio-loopback-driver/virtio-loopback-driver_git.bb
new file mode 100644
index 00000000..687c33dd
--- /dev/null
+++ b/meta-uhmi/meta-rvgpu/recipes-kernel/virtio-loopback-driver/virtio-loopback-driver_git.bb
@@ -0,0 +1,41 @@
+SUMMARY = "Virtio Loopback Driver for Remote virtual display device"
+
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE.md;md5=688693ebbe31e3eadf819d7d007fa654"
+
+require virtio-loopback-driver.inc
+
+SRC_URI:append = " \
+    file://0001-Remove-card_index-option.patch \
+    file://Makefile.driver \
+    file://Kbuild \
+"
+
+S = "${WORKDIR}/git"
+EXTRA_OEMAKE = "KDIR=${STAGING_KERNEL_BUILDDIR}"
+MODULES_MODULE_SYMVERS_LOCATION = "src"
+
+inherit module
+
+do_compile:prepend() {
+    cp ${WORKDIR}/Makefile.driver ${S}/Makefile
+    cp ${WORKDIR}/Kbuild ${S}/src/
+}
+
+do_install:append() {
+    install -d ${D}${PKG_CONFIG_SYSTEM_INCLUDE_PATH}/remote-virtio-gpu
+    install -m 755 ${S}/src/virtio_lo.h ${D}${PKG_CONFIG_SYSTEM_INCLUDE_PATH}/remote-virtio-gpu/virtio_lo.h
+}
+
+FILES:${PN} = " \
+    ${libdir}/modules/${KERNEL_VERSION}/extra/virtio_lo* \
+    ${sysconfdir}/modules-load.d \
+"
+
+RPROVIDES:${PN} += " \
+    kernel-module-virtiolo \
+    kernel-module-virtio-lo${KERNEL_MODULE_PACKAGE_SUFFIX} \
+"
+
+# Autoload virtio lo driver
+KERNEL_MODULE_AUTOLOAD:append = " virtio_lo"