First commit.Renesas-Yocto-v2.16.0

Renesas BSP v3.5.1 (kernel v4.9 stable)

[Environment]
poky: yocto-2.1.2 (cca8dd15c8096626052f6d8d25ff1e9a606104a3)
meta-openembedded: 55c8a76da5dc099a7bc3838495c672140cedb78e
meta-linaro: 2f51d38048599d9878f149d6d15539fb97603f8f

[Information]
- U-boot: Changed load address from H'49000000 to H'50000000
- XDG_RUNTIME_DIR has been changed from "/run/user/root" to "/run/user/0"
- Change location of include directory, which stores common user header
  files, to $(INCSHARED)
- In BSP Only, core-image-weston is not supported even though
  local-wayland.conf is provided.
- Please set Salvator-x SW7 Pin-1. In after Yocto BSP v2.12.0, it is
　necessary to enable BKUP_TRG signal for Suspend to RAM.
- The dtb filename was changed in R-Car H3. Only
  "Image-r8a7795-es1-salvator-x.dtb" is supported in this version.
  Please use "Image-r8a7795-es1-salvator-x.dtb" It supports R-Car H3
  WS1.0 and WS1.1.
- Please update your local.conf and bblayers.conf corresponding to Yocto
  v2.16.0 package. You can refer to meta-rcargen3/docs/sample/conf/ for
  updated contents.
- You have to re-compile out-of-recipe software like user application by
  v2.16.0 SDK toolchains.
- In some boards, the resuming from System Suspend to RAM may cause
  unstable operation or failed to resume.

Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>

8 files changed, 317 insertions, 0 deletions

diff --git a/meta-rcar-gen3/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware_git.bb b/meta-rcar-gen3/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware_git.bb
new file mode 100644
index 0000000..7074970
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/arm-trusted-firmware/arm-trusted-firmware_git.bb
@@ -0,0 +1,55 @@
+DESCRIPTION = "ARM Trusted Firmware"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://license.md;md5=829bdeb34c1d9044f393d5a16c068371"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+require include/multimedia-control.inc
+
+S = "${WORKDIR}/git"
+
+BRANCH = "rcar_gen3"
+SRC_URI = "git://github.com/renesas-rcar/arm-trusted-firmware.git;branch=${BRANCH}"
+SRCREV = "c040be5a757a945da75cf97d3a3e1db3a43168f9"
+
+PV = "v1.3+renesas+git${SRCPV}"
+
+COMPATIBLE_MACHINE = "(salvator-x|h3ulcb|m3ulcb)"
+PLATFORM = "rcar"
+ATFW_OPT_LOSSY = "${@base_conditional("USE_MULTIMEDIA", "1", "RCAR_LOSSY_ENABLE=1", "", d)}"
+ATFW_OPT_r8a7795 = "LSI=H3 RCAR_DRAM_SPLIT=1 ${ATFW_OPT_LOSSY}"
+ATFW_OPT_r8a7796 = "LSI=M3 RCAR_DRAM_SPLIT=2 ${ATFW_OPT_LOSSY}"
+
+# requires CROSS_COMPILE set by hand as there is no configure script
+export CROSS_COMPILE="${TARGET_PREFIX}"
+
+# Let the Makefile handle setting up the CFLAGS and LDFLAGS as it is a standalone application
+CFLAGS[unexport] = "1"
+LDFLAGS[unexport] = "1"
+AS[unexport] = "1"
+LD[unexport] = "1"
+
+do_compile() {
+    oe_runmake bl2 bl31 dummytool PLAT=${PLATFORM} ${ATFW_OPT}
+}
+
+# do_install() nothing
+do_install[noexec] = "1"
+
+do_deploy() {
+    # Create deploy folder
+    install -d ${DEPLOYDIR}
+
+    # Copy IPL to deploy folder
+    install -m 0644 ${S}/build/${PLATFORM}/release/bl2/bl2.elf ${DEPLOYDIR}/bl2-${MACHINE}.elf
+    install -m 0644 ${S}/build/${PLATFORM}/release/bl2.bin ${DEPLOYDIR}/bl2-${MACHINE}.bin
+    install -m 0644 ${S}/build/${PLATFORM}/release/bl2.srec ${DEPLOYDIR}/bl2-${MACHINE}.srec
+    install -m 0644 ${S}/build/${PLATFORM}/release/bl31/bl31.elf ${DEPLOYDIR}/bl31-${MACHINE}.elf
+    install -m 0644 ${S}/build/${PLATFORM}/release/bl31.bin ${DEPLOYDIR}/bl31-${MACHINE}.bin
+    install -m 0644 ${S}/build/${PLATFORM}/release/bl31.srec ${DEPLOYDIR}/bl31-${MACHINE}.srec
+    install -m 0644 ${S}/tools/dummy_create/bootparam_sa0.srec ${DEPLOYDIR}/bootparam_sa0.srec
+    install -m 0644 ${S}/tools/dummy_create/cert_header_sa6.srec ${DEPLOYDIR}/cert_header_sa6.srec
+}
+addtask deploy before do_build after do_compile
diff --git a/meta-rcar-gen3/recipes-bsp/optee/optee-client/optee.service b/meta-rcar-gen3/recipes-bsp/optee/optee-client/optee.service
new file mode 100644
index 0000000..4396f9f
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/optee/optee-client/optee.service
@@ -0,0 +1,11 @@
+[Unit]
+Description=optee services
+
+[Service]
+ExecStartPre=/sbin/modprobe -q optee_armtz
+ExecStart=/usr/bin/tee-supplicant
+ExecStop=/usr/bin/killall -s KILL tee-supplicant
+ExecStopPost=/sbin/modprobe -r optee_armtz
+
+[Install]
+WantedBy=multi-user.target
diff --git a/meta-rcar-gen3/recipes-bsp/optee/optee-client_git.bb b/meta-rcar-gen3/recipes-bsp/optee/optee-client_git.bb
new file mode 100644
index 0000000..9efbfb5
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/optee/optee-client_git.bb
@@ -0,0 +1,58 @@
+DESCRIPTION = "OP-TEE Client"
+LICENSE = "BSD-2-Clause"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=69663ab153298557a59c67a60a743e5b"
+PR = "r0"
+PV = "1.1.0+renesas+git${SRCPV}"
+BRANCH = "master"
+SRC_URI = "git://github.com/OP-TEE/optee_client.git;branch=${BRANCH}"
+SRCREV = "db9c64d45818d146200297eaaedbd421a8b59e3a"
+
+SRC_URI += " \
+    file://optee.service \
+"
+
+inherit systemd
+SYSTEMD_SERVICE_${PN} = "optee.service"
+
+COMPATIBLE_MACHINE = "salvator-x|h3ulcb|m3ulcb"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "RPMB_EMU=0"
+
+do_install () {
+    # Create destination directories
+    install -d ${D}/${libdir}
+    install -d ${D}/${includedir}
+
+    # Install library
+    install -m 0755 ${S}/out/export/lib/libteec.so.1.0 ${D}/${libdir}
+
+    # Create symbolic link
+    cd ${D}/${libdir}
+    ln -sf libteec.so.1.0 libteec.so.1
+    ln -sf libteec.so.1 libteec.so
+
+    # Install header files
+    install -m 0644 ${S}/out/export/include/* ${D}/${includedir}
+
+    # Install systemd service configure file for OP-TEE client
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+        install -d ${D}/${systemd_system_unitdir}
+        install -m 0644 ${WORKDIR}/optee.service ${D}/${systemd_system_unitdir}
+    fi
+}
+
+# install the tee-supplicant for 64 bit only.
+do_install_append_aarch64 () {
+    # Create destination directory
+    install -d ${D}/${bindir}
+
+    # Install binary to bindir
+    install -m 0755 ${S}/out/export/bin/tee-supplicant ${D}/${bindir}
+}
+
+RPROVIDES_${PN} += "optee-client"
diff --git a/meta-rcar-gen3/recipes-bsp/optee/optee-os_git.bb b/meta-rcar-gen3/recipes-bsp/optee/optee-os_git.bb
new file mode 100644
index 0000000..5d99bfe
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/optee/optee-os_git.bb
@@ -0,0 +1,67 @@
+DESCRIPTION = "OP-TEE OS"
+
+LICENSE = "BSD-2-Clause & BSD-3-Clause"
+LIC_FILES_CHKSUM = " \
+    file://LICENSE;md5=69663ab153298557a59c67a60a743e5b \
+    file://lib/libpng/LICENSE;md5=06a1b6fde6d93170bb72201c8000bf3d \
+    file://${WORKDIR}/git_official/LICENSE;md5=69663ab153298557a59c67a60a743e5b \
+    file://${WORKDIR}/git_official/lib/libpng/LICENSE;md5=06a1b6fde6d93170bb72201c8000bf3d \
+"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy pythonnative
+
+PV = "2.2.0+renesas+git${SRCPV}"
+
+BRANCH = "rcar_gen3"
+SRCREV_renesas = "fab553ef09322e8cca76e067282742b946f1ecb5"
+SRCREV_officialgit = "c0c5d399d81a0669f5c8e3bcb20039d65649a78d"
+SRCREV_FORMAT = "renesas_officialgit"
+
+SRC_URI = " \
+    git://github.com/renesas-rcar/optee_os.git;branch=${BRANCH};name=renesas \
+    git://github.com/OP-TEE/optee_os.git;branch=master;name=officialgit;destsuffix=git_official \
+"
+
+COMPATIBLE_MACHINE = "(salvator-x|h3ulcb|m3ulcb)"
+PLATFORM = "rcar"
+
+DEPENDS = "python-wand-native python-pycrypto-native"
+
+# Needed so that python-wand can find the installed imagemagick install.
+export MAGICK_HOME="${STAGING_DIR_NATIVE}${prefix}"
+
+export CROSS_COMPILE64="${TARGET_PREFIX}"
+
+# Let the Makefile handle setting up the flags as it is a standalone application
+LD[unexport] = "1"
+LDFLAGS[unexport] = "1"
+export CCcore="${CC}"
+export LDcore="${LD}"
+libdir[unexport] = "1"
+
+S = "${WORKDIR}/git"
+EXTRA_OEMAKE = "-e MAKEFLAGS="
+
+do_configure() {
+    cp -r ${WORKDIR}/git_official/core/lib/libtomcrypt ${B}/core/lib/.
+}
+
+do_compile() {
+    oe_runmake PLATFORM=${PLATFORM} CFG_ARM64_core=y
+}
+
+# do_install() nothing
+do_install[noexec] = "1"
+
+do_deploy() {
+    # Create deploy folder
+    install -d ${DEPLOYDIR}
+
+    # Copy TEE OS to deploy folder
+    install -m 0644 ${S}/out/arm-plat-${PLATFORM}/core/tee.elf ${DEPLOYDIR}/tee-${MACHINE}.elf
+    install -m 0644 ${S}/out/arm-plat-${PLATFORM}/core/tee.bin ${DEPLOYDIR}/tee-${MACHINE}.bin
+    install -m 0644 ${S}/out/arm-plat-${PLATFORM}/core/tee.srec ${DEPLOYDIR}/tee-${MACHINE}.srec
+}
+addtask deploy before do_build after do_compile
diff --git a/meta-rcar-gen3/recipes-bsp/qos/qosif-tp-user-module.bb b/meta-rcar-gen3/recipes-bsp/qos/qosif-tp-user-module.bb
new file mode 100644
index 0000000..9d9b101
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/qos/qosif-tp-user-module.bb
@@ -0,0 +1,36 @@
+DESCRIPTION = "QOS Interface test app for R-Car Gen3"
+
+require qosif.inc
+
+DEPENDS = "qosif-user-module"
+PN = "qosif-tp-user-module"
+PR = "r0"
+
+S = "${WORKDIR}/git"
+QOSIF_TP_DIR = "qos_if-tp-user/files/qos_if"
+
+includedir = "/usr/local/include"
+
+do_compile() {
+    cd ${S}/${QOSIF_TP_DIR}
+    oe_runmake
+}
+
+do_install() {
+    # Create destination directory
+    install -d ${D}/usr/local/bin/
+
+    # Copy user test program
+    install -m 755 ${S}/${QOSIF_TP_DIR}/qos_tp ${D}/usr/local/bin/
+}
+
+PACKAGES = " \
+    ${PN} \
+    ${PN}-dbg \
+"
+
+FILES_${PN} = "/usr/local/bin/qos_tp"
+
+FILES_${PN}-dbg = " \
+    /usr/local/bin/.debug/* \
+"
diff --git a/meta-rcar-gen3/recipes-bsp/qos/qosif-user-module.bb b/meta-rcar-gen3/recipes-bsp/qos/qosif-user-module.bb
new file mode 100644
index 0000000..d2871f2
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/qos/qosif-user-module.bb
@@ -0,0 +1,48 @@
+DESCRIPTION = "QOS Interface library for R-Car Gen3"
+
+require qosif.inc
+
+DEPENDS = "kernel-module-qos"
+PN = "qosif-user-module"
+PR = "r0"
+
+S = "${WORKDIR}/git"
+QOSIF_LIB_DIR = "qos_if-module/files/qos_if"
+
+EXTRA_OEMAKE = "ARCH=${TARGET_ARCH}"
+
+includedir = "/usr/local/include"
+
+do_compile() {
+    # Build shared library
+    cd ${S}/${QOSIF_LIB_DIR}/if
+    rm -rf ${S}/${QOSIF_LIB_DIR}/if/libqos.so*
+    oe_runmake
+}
+
+do_install() {
+    # Create destination directories
+    install -d ${D}/${libdir}
+    install -d ${D}/${includedir}
+
+    # Copy shared library
+    install -m 755 ${S}/${QOSIF_LIB_DIR}/if/libqos.so* ${D}/${libdir}/
+    cd ${D}/${libdir}/
+    ln -sf libqos.so.1.0.0 libqos.so.1
+    ln -sf libqos.so.1 libqos.so
+
+    # Install shared header file
+    install -m 644 ${S}/${QOSIF_LIB_DIR}/include/qos_public.h ${D}/${includedir}/
+}
+
+PACKAGES = " \
+    ${PN} \
+    ${PN}-dev \
+    ${PN}-dbg \
+"
+
+FILES_${PN} = " \
+    ${libdir}/libqos.so* \
+"
+
+INSANE_SKIP_${PN} = "dev-so"
diff --git a/meta-rcar-gen3/recipes-bsp/qos/qosif.inc b/meta-rcar-gen3/recipes-bsp/qos/qosif.inc
new file mode 100644
index 0000000..a5d85ee
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/qos/qosif.inc
@@ -0,0 +1,15 @@
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = " \
+    file://COPYING.MIT;md5=96659f2a7571bfa27483882a653c3bb9 \
+"
+
+require include/rcar-gen3-modules-common.inc
+
+QOSIF_LIB_URL = "git://github.com/renesas-rcar/qos_lib.git"
+BRANCH = "rcar-gen3"
+SRCREV = "ae3bfdb6d8bcf99c73b30f82bb9a1418cc998d00"
+
+SRC_URI = "${QOSIF_LIB_URL};branch=${BRANCH}"
+
+# This module is machine specific.
+PACKAGE_ARCH = "${MACHINE_ARCH}"
diff --git a/meta-rcar-gen3/recipes-bsp/u-boot/u-boot_2015.04.bb b/meta-rcar-gen3/recipes-bsp/u-boot/u-boot_2015.04.bb
new file mode 100644
index 0000000..1aa4961
--- /dev/null
+++ b/meta-rcar-gen3/recipes-bsp/u-boot/u-boot_2015.04.bb
@@ -0,0 +1,27 @@
+require recipes-bsp/u-boot/u-boot.inc
+
+DEPENDS += "dtc-native"
+
+UBOOT_URL = "git://github.com/renesas-rcar/u-boot.git"
+BRANCH = "v2015.04/rcar-3.5.0"
+
+LIC_FILES_CHKSUM = "file://Licenses/README;md5=c7383a594871c03da76b3707929d2919"
+
+SRC_URI = "${UBOOT_URL};branch=${BRANCH}"
+SRCREV = "1852a50412be4cd8b4f668d78003293e437e7ac2"
+
+PV = "v2015.04+git${SRCPV}"
+
+EXTRA_OEMAKE_append = " KCFLAGS=-fgnu89-inline"
+
+UBOOT_SREC ?= "u-boot-elf.srec"
+UBOOT_SREC_IMAGE ?= "u-boot-elf-${MACHINE}-${PV}-${PR}.srec"
+UBOOT_SREC_SYMLINK ?= "u-boot-elf-${MACHINE}.srec"
+
+do_deploy_append() {
+    install -m 644 ${S}/${UBOOT_SREC} ${DEPLOYDIR}/${UBOOT_SREC_IMAGE}
+    cd ${DEPLOYDIR}
+    rm -f ${UBOOT_SREC} ${UBOOT_SREC_SYMLINK}
+    ln -sf ${UBOOT_SREC_IMAGE} ${UBOOT_SREC_SYMLINK}
+    ln -sf ${UBOOT_SREC_IMAGE} ${UBOOT_SREC}
+}