First commit.Renesas-Yocto-v2.16.0

Renesas BSP v3.5.1 (kernel v4.9 stable)

[Environment]
poky: yocto-2.1.2 (cca8dd15c8096626052f6d8d25ff1e9a606104a3)
meta-openembedded: 55c8a76da5dc099a7bc3838495c672140cedb78e
meta-linaro: 2f51d38048599d9878f149d6d15539fb97603f8f

[Information]
- U-boot: Changed load address from H'49000000 to H'50000000
- XDG_RUNTIME_DIR has been changed from "/run/user/root" to "/run/user/0"
- Change location of include directory, which stores common user header
  files, to $(INCSHARED)
- In BSP Only, core-image-weston is not supported even though
  local-wayland.conf is provided.
- Please set Salvator-x SW7 Pin-1. In after Yocto BSP v2.12.0, it is
　necessary to enable BKUP_TRG signal for Suspend to RAM.
- The dtb filename was changed in R-Car H3. Only
  "Image-r8a7795-es1-salvator-x.dtb" is supported in this version.
  Please use "Image-r8a7795-es1-salvator-x.dtb" It supports R-Car H3
  WS1.0 and WS1.1.
- Please update your local.conf and bblayers.conf corresponding to Yocto
  v2.16.0 package. You can refer to meta-rcargen3/docs/sample/conf/ for
  updated contents.
- You have to re-compile out-of-recipe software like user application by
  v2.16.0 SDK toolchains.
- In some boards, the resuming from System Suspend to RAM may cause
  unstable operation or failed to resume.

Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>

5 files changed, 222 insertions, 0 deletions

diff --git a/meta-rcar-gen3/recipes-graphics/images/core-image-renesas-base.inc b/meta-rcar-gen3/recipes-graphics/images/core-image-renesas-base.inc
new file mode 100644
index 0000000..c1081ce
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/images/core-image-renesas-base.inc
@@ -0,0 +1,67 @@
+require include/iccom-control.inc
+
+# Basic packages
+IMAGE_INSTALL_append = " \
+    bash \
+    v4l-utils \
+    i2c-tools \
+"
+
+# Support secure environment
+IMAGE_INSTALL_append = " \
+    optee-linuxdriver \
+    optee-linuxdriver-armtz \
+    optee-client \
+"
+
+# Add overrides for selection 32 bit or 64 bit target
+OVERRIDES .= ":${TARGET_SYS}"
+
+# Qos user packages only supports 64bit.
+QOS_USER_PKGS = ""
+QOS_USER_PKGS_aarch64-poky-linux = " \
+    qosif-user-module \
+    qosif-tp-user-module \
+"
+
+# Installation for QoS packages
+IMAGE_INSTALL_append = " \
+    kernel-module-qos \
+    ${QOS_USER_PKGS} \
+"
+
+# Renesas Basic packages for 32bit
+BASIC_32BIT_PKGS = " \
+    lib32-coreutils \
+    lib32-libstdc++ \
+    lib32-optee-client \
+"
+
+# Installation for 32bit packages
+IMAGE_INSTALL_append = " \
+    ${@base_conditional("USE_32BIT_PKGS", "1", "${BASIC_32BIT_PKGS}", "", d)} \
+"
+
+# Kernel modules of ICCOM
+ICCOM_KERNEL_PKGS = " \
+    kernel-module-iccom-mfis \
+    kernel-module-iccom-hwspinlock-sample \
+"
+
+# User modules of ICCOM only supports 64bit
+ICCOM_USER_PKGS = ""
+ICCOM_USER_PKGS_aarch64-poky-linux = " \
+    iccom-user-module \
+    iccom-tp-user-module \
+"
+
+# ICCOM Packages
+ICCOM_PKGS = " \
+    ${ICCOM_KERNEL_PKGS} \
+    ${ICCOM_USER_PKGS} \
+"
+
+# Installation for ICCOM Packages
+IMAGE_INSTALL_append = " \
+    ${@base_conditional("USE_ICCOM", "1", " ${ICCOM_PKGS}", "", d)} \
+"
diff --git a/meta-rcar-gen3/recipes-graphics/images/core-image-renesas-mmp-base.inc b/meta-rcar-gen3/recipes-graphics/images/core-image-renesas-mmp-base.inc
new file mode 100644
index 0000000..7c85d04
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/images/core-image-renesas-mmp-base.inc
@@ -0,0 +1,96 @@
+require include/multimedia-control.inc
+require include/cms-control.inc
+require include/adsp-control.inc
+require include/dtv-dvd-control.inc
+require include/avb-control.inc
+require include/omx-control.inc
+
+# Common Multi Media Packages (MMP)
+MULTIMEDIA_PKGS = " \
+    packagegroup-multimedia-kernel-modules \
+    packagegroup-multimedia-libs \
+"
+
+# MMP test Packages
+MULTIMEDIA_TP_PKGS = " \
+    vspmif-tp-user-module \
+"
+
+# OMX MMP Packages
+OMX_MULTIMEDIA_PKGS = " \
+    omx-user-module \
+"
+
+# CMS MMP Packages
+CMS_MULTIMEDIA_PKGS = " \
+    cms-user-module \
+"
+
+# Kernel modules of DTV
+DTV_KERNEL_PKGS = " \
+    kernel-module-scu-src \
+    kernel-module-ssp \
+    kernel-module-tddmac \
+    kernel-module-tsif \
+"
+
+# DTV Packages
+DTV_PKGS = " \
+    ${DTV_KERNEL_PKGS} \
+    dtv-user-module \
+"
+
+# DVD Packages
+DVD_PKGS = " \
+    dvd-user-module \
+"
+
+# ADSP Packages
+ADSP_PKGS = " \
+    kernel-module-xtensa-hifi \
+    adsp-if-module \
+    adsp-fw-module \
+"
+
+# Kernel modules of AVB
+AVB_KERNEL_PKGS = " \
+    kernel-module-avb-streaming \
+    kernel-module-avb-mch \
+    kernel-module-avb-mse \
+"
+
+# AVB Packages
+AVB_PKGS = " \
+    ${AVB_KERNEL_PKGS} \
+    avbtool \
+    linuxptp \
+    open-avb-mrpd \
+    open-avb-gptp \
+    open-avb-maap \
+    avb-demoapps-avblauncher \
+    avb-demoapps-mrpdummy \
+    avb-demoapps-simple \
+"
+
+# Renesas MMP 32bit packages
+MMP_32BIT_PKGS = " \
+    ${@base_conditional("USE_MULTIMEDIA", "1", "lib32-packagegroup-multimedia-libs lib32-omx-user-module", "", d)} \
+    ${@base_conditional("USE_MULTIMEDIA_TP", "1", "lib32-vspmif-tp-user-module", "", d)} \
+    ${@base_conditional("USE_CMS", "1", "lib32-cms-user-module", "", d)} \
+    ${@base_conditional("USE_DTV", "1", "lib32-dtv-user-module", "", d)} \
+    ${@base_conditional("USE_DVD", "1", "lib32-dvd-user-module", "", d)} \
+    ${@base_conditional("USE_ADSP", "1", "lib32-adsp-if-module", "", d)} \
+"
+
+# Install pkg selection
+IMAGE_INSTALL_append = " \
+    ${@base_conditional("USE_MULTIMEDIA", "1", " ${MULTIMEDIA_PKGS}", "", d)} \
+    ${@base_conditional("USE_MULTIMEDIA_TP", "1", " ${MULTIMEDIA_TP_PKGS}", "", d)} \
+    ${@base_conditional("USE_OMX_USER_MODULE", "1", " ${OMX_MULTIMEDIA_PKGS}", "", d)} \
+    ${@base_conditional("USE_CMS", "1", " ${CMS_MULTIMEDIA_PKGS}", "", d)} \
+    ${@base_conditional("USE_DTV", "1", " ${DTV_PKGS}", "", d)} \
+    ${@base_conditional("USE_DVD", "1", " ${DVD_PKGS}", "", d)} \
+    ${@base_conditional("USE_ADSP", "1", " ${ADSP_PKGS}", "", d)} \
+    ${@base_conditional("USE_AVB", "1", " ${AVB_PKGS}", "", d)} \
+    ${@base_conditional("USE_32BIT_MMP", "1", " ${MMP_32BIT_PKGS}", "", d)} \
+"
diff --git a/meta-rcar-gen3/recipes-graphics/images/core-image-weston-sdk.bb b/meta-rcar-gen3/recipes-graphics/images/core-image-weston-sdk.bb
new file mode 100644
index 0000000..fd4e6a0
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/images/core-image-weston-sdk.bb
@@ -0,0 +1,15 @@
+require recipes-graphics/images/core-image-weston.bb
+require core-image-renesas-base.inc
+require core-image-weston.inc
+
+DESCRIPTION = "Image with weston support that includes everything within \
+core-image-weston plus meta-toolchain, development headers and libraries to \
+form a standalone SDK."
+
+IMAGE_FEATURES += " \
+    dev-pkgs tools-sdk \
+    tools-debug debug-tweaks \
+    ssh-server-openssh \
+"
+
+IMAGE_INSTALL_append = " kernel-devsrc ltp"
diff --git a/meta-rcar-gen3/recipes-graphics/images/core-image-weston.bbappend b/meta-rcar-gen3/recipes-graphics/images/core-image-weston.bbappend
new file mode 100644
index 0000000..e30bc2e
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/images/core-image-weston.bbappend
@@ -0,0 +1,2 @@
+require core-image-renesas-base.inc
+require core-image-weston.inc
diff --git a/meta-rcar-gen3/recipes-graphics/images/core-image-weston.inc b/meta-rcar-gen3/recipes-graphics/images/core-image-weston.inc
new file mode 100644
index 0000000..28e28d4
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/images/core-image-weston.inc
@@ -0,0 +1,42 @@
+require include/gles-control.inc
+require core-image-renesas-mmp-base.inc
+
+# Wayland basic packages
+WAYLAND_BASE_PKGS = " \
+    weston-bin \
+    alsa-utils \
+    alsa-tools \
+    libdrm-tests \
+    libdrm-kms \
+"
+
+# GFX for Wayland packages
+WAYLAND_GLES_PKGS = "libgbm-dev"
+
+# GFX driver and library packages
+GLES_PKGS = " \
+    kernel-module-gles \
+    gles-user-module \
+"
+
+# Gstreamer Packages
+GSTREAMER_PKGS = "packagegroup-gstreamer1.0-plugins"
+
+# 32bit packages for wayland env
+WAYLAND_32BIT_PKGS = " \
+    lib32-weston \
+    lib32-libdrm \
+    lib32-libdrm-kms \
+    ${@base_conditional("USE_GLES", "1", "lib32-gles-user-module", "", d)} \
+"
+
+# Install packages for Wayland Env
+# default: Basic packages, Gstreamer packages
+# optional: GFX packages
+IMAGE_INSTALL_append = " \
+    ${WAYLAND_BASE_PKGS} \
+    ${GSTREAMER_PKGS} \
+    ${@base_conditional("USE_GLES", "1", "${GLES_PKGS}", "", d)} \
+    ${@base_conditional("USE_GLES_WAYLAND", "1", "${WAYLAND_GLES_PKGS}", "", d)} \
+    ${@base_conditional("USE_32BIT_WAYLAND", "1", "${WAYLAND_32BIT_PKGS}", "", d)} \
+"