rcar-gen3: weston: Split out machine specific configuration

This commit adds more weston-conf bbappend to adapt YP2.6.
Renesas MACHINEs also provided their configurations.

(From Poky rev: 4001e1adb21b9785a19669968f07166f5b8772cd)

Signed-off-by: Thuy Tran <thuy.tran.xh@renesas.com>
Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>

1 files changed, 34 insertions, 0 deletions

diff --git a/meta-rcar-gen3/recipes-graphics/wayland/weston-conf.bbappend b/meta-rcar-gen3/recipes-graphics/wayland/weston-conf.bbappend
new file mode 100644
index 0000000..179651b
--- /dev/null
+++ b/meta-rcar-gen3/recipes-graphics/wayland/weston-conf.bbappend
@@ -0,0 +1,34 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+SRC_URI = " \
+    file://weston.ini \
+    file://weston.sh \
+"
+
+do_install_append() {
+    install -d ${D}/${sysconfdir}/xdg/weston
+    # install weston.ini as sample settings of gl-renderer
+    install -m 644 ${WORKDIR}/weston.ini ${D}/${sysconfdir}/xdg/weston/
+
+    # Checking for ivi-shell configuration
+    # If ivi-shell is enable, we will add its configs to weston.ini
+    if [ "X${USE_WAYLAND_IVI_SHELL}" = "X1" ]; then
+        sed -i '/repaint-window=34/c\repaint-window=34\nshell=ivi-shell.so' \
+            ${D}/${sysconfdir}/xdg/weston/weston.ini
+        sed -e '$a\\' \
+            -e '$a\[ivi-shell]' \
+            -e '$a\ivi-module=ivi-controller.so' \
+            -e '$a\ivi-input-module=ivi-input-controller.so' \
+            -e '$a\transition-duration=300' \
+            -e '$a\cursor-theme=default' \
+            -i ${D}/${sysconfdir}/xdg/weston/weston.ini
+    fi
+
+    # Set XDG_RUNTIME_DIR to /run/user/$UID (e.g. run/user/0)
+    install -d ${D}/${sysconfdir}/profile.d
+    install -m 0755 ${WORKDIR}/weston.sh ${D}/${sysconfdir}/profile.d/weston.sh
+}
+
+FILES_${PN}_append = " \
+    ${sysconfdir}/profile.d/weston.sh \
+"