First commit.Renesas-Yocto-v2.16.0

Renesas BSP v3.5.1 (kernel v4.9 stable)

[Environment]
poky: yocto-2.1.2 (cca8dd15c8096626052f6d8d25ff1e9a606104a3)
meta-openembedded: 55c8a76da5dc099a7bc3838495c672140cedb78e
meta-linaro: 2f51d38048599d9878f149d6d15539fb97603f8f

[Information]
- U-boot: Changed load address from H'49000000 to H'50000000
- XDG_RUNTIME_DIR has been changed from "/run/user/root" to "/run/user/0"
- Change location of include directory, which stores common user header
  files, to $(INCSHARED)
- In BSP Only, core-image-weston is not supported even though
  local-wayland.conf is provided.
- Please set Salvator-x SW7 Pin-1. In after Yocto BSP v2.12.0, it is
　necessary to enable BKUP_TRG signal for Suspend to RAM.
- The dtb filename was changed in R-Car H3. Only
  "Image-r8a7795-es1-salvator-x.dtb" is supported in this version.
  Please use "Image-r8a7795-es1-salvator-x.dtb" It supports R-Car H3
  WS1.0 and WS1.1.
- Please update your local.conf and bblayers.conf corresponding to Yocto
  v2.16.0 package. You can refer to meta-rcargen3/docs/sample/conf/ for
  updated contents.
- You have to re-compile out-of-recipe software like user application by
  v2.16.0 SDK toolchains.
- In some boards, the resuming from System Suspend to RAM may cause
  unstable operation or failed to resume.

Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>

1 files changed, 59 insertions, 0 deletions

diff --git a/meta-rcar-gen3/recipes-kernel/kernel-module-vsp2driver/kernel-module-vsp2driver.bb b/meta-rcar-gen3/recipes-kernel/kernel-module-vsp2driver/kernel-module-vsp2driver.bb
new file mode 100644
index 0000000..45b8d86
--- /dev/null
+++ b/meta-rcar-gen3/recipes-kernel/kernel-module-vsp2driver/kernel-module-vsp2driver.bb
@@ -0,0 +1,59 @@
+DESCRIPTION = "VSP2Driver for the R-Car Gen3"
+
+LICENSE = "GPLv2 & MIT"
+LIC_FILES_CHKSUM = " \
+    file://GPL-COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://MIT-COPYING;md5=192063521ce782a445a3c9f99a8ad560 \
+"
+
+require include/rcar-gen3-modules-common.inc
+
+inherit module
+
+DEPENDS = "linux-renesas kernel-module-vspm"
+PN = "kernel-module-vsp2driver"
+PR = "r0"
+
+VSP2DRIVER_URL = " \
+    git://github.com/renesas-rcar/vsp2driver.git"
+BRANCH = "rcar-gen3"
+SRCREV = "d96345b179973987731e2ef1b83c3b45395862db"
+
+SRC_URI = "${VSP2DRIVER_URL};branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+do_compile() {
+    cd ${S}/vsp2driver
+    make all
+}
+
+do_install () {
+    # Create destination directories
+    install -d ${D}/lib/modules/${KERNEL_VERSION}/extra/
+    install -d ${KERNELSRC}/include
+
+    # Install shared library to KERNELSRC(STAGING_KERNEL_DIR) for reference from other modules
+    # This file installed in SDK by kernel-devsrc pkg.
+    install -m 644 ${S}/vsp2driver/Module.symvers ${KERNELSRC}/include/vsp2.symvers
+
+    # Copy kernel module
+    install -m 644 ${S}/vsp2driver/vsp2.ko ${D}/lib/modules/${KERNEL_VERSION}/extra/
+
+    # Install shared header files to KERNELSRC(STAGING_KERNEL_DIR)
+    # This file installed in SDK by kernel-devsrc pkg.
+    install -m 644 ${S}/vsp2driver/linux/vsp2.h ${KERNELSRC}/include/
+}
+
+PACKAGES = "\
+    ${PN} \
+"
+
+FILES_${PN} = " \
+    /lib/modules/${KERNEL_VERSION}/extra/vsp2.ko \
+"
+
+RPROVIDES_${PN} += "kernel-module-vsp2driver kernel-module-vsp2"
+
+# Autoload VSP2Driver
+KERNEL_MODULE_AUTOLOAD = "vsp2"