First commit.Renesas-Yocto-v2.16.0

Renesas BSP v3.5.1 (kernel v4.9 stable)

[Environment]
poky: yocto-2.1.2 (cca8dd15c8096626052f6d8d25ff1e9a606104a3)
meta-openembedded: 55c8a76da5dc099a7bc3838495c672140cedb78e
meta-linaro: 2f51d38048599d9878f149d6d15539fb97603f8f

[Information]
- U-boot: Changed load address from H'49000000 to H'50000000
- XDG_RUNTIME_DIR has been changed from "/run/user/root" to "/run/user/0"
- Change location of include directory, which stores common user header
  files, to $(INCSHARED)
- In BSP Only, core-image-weston is not supported even though
  local-wayland.conf is provided.
- Please set Salvator-x SW7 Pin-1. In after Yocto BSP v2.12.0, it is
　necessary to enable BKUP_TRG signal for Suspend to RAM.
- The dtb filename was changed in R-Car H3. Only
  "Image-r8a7795-es1-salvator-x.dtb" is supported in this version.
  Please use "Image-r8a7795-es1-salvator-x.dtb" It supports R-Car H3
  WS1.0 and WS1.1.
- Please update your local.conf and bblayers.conf corresponding to Yocto
  v2.16.0 package. You can refer to meta-rcargen3/docs/sample/conf/ for
  updated contents.
- You have to re-compile out-of-recipe software like user application by
  v2.16.0 SDK toolchains.
- In some boards, the resuming from System Suspend to RAM may cause
  unstable operation or failed to resume.

Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>

1 files changed, 86 insertions, 0 deletions

diff --git a/meta-rcar-gen3/recipes-kernel/kernel-module-vspm/kernel-module-vspm.bb b/meta-rcar-gen3/recipes-kernel/kernel-module-vspm/kernel-module-vspm.bb
new file mode 100644
index 0000000..698dd58
--- /dev/null
+++ b/meta-rcar-gen3/recipes-kernel/kernel-module-vspm/kernel-module-vspm.bb
@@ -0,0 +1,86 @@
+DESCRIPTION = "VSP Manager for the R-Car Gen3"
+
+require include/rcar-gen3-modules-common.inc
+
+LICENSE = "GPLv2 & MIT"
+LIC_FILES_CHKSUM = " \
+    file://GPL-COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://MIT-COPYING;md5=0ebf15a927e436cec699371cd890775c \
+"
+
+inherit module
+
+DEPENDS = "linux-renesas"
+PN = "kernel-module-vspm"
+PR = "r0"
+
+VSPM_DRV_URL = "git://github.com/renesas-rcar/vspm_drv.git"
+BRANCH = "rcar_gen3"
+SRCREV = "a55d7823cef3c5402b77f90978e0e60ea367d56d"
+
+SRC_URI = "${VSPM_DRV_URL};branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+VSPM_DRV_DIR = "vspm-module/files/vspm"
+includedir = "/usr/local/include"
+
+do_compile() {
+    cd ${S}/${VSPM_DRV_DIR}/drv
+    make all
+}
+
+do_install () {
+    # Create destination directories
+    install -d ${D}/lib/modules/${KERNEL_VERSION}/extra/
+    install -d ${KERNELSRC}/include
+    install -d ${D}/${includedir}
+
+    # Install shared library to KERNELSRC(STAGING_KERNEL_DIR) for reference from other modules
+    # This file installed in SDK by kernel-devsrc pkg.
+    install -m 644 ${S}/${VSPM_DRV_DIR}/drv/Module.symvers ${KERNELSRC}/include/vspm.symvers
+
+    # Install kernel module
+    install -m 644 ${S}/${VSPM_DRV_DIR}/drv/vspm.ko ${D}/lib/modules/${KERNEL_VERSION}/extra/
+
+    # Install shared header files to KERNELSRC(STAGING_KERNEL_DIR)
+    # This file installed in SDK by kernel-devsrc pkg.
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/vspm_public.h ${KERNELSRC}/include/
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/vspm_cmn.h ${KERNELSRC}/include/
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/vsp_drv.h ${KERNELSRC}/include/
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/fdp_drv.h ${KERNELSRC}/include/
+
+    # Install shared header files
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/vspm_cmn.h ${D}/${includedir}/
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/vsp_drv.h ${D}/${includedir}/
+    install -m 644 ${S}/${VSPM_DRV_DIR}/include/fdp_drv.h ${D}/${includedir}/
+}
+
+do_populate_sysroot[sstate-inputdirs] += "${S}/${VSPM_DRV_DIR}/include/"
+do_populate_sysroot[sstate-outputdirs] += "${KERNELSRC}/include/"
+do_populate_sysroot_setscene[prefuncs] = "vspm_sstate_check_func"
+SSTATE_DUPWHITELIST = "${KERNELSRC}/include"
+
+vspm_sstate_check_func() {
+    # An error is returned when unpack of kernel source has not been completed yet.
+    # By returning error, rebuild task runs by force (Invalidating sstate).
+    # This module installs shared header files in ${KERNELSRC}/include by
+    # sstate cache.
+    # Those files will be deleted by unpack task of kernel.
+    if [ ! -d "${KERNELSRC}/include" ]; then
+        exit 1
+    fi
+}
+
+PACKAGES = " \
+    ${PN} \
+    ${PN}-dev \
+"
+
+FILES_${PN} = " \
+    /lib/modules/${KERNEL_VERSION}/extra/vspm.ko \
+"
+
+RPROVIDES_${PN} += "kernel-module-vspm"
+
+# Autoload VSPM
+KERNEL_MODULE_AUTOLOAD = "vspm"