First commit.Renesas-Yocto-v2.16.0

Renesas BSP v3.5.1 (kernel v4.9 stable)

[Environment]
poky: yocto-2.1.2 (cca8dd15c8096626052f6d8d25ff1e9a606104a3)
meta-openembedded: 55c8a76da5dc099a7bc3838495c672140cedb78e
meta-linaro: 2f51d38048599d9878f149d6d15539fb97603f8f

[Information]
- U-boot: Changed load address from H'49000000 to H'50000000
- XDG_RUNTIME_DIR has been changed from "/run/user/root" to "/run/user/0"
- Change location of include directory, which stores common user header
  files, to $(INCSHARED)
- In BSP Only, core-image-weston is not supported even though
  local-wayland.conf is provided.
- Please set Salvator-x SW7 Pin-1. In after Yocto BSP v2.12.0, it is
　necessary to enable BKUP_TRG signal for Suspend to RAM.
- The dtb filename was changed in R-Car H3. Only
  "Image-r8a7795-es1-salvator-x.dtb" is supported in this version.
  Please use "Image-r8a7795-es1-salvator-x.dtb" It supports R-Car H3
  WS1.0 and WS1.1.
- Please update your local.conf and bblayers.conf corresponding to Yocto
  v2.16.0 package. You can refer to meta-rcargen3/docs/sample/conf/ for
  updated contents.
- You have to re-compile out-of-recipe software like user application by
  v2.16.0 SDK toolchains.
- In some boards, the resuming from System Suspend to RAM may cause
  unstable operation or failed to resume.

Signed-off-by: Takamitsu Honda <takamitsu.honda.pv@renesas.com>

1 files changed, 66 insertions, 0 deletions

diff --git a/meta-rcar-gen3/recipes-multimedia/open-avb/open-avb_git.bb b/meta-rcar-gen3/recipes-multimedia/open-avb/open-avb_git.bb
new file mode 100644
index 0000000..88900b5
--- /dev/null
+++ b/meta-rcar-gen3/recipes-multimedia/open-avb/open-avb_git.bb
@@ -0,0 +1,66 @@
+DESCRIPTION = "Open AVB - an AVnu sponsored repository for Audio/Video Bridging technology"
+HOMEPAGE = "https://github.com/AVnu/Open-AVB"
+LICENSE = "BSD & MIT & GPLv2 & LGPLv2"
+LIC_FILES_CHKSUM = " \
+    file://daemons/LICENSE;md5=81ccd62d4bc28bafc5e1a2576536b927 \
+    file://kmod/igb/COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://kmod/igb/LICENSE;md5=e2c0cd0820d168b0b26e19f13df4dc56 \
+    file://lib/igb/LICENSE;md5=9bc783ca40be823a8b237df5eed80fc4 \
+    file://lib/avtp_pipeline/LICENSE;md5=8f7b370a91d698ed80d2d20e8e01fbb6 \
+    file://examples/LICENSE;md5=81ccd62d4bc28bafc5e1a2576536b927 \
+    file://examples/gstreamer-avb-plugins/COPYING.LIB;md5=55ca817ccb7d5b5b66355690e9abc605 \
+    file://examples/gstreamer-avb-plugins/COPYING.MIT;md5=bba6cdb9c2b03c849ed4975ed9ed90dc \
+"
+
+DEPENDS = "libpcap"
+
+PV = "1.1+git${SRCPV}"
+
+SRCREV = "20731bd82d2b2e59387f7b3a61fc0370c93ec568"
+SRC_URI = "git://github.com/AVnu/Open-AVB.git;branch=open-avb-next"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = "'CC=${CC}' 'CXX=${CXX}'"
+
+do_compile() {
+    oe_runmake daemons_all
+}
+
+do_install() {
+    install -d ${D}/${bindir}
+    install -m 755 daemons/maap/linux/maap_daemon ${D}/${bindir}
+    install -m 755 daemons/mrpd/mrpd daemons/mrpd/mrpctl ${D}/${bindir}
+    install -m 755 daemons/gptp/linux/build/obj/daemon_cl ${D}/${bindir}
+}
+
+PACKAGES =+ " \
+    ${PN}-gptp \
+    ${PN}-mrpd \
+    ${PN}-maap \
+"
+
+ALLOW_EMPTY_${PN} = "1"
+
+FILES_${PN}-gptp = " \
+    ${bindir}/daemon_cl \
+"
+
+FILES_${PN}-mrpd = " \
+    ${bindir}/mrpd \
+    ${bindir}/mrpctl \
+"
+
+FILES_${PN}-maap = " \
+    ${bindir}/maap_daemon \
+"
+
+RDEPENDS_${PN} = " \
+    ${PN}-gptp \
+    ${PN}-mrpd \
+    ${PN}-maap \
+"
+
+RDEPENDS_${PN}-maap = " \
+    libpcap \
+"