meta-rcar-gen3/recipes-kernel/kernel-module-avb/kernel-module-avb-mse.bb


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

DESCRIPTION = "AVB MSE Driver for Linux for the R-Car Gen3"

require include/avb-control.inc
require include/rcar-gen3-modules-common.inc

LICENSE = "GPLv2 & MIT"
LIC_FILES_CHKSUM = " \
    file://GPL-COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
    file://MIT-COPYING;md5=98449101c5d5452a9429b88d6ead1ba4 \
"

inherit module distro_features_check

DEPENDS = "linux-renesas kernel-module-avb-streaming kernel-module-avb-mch"

REQUIRED_DISTRO_FEATURES = "avb"

SRC_URI = "git://github.com/renesas-rcar/avb-mse.git;branch=rcar-gen3"
SRCREV = "45779953bd9069ffc8add30d247f87326a8f89e9"

S = "${WORKDIR}/git"

includedir = "/usr/local/include"

do_install_append() {
    # Create destination directories
    install -d ${KERNELSRC}/include
    install -d ${D}/${includedir}

    # Install shared header files to KERNELSRC(STAGING_KERNEL_DIR).
    # This file installed in SDK by kernel-devsrc pkg.
    install -m 644 ${S}/ravb_mse.h ${KERNELSRC}/include
    install -m 644 ${S}/ravb_mse_kernel.h ${KERNELSRC}/include

    # Install shared header files to ${includedir}
    install -m 644 ${S}/ravb_mse.h ${D}/${includedir}
    install -m 644 ${S}/ravb_mse_kernel.h ${D}/${includedir}
}