blob: 31695e061e923e442179e02382e6d959f4e3d22b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
DESCRIPTION = "Linux kernel for the R-Car Generation 3 based board"
require include/avb-control.inc
require recipes-kernel/linux/linux-yocto.inc
FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}/:"
COMPATIBLE_MACHINE = "salvator-x|h3ulcb|m3ulcb"
RENESAS_BSP_URL = "git://git.kernel.org/pub/scm/linux/kernel/git/horms/renesas-bsp.git"
BRANCH = "v4.14/rcar-3.6.0"
SRCREV = "cdbdfa1452a86607db4d43914f4953ac811d2c56"
SRC_URI = "${RENESAS_BSP_URL};protocol=git;nocheckout=1;branch=${BRANCH}"
LINUX_VERSION ?= "4.14.0"
PV = "${LINUX_VERSION}+git${SRCPV}"
PR = "r1"
SRC_URI_append = " \
file://defconfig \
file://touch.cfg \
${@base_conditional("USE_AVB", "1", " file://usb-video-class.cfg", "", d)} \
"
# Add SCHED_DEBUG config fragment to support CAS
SRC_URI_append = " \
${@bb.utils.contains('MACHINE_FEATURES','cas','file://capacity_aware_migration_strategy.cfg','',d)} \
"
# Install USB3.0 firmware to rootfs
USB3_FIRMWARE_V2 = "https://git.kernel.org/pub/scm/linux/kernel/git/firmware/linux-firmware.git/plain/r8a779x_usb3_v2.dlmem;md5sum=645db7e9056029efa15f158e51cc8a11"
USB3_FIRMWARE_V3 = "https://git.kernel.org/pub/scm/linux/kernel/git/firmware/linux-firmware.git/plain/r8a779x_usb3_v3.dlmem;md5sum=687d5d42f38f9850f8d5a6071dca3109"
SRC_URI_append = " \
${USB3_FIRMWARE_V2} \
${USB3_FIRMWARE_V3} \
${@bb.utils.contains('MACHINE_FEATURES','usb3','file://usb3.cfg','',d)} \
"
do_download_firmware () {
install -m 755 ${WORKDIR}/r8a779x_usb3_v*.dlmem ${STAGING_KERNEL_DIR}/firmware
}
addtask do_download_firmware after do_configure before do_compile
|
