afm-unit.conf: Refactor its generation

The process of generating the file /etc/afm-unit.conf
had be reworked to be more straight forward.

Before that commit, a manual operation (a "make") had
to be done before committing the repository. This was
not efficient, error prone and kept temporary files in
conf.

That commit changes it by calling m4 through cmake.

Bug-AGL: SPEC-2436

Change-Id: Ia32a810286471dde8a01387d157e33277d67411d
Signed-off-by: Jose Bollo <jose.bollo@iot.bzh>

1 files changed, 67 insertions, 0 deletions

diff --git a/conf/unit/macros.inc b/conf/unit/macros.inc
new file mode 100644
index 0000000..a764765
--- /dev/null
+++ b/conf/unit/macros.inc
@@ -0,0 +1,67 @@
+dnl vim: set filetype=sysctl.conf.m4 syntax=sysctl.conf.m4:
+--------------------------------------------------------------------------------
+-- GLOBAL IMPORTANT DEFINITIONS
+--------------------------------------------------------------------------------
+define( `X_EMITS', 1)
+define( `X_DIVERTS', `divert(eval(-!X_EMITS()))')
+define( `X_PUSH_DIVERTS', `pushdef(`X_EMITS', eval(X_EMITS() && $1))X_DIVERTS()')
+
+define( `X_IF', `pushdef(`X_COND', $1)X_PUSH_DIVERTS($1)')
+define( `X_ELSE', `popdef(`X_EMITS')X_PUSH_DIVERTS(eval(!X_COND))')
+define( `X_ELIF', `X_ELSE()X_IF($1)')
+define( `X_ENDIF', `popdef(`X_EMITS')popdef(`X_COND')X_DIVERTS()')
+
+define( `IF', `pushdef(`ELSE',`X_ELSE()')pushdef(`ELIF',`X_ELIF($1)')pushdef(`ENDIF',`X_ENDIF()popdef(`ELSE',`ELIF',`ENDIF')')X_IF($1)')
+--------------------------------------------------------------------------------
+-- MUSTACH SPECIFIC DEFINITIONS
+--------------------------------------------------------------------------------
+define( `MUSTACH_ON', `ifelse(`$2',,,`{{#$1}}`$2'{{/$1}}')ifelse(`$3',,,`{{^$1}}`$3'{{/$1}}')')
+define( `MUSTACH_IF', `{{#$1}}pushdef(`ELSE',`{{/$1}}{{^$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
+define( `MUSTACH_IF_NOT', `{{^$1}}pushdef(`ELSE',`{{/$1}}{{#$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
+--------------------------------------------------------------------------------
+-- CONDITIONAL HELPERS
+--------------------------------------------------------------------------------
+define( `PERM', `@afm_prefix@permission:$1')
+define( `REQPERM', `required-permission.PERM($1)')
+
+define( `ON_PERM', `MUSTACH_ON(REQPERM($1),$2,$3)')
+define( `IF_PERM', `MUSTACH_IF(REQPERM($1))')
+define( `IF_NOT_PERM', `MUSTACH_IF_NOT(REQPERM($1))')
+
+define( `ON_CONTENT', `MUSTACH_ON(content.type=$1,$2,$3)')
+define( `IF_CONTENT', `MUSTACH_IF(content.type=$1)')
+define( `IF_NOT_CONTENT', `MUSTACH_IF_NOT(content.type=$1)')
+
+define( `ON_VALUE', `MUSTACH_ON(value=$1,$2,$3)')
+define( `IF_VALUE', `MUSTACH_IF(value=$1)')
+define( `IF_NOT_VALUE', `MUSTACH_IF_NOT(value=$1)')
+--------------------------------------------------------------------------------
+-- AFM DEFINITION
+--------------------------------------------------------------------------------
+-- NOTE:
+--  when home screen will use real ids
+--  use TARGET={{:id}}--{{:ver}}--{{:#target}}
+--  instead of TARGET={{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}
+--------------------------------------------------------------------------------
+define( `TARGET', `{{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}')
+define( `NEWTARGET', `{{:id}}--{{:ver}}--{{:#target}}')
+define( `UNIT_NAME_BASE', `afm-ON_PERM(`:public:hidden', `service', `appli')-NEWTARGET')
+define( `UNIT_NAME_SERVICE', `UNIT_NAME_BASE@%i.service')
+define( `UNIT_NAME_API_BASE', `afm-api-$1')
+define( `UNIT_NAME_API_SERVICE', `UNIT_NAME_API_BASE($1)@$2.service')
+define( `UNIT_NAME_API_SOCKET', `UNIT_NAME_API_BASE($1)@$2.socket')
+define( `UNIT_NAME_BINDING_BASE', `afm-link-$1')
+define( `UNIT_NAME_BINDING_SERVICE', `UNIT_NAME_BINDING_BASE($1)@$2.service')
+define( `APP_DATA_DIR', `/home/%i/app-data')
+define( `USER_RUN_DIR', `@afm_users_rundir@/%i')
+define( `DEBUGGING_DIR', `@afm_platform_rundir@/debug')
+define( `API_PATH', `USER_RUN_DIR/apis')
+define( `API_PATH_WS', `API_PATH/ws')
+define( `API_PATH_LINK', `API_PATH/link')
+--------------------------------------------------------------------------------
+-- AGL_DEVEL SPECIFIC PARTS
+--------------------------------------------------------------------------------
+define( `ON_AGL_DEVEL', `ifdef(`AGL_DEVEL', $1, $2)')
+define( `ON_NOT_AGL_DEVEL', `ifdef(`AGL_DEVEL', $2, $1)')
+define( `IF_AGL_DEVEL', `IF(ON_AGL_DEVEL(1,0))')
+define( `IF_NOT_AGL_DEVEL', `IF(ON_AGL_DEVEL(0,1))')