1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
|
divert(-1)
dnl vim: set filetype=sysctl.conf.m4 syntax=sysctl.conf.m4:
-----------------------------------------------------------------------
-- Set the comment character of m4 to ; instead of #
-- This is needed for substitution within lines starting with #
changecom( ';')
-----------------------------------------------------------------------
--
define( `X_EMITS', 1)
define( `X_DIVERTS', `divert(eval(-!X_EMITS()))')
define( `X_PUSH_DIVERTS', `pushdef(`X_EMITS', eval(X_EMITS() && $1))X_DIVERTS()')
define( `X_IF', `pushdef(`X_COND', $1)X_PUSH_DIVERTS($1)')
define( `X_ELSE', `popdef(`X_EMITS')X_PUSH_DIVERTS(eval(!X_COND))')
define( `X_ELIF', `X_ELSE()X_IF($1)')
define( `X_ENDIF', `popdef(`X_EMITS')popdef(`X_COND')X_DIVERTS()')
define( `IF', `pushdef(`ELSE',`X_ELSE()')pushdef(`ELIF',`X_ELIF($1)')pushdef(`ENDIF',`X_ENDIF()popdef(`ELSE',`ELIF',`ENDIF')')X_IF($1)')
-----------------------------------------------------------------------
--
define( `MUSTACH_ON', `ifelse(`$2',,,`{{#$1}}`$2'{{/$1}}')ifelse(`$3',,,`{{^$1}}`$3'{{/$1}}')')
define( `MUSTACH_IF', `{{#$1}}pushdef(`ELSE',`{{/$1}}{{^$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
define( `MUSTACH_IF_NOT', `{{^$1}}pushdef(`ELSE',`{{/$1}}{{#$1}}')pushdef(`ENDIF',`{{/$1}}popdef(`ELSE',`ENDIF')')')
-----------------------------------------------------------------------
--
define( `PERM', `urn:AGL:permission:$1')
define( `REQPERM', `required-permission.PERM($1)')
define( `ON_PERM', `MUSTACH_ON(REQPERM($1),$2,$3)')
define( `IF_PERM', `MUSTACH_IF(REQPERM($1))')
define( `IF_NOT_PERM', `MUSTACH_IF_NOT(REQPERM($1))')
define( `ON_CONTENT', `MUSTACH_ON(content.type=$1,$2,$3)')
define( `IF_CONTENT', `MUSTACH_IF(content.type=$1)')
define( `IF_NOT_CONTENT', `MUSTACH_IF_NOT(content.type=$1)')
define( `ON_VALUE', `MUSTACH_ON(value=$1,$2,$3)')
define( `IF_VALUE', `MUSTACH_IF(value=$1)')
define( `IF_NOT_VALUE', `MUSTACH_IF_NOT(value=$1)')
-----------------------------------------------------------------------
--
when home screen will use real ids
use TARGET={{:id}}--{{:ver}}--{{:#target}}
instead of TARGET={{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}
define( `TARGET', `{{idaver}}{{^#target=main}}@{{:#target}}{{/#target=main}}')
define( `UNIT_NAME_BASE', `afm-ON_PERM(`:public:hidden', `service', `appli')-{{:id}}--{{:ver}}--{{:#target}}@')
define( `UNIT_NAME_SERVICE', `UNIT_NAME_BASE%i.service')
define( `UNIT_NAME_API_BASE', `afm-api-$1')
define( `UNIT_NAME_API_SERVICE', `UNIT_NAME_API_BASE($1)@$2.service')
define( `UNIT_NAME_API_SOCKET', `UNIT_NAME_API_BASE($1)@$2.socket')
define( `UNIT_NAME_BINDING_BASE', `afm-link-$1')
define( `UNIT_NAME_BINDING_SERVICE', `UNIT_NAME_BINDING_BASE($1)@$2.service')
define( `APP_DATA_DIR', `/home/%i/app-data')
define( `USER_RUN_DIR', `@afm_users_rundir@/%i')
define( `DEBUGGING_DIR', `@afm_platform_rundir@/debug')
define( `API_PATH', `USER_RUN_DIR/apis')
define( `API_PATH_WS', `API_PATH/ws')
define( `API_PATH_LINK', `API_PATH/link')
-----------------------------------------------------------------------
--
define( `ON_AGL_DEVEL', `ifdef(`AGL_DEVEL', $1, $2)')
define( `IF_AGL_DEVEL', `IF(ON_AGL_DEVEL(1,0))')
divert(0)dnl
;---------------------------------------------------------------------------------
; File:
;
; afm-unit.conf
;
; Mode:
;
; ON_AGL_DEVEL(DEVEL, RELEASE)
;
; Role:
;
; Configure how installation of widget produces unit files for systemd
;
; Processing and format:
;
; 1. File load
;
; Lines beginning with ; are firstly removed
;
; 2. File instantiation
;
; Mustache (extended) substitutions are applied using JSON
; data deduced from config.xml file of the widget.
;
; 3. Extraction of units
;
; Extract produced units, pack it (remove empty lines and directives)
;
; Directives:
;
; Any directive occupy one whole line starting with %
;
; - %nl
;
; produce an empty line at the end
;
; - %begin systemd-unit
; - %end systemd-unit
;
; delimit the produced unit
;
; - %systemd-unit user
; - %systemd-unit system
;
; tells the kind of unit (user/system)
;
; - %systemd-unit service NAME
; - %systemd-unit socket NAME
;
; gives the name and type of the unit
;
; - %systemd-unit wanted-by NAME
;
; tells to install a link to unit in the wants of NAME
;
; Setting variables:
;
; AFM uses the feature of systemd that completely ignores options prefixed
; with X-
;
; Consequently, options starting with X-AFM- are recorded as public data
; about the application and options starting starting with X-AFM-- are
; recorded as private data.
;
; Examples:
;
; X-AFM-description={{description}}
;
; Records the description of the unit in the field "description"
; of both the public and private object describing the unit.
;
; X-AFM--wgtdir={{:#metadata.install-dir}}
;
; Records the installation directory path in the field "wgtdir"
; of the private object only.
;
;---------------------------------------------------------------------------------
{{#targets}}
include(service.inc)
include(provided-api.inc)
include(provided-binding.inc)
{{/targets}}
;---------------------------------------------------------------------------------
; End of file afm-unit.conf mode ON_AGL_DEVEL(DEVEL, RELEASE)
;---------------------------------------------------------------------------------
|
